सामान्यीकृत रैखिक मॉडल में अवशिष्टों का अपेक्षित वितरण क्या है?
जवाबों:
What is the expected distribution of residuals?
यह उन तरीकों से मॉडल के साथ बदलता है जो आम तौर पर इसका जवाब देना असंभव बनाते हैं।
For example, should the residuals be distributed normally?
आम तौर पर नहीं, नहीं।
जीएलएम के लिए अवशिष्ट डिजाइन करने के आसपास केंद्रित एक संपूर्ण कुटीर उद्योग है जो अधिक सममित या यहां तक कि लगभग "सामान्य" (यानी गॉसियन) हैं, उदाहरण के लिए पियर्सन अवशेष, Anscombe अवशिष्ट, (समायोजित) अवशिष्ट अवशिष्ट, उदाहरण के लिए देखें जेम्स डब्ल्यू के अध्याय 6। । हार्डिन और जोसेफ एम। हिल्बे (2007) "सामान्यीकृत रैखिक मॉडल और एक्सटेंशन" दूसरा संस्करण। कॉलेज स्टेशन, TX: स्टैटा प्रेस। यदि आश्रित चर असतत है (एक संकेतक चर या एक गिनती) तो यह अवशिष्टों के अपेक्षित वितरण को वास्तव में गाऊसी बनाने के लिए बहुत कठिन है।
एक चीज जो आप कर सकते हैं, वह है कि आपके मॉडल के सत्य होने की धारणा के तहत बार-बार नए डेटा का अनुकरण करें, उस सिम्युलेटेड डेटा का उपयोग करके अपने मॉडल का अनुमान लगाएं और अवशिष्टों की गणना करें, और फिर अपने वास्तविक अवशेषों की अपने सिम्युलेटेड अवशेषों से तुलना करें। Stata में मैं ऐसा करना चाहूँगा:
sysuse nlsw88, clear
glm wage i.union grade c.ttl_exp##c.ttl_exp, link(log) family(poisson)
// collect which observations were used in estimation and the predicted mean
gen byte touse = e(sample)
predict double mu if touse
// predict residuals
predict resid if touse, anscombe
// prepare variables for plotting a cumulative distribution function
cumul resid, gen(c)
// collect the graph command in the local macro `graph'
local graph "twoway"
// create 19 simulations:
gen ysim = .
forvalues i = 1/19 {
replace ysim = rpoisson(mu) if touse
glm ysim i.union grade c.ttl_exp##c.ttl_exp, link(log) family(poisson)
predict resid`i' if touse, anscombe
cumul resid`i', gen(c`i')
local graph "`graph' line c`i' resid`i', sort lpattern(solid) lcolor(gs8) ||"
}
local graph "`graph' line c resid, sort lpattern(solid) lcolor(black) "
// display the graph
`graph' legend(order(20 "actual residuals" 1 "simulations"))
