यहां मेरा पूरा सीखने का अनुभव है, जिसके परिणामस्वरूप मुझे नॉन के आंतरिक तरीकों का उपयोग करते हुए आंदोलन के एक बहुत ही कार्यात्मक संस्करण की आवश्यकता थी। यह सभी कोड मेरे स्पाइडर वर्ग के भीतर है, जो अपने माता-पिता से कुछ गुणों को खींचता है, एक स्तर वर्ग।
अन्य वर्गों और विधियों में से अधिकांश नपे पैकेज का हिस्सा हैं। यहाँ मेरी आयात सूची का उचित भाग है:
import flash.events.TimerEvent;
import flash.utils.Timer;
import nape.callbacks.CbEvent;
import nape.callbacks.CbType;
import nape.callbacks.InteractionCallback;
import nape.callbacks.InteractionListener;
import nape.callbacks.InteractionType;
import nape.callbacks.OptionType;
import nape.dynamics.Arbiter;
import nape.dynamics.ArbiterList;
import nape.geom.Geom;
import nape.geom.Vec2;
सबसे पहले, जब मकड़ी को मंच पर जोड़ा जाता है, तो मैं श्रोताओं को टकराव के लिए नपे दुनिया में जोड़ता हूं। जैसा कि मैं विकास में आगे हूं, मुझे टकराव समूहों को अलग करने की आवश्यकता होगी; इस समय, ये कॉलबैक तकनीकी रूप से चलाए जाएंगे जब कोई भी शरीर किसी अन्य शरीर से टकराता है।
var opType:OptionType = new OptionType([CbType.ANY_BODY]);
mass = body.mass;
// Listen for collision with level, before, during, and after.
var landDetect:InteractionListener = new InteractionListener(CbEvent.BEGIN, InteractionType.COLLISION, opType, opType, spiderLand)
var moveDetect:InteractionListener = new InteractionListener(CbEvent.ONGOING, InteractionType.COLLISION, opType, opType, spiderMove);
var toDetect:InteractionListener = new InteractionListener(CbEvent.END, InteractionType.COLLISION, opType, opType, takeOff);
Level(this.parent).world.listeners.add(landDetect);
Level(this.parent).world.listeners.add(moveDetect);
Level(this.parent).world.listeners.add(toDetect);
/*
A reference to the spider's parent level's master timer, which also drives the nape world,
runs a callback within the spider class every frame.
*/
Level(this.parent).nTimer.addEventListener(TimerEvent.TIMER, tick);
कॉलबैक में मकड़ी की "राज्य" संपत्ति बदल जाती है, जो कि बुलियन का एक सेट है, और मेरे चलने वाले तर्क में बाद में उपयोग के लिए किसी भी बाप टक्कर मध्यस्थ को रिकॉर्ड करता है। उन्होंने टिमीर को भी सेट और क्लियर कर दिया है, जो मकड़ी को विश्व गुरुत्वाकर्षण को फिर से पकड़ लेने की अनुमति देने से पहले 100 सेंटीमीटर तक की सतह के साथ संपर्क खोने की अनुमति देता है।
protected function spiderLand(callBack:InteractionCallback):void {
tArbiters = callBack.arbiters.copy();
state.isGrounded = true;
state.isMidair = false;
body.gravMass = 0;
toTimer.stop();
toTimer.reset();
}
protected function spiderMove(callBack:InteractionCallback):void {
tArbiters = callBack.arbiters.copy();
}
protected function takeOff(callBack:InteractionCallback):void {
tArbiters.clear();
toTimer.reset();
toTimer.start();
}
protected function takeOffTimer(e:TimerEvent):void {
state.isGrounded = false;
state.isMidair = true;
body.gravMass = mass;
state.isMoving = false;
}
अंत में, मैं गणना करता हूं कि मकड़ी को उसके राज्य और उसके स्तर ज्यामिति के संबंध के आधार पर क्या लागू करना है। मैं ज्यादातर टिप्पणियों को खुद के लिए बोलने देता हूँ।
protected function tick(e:TimerEvent):void {
if(state.isGrounded) {
switch(tArbiters.length) {
/*
If there are no arbiters (i.e. spider is in midair and toTimer hasn't expired),
aim the adhesion force at the nearest point on the level geometry.
*/
case 0:
closestA = Vec2.get();
closestB = Vec2.get();
Geom.distanceBody(body, lvBody, closestA, closestB);
stickForce = closestA.sub(body.position, true);
break;
// For one contact point, aim the adhesion force at that point.
case 1:
stickForce = tArbiters.at(0).collisionArbiter.contacts.at(0).position.sub(body.position, true);
break;
// For multiple contact points, add the vectors to find the average angle.
default:
var taSum:Vec2 = tArbiters.at(0).collisionArbiter.contacts.at(0).position.sub(body.position, true);
tArbiters.copy().foreach(function(a:Arbiter):void {
if(taSum != a.collisionArbiter.contacts.at(0).position.sub(body.position, true))
taSum.addeq(a.collisionArbiter.contacts.at(0).position.sub(body.position, true));
});
stickForce=taSum.copy();
}
// Normalize stickForce's strength.
stickForce.length = 1000;
var curForce:Vec2 = new Vec2(stickForce.x, stickForce.y);
// For graphical purposes, align the body (simulation-based rotation is disabled) with the adhesion force.
body.rotation = stickForce.angle - Math.PI/2;
body.applyImpulse(curForce);
if(state.isMoving) {
// Gives "movement force" a dummy value since (0,0) causes problems.
mForce = new Vec2(10,10);
mForce.length = 1000;
// Dir is movement direction, a boolean. If true, the spider is moving left with respect to the surface; otherwise right.
// Using the corrected "down" angle, move perpendicular to that angle
if(dir) {
mForce.angle = correctAngle()+Math.PI/2;
} else {
mForce.angle = correctAngle()-Math.PI/2;
}
// Flip the spider's graphic depending on direction.
texture.scaleX = dir?-1:1;
// Now apply the movement impulse and decrease speed if it goes over the max.
body.applyImpulse(mForce);
if(body.velocity.length > 1000) body.velocity.length = 1000;
}
}
}
वास्तविक चिपचिपा हिस्सा मैंने पाया था कि आंदोलन के कोण को कई संपर्क बिंदु परिदृश्य में आंदोलन की वास्तविक वांछित दिशा में होना चाहिए जहां मकड़ी एक तेज कोण तक पहुंचती है या एक गहरी घाटी में बैठती है। विशेष रूप से तब से, आसंजन बल के लिए मेरे सुस्पष्ट वैक्टर को देखते हुए, वह बल AWAY को उस दिशा से खींच रहा होगा जिसे हम इसके बजाय लंबवत स्थानांतरित करना चाहते हैं, इसलिए हमें इसका मुकाबला करने की आवश्यकता है। इसलिए मुझे आंदोलन वेक्टर के कोण के आधार के रूप में उपयोग करने के लिए संपर्क बिंदुओं में से एक को लेने के लिए तर्क की आवश्यकता थी।
आसंजन बल के "पुल" का एक साइड इफेक्ट एक मामूली हिचकिचाहट है जब मकड़ी एक तेज अवतल कोण / वक्र तक पहुंचती है, लेकिन यह वास्तव में एक नज़र-और-महसूस दृष्टिकोण से यथार्थवादी है ताकि जब तक कि यह सड़क के नीचे की समस्याओं का कारण न हो। जैसा है वैसा ही छोड़ दो। अगर मुझे जरूरत है, तो मैं आसंजन बल की गणना करने के लिए इस पद्धति पर भिन्नता का उपयोग कर सकता हूं।
protected function correctAngle():Number {
var angle:Number;
if(tArbiters.length < 2) {
// If there is only one (or zero) contact point(s), the "corrected" angle doesn't change from stickForce's angle.
angle = stickForce.angle;
} else {
/*
For more than one contact point, we want to run perpendicular to the "new" down, so we copy all the
contact point angles into an array...
*/
var angArr:Array = [];
tArbiters.copy().foreach(function(a:Arbiter):void {
var curAng:Number = a.collisionArbiter.contacts.at(0).position.sub(body.position, true).angle;
if (curAng < 0) curAng += Math.PI*2;
angArr.push(curAng);
});
/*
...then we iterate through all those contact points' angles with respect to the spider's COM to figure out
which one is more clockwise or more counterclockwise, depending, with some restrictions...
...Whatever, the correct one.
*/
angle = angArr[0];
for(var i:int = 1; i<angArr.length; i++) {
if(dir) {
if(Math.abs(angArr[i]-angle) < Math.PI)
angle = Math.max(angle, angArr[i]);
else
angle = Math.min(angle, angArr[i]);
}
else {
if(Math.abs(angArr[i]-angle) < Math.PI)
angle = Math.min(angle, angArr[i]);
else
angle = Math.max(angle, angArr[i]);
}
}
}
return angle;
}
यह तर्क बहुत ज्यादा "सही" है, क्योंकि यह अभी तक ऐसा लगता है कि मैं जो करना चाहता हूं वह कर रहा हूं। हालाँकि, एक सुस्त कॉस्मेटिक मुद्दा है, लेकिन अगर मैं स्पाइडर के ग्राफिक को या तो आसंजन या आंदोलन बलों में संरेखित करने की कोशिश करता हूं, तो मुझे लगता है कि स्पाइडर आंदोलन की दिशा में "झुकाव" को समाप्त करता है, जो कि ठीक होगा यदि वह एक था दो-पैर वाले एथलेटिक स्प्रिंटर लेकिन वह नहीं है, और इलाके में भिन्नता के लिए कोण अतिसंवेदनशील हैं, इसलिए जब यह मामूली टक्कर से ऊपर जाता है तो मकड़ी उछल जाती है। मैं मकड़ी के उन्मुखीकरण को और अधिक यथार्थवादी बनाने के लिए, बाइटे 56 के समाधान पर एक बदलाव का पीछा कर सकता हूं, आस-पास के परिदृश्य और औसतन उन कोणों का नमूना ले सकता हूं।
