जीएलएसएल के साथ तेजी से गॉसियन धुंधला होने की चाल इस तथ्य का लाभ उठाने के लिए है कि GPU हार्डवेयर में रैखिक प्रक्षेप प्रदान करता है। इसलिए, आप एक ही प्रीफ़ेट या आठ 3D स्वर के साथ चार 2D पिक्सल को प्रभावी ढंग से नमूना कर सकते हैं। यह तय करने के लिए कि आप किस नमूने का उत्पादन कर सकते हैं। निश्चित संदर्भ सिग और हैडविग का "फास्ट थर्ड-ऑर्डर टेक्सचर फ़िल्टरिंग" है जिसे आप ऑनलाइन पा सकते हैं।
एक पठनीय व्याख्या के लिए वेब पेज "रैखिक नमूने के साथ कुशल गाऊसी धुंधला" खोजें। जैसा कि कहा गया है, चूंकि गाऊसी धब्बा विस्तृत गुठली के साथ अलग है, यह प्रति आयाम एक पास करने के लिए सबसे अधिक कुशल है।
हालाँकि, आप इस ट्रिक का उपयोग एक पास में एक तंग कर्नेल के साथ एक गाऊसी को अनुमानित करने के लिए कर सकते हैं। नीचे दिए गए उदाहरण में मैं शीर्ष स्लाइस के साथ 3 डी कर्नेल का अनुकरण करता हूं = [1 2 1; 2 4 2; 1 2 1]; मध्य टुकड़ा = [२ ४ २; 4 8 4; 2 4 2]; निचला टुकड़ा = [१ २ १; 2 4 2; १ २ १]। प्रत्येक आयाम में +/- 0.5 voxels का नमूना करके आप 27 के बजाय सिर्फ 8 बनावट के साथ ऐसा करते हैं। मैं GLSL में इसे MRIcroGL shader फ़ाइल के रूप में प्रदर्शित कर रहा हूं - बस नीचे दी गई स्क्रिप्ट को "a.txt" के रूप में सहेजें और इसे इसमें रखें। MRIcroGL का "Shader" फ़ोल्डर। जब आप प्रोग्राम को पुनः लोड करते हैं तो आप अपनी किरण डाली छवि को धुंधला देखेंगे। "DoBlur" चेकबॉक्स पर क्लिक करने से धुंधलापन दूर होता है। मेरे लैपटॉप और "chris_t1" में एकीकृत इंटेल GPU का उपयोग करना ऐसी छवि जो MRIcroGL I के साथ आती है, बिना ब्लरिंग (1 बनावट वाला) के साथ 70fps और धुंधला (8 भ्रूण) के साथ 21fps मिलता है। अधिकांश कोड सिर्फ एक क्लासिक रे ढलाईकार है, "doBlur" सशर्त आपके प्रश्न को एनकैप्सुलेट करता है।
//-------a.txt फ़ाइल इस प्रकार है
//pref
doBlur|bool|true
//vert
void main() {
gl_TexCoord[1] = gl_MultiTexCoord1;
gl_Position = ftransform();
}
//frag
uniform int loops;
uniform float stepSize, sliceSize, viewWidth, viewHeight;
uniform sampler3D intensityVol;
uniform sampler2D backFace;
uniform vec3 clearColor;
uniform bool doBlur;
void main() {
// get normalized pixel coordinate in view port (e.g. [0,1]x[0,1])
vec2 pixelCoord = gl_FragCoord.st;
pixelCoord.x /= viewWidth;
pixelCoord.y /= viewHeight;
// starting position of the ray is stored in the texture coordinate
vec3 start = gl_TexCoord[1].xyz;
vec3 backPosition = texture2D(backFace,pixelCoord).xyz;
vec3 dir = backPosition - start;
float len = length(dir);
dir = normalize(dir);
vec3 deltaDir = dir * stepSize;
vec4 colorSample,colAcc = vec4(0.0,0.0,0.0,0.0);
float lengthAcc = 0.0;
float opacityCorrection = stepSize/sliceSize;
//ray dithering http://marcusbannerman.co.uk/index.php/home/42-articles/97-vol-render-optimizations.html
vec3 samplePos = start.xyz + deltaDir* (fract(sin(gl_FragCoord.x * 12.9898 + gl_FragCoord.y * 78.233) * 43758.5453));
//offset to eight locations surround target: permute top/bottom, anterior/posterior, left/right
float dx = 0.5; //distance from target voxel
vec3 vTAR = vec3( dx, dx, dx)*sliceSize;
vec3 vTAL = vec3( dx, dx,-dx)*sliceSize;
vec3 vTPR = vec3( dx,-dx, dx)*sliceSize;
vec3 vTPL = vec3( dx,-dx,-dx)*sliceSize;
vec3 vBAR = vec3(-dx, dx, dx)*sliceSize;
vec3 vBAL = vec3(-dx, dx,-dx)*sliceSize;
vec3 vBPR = vec3(-dx,-dx, dx)*sliceSize;
vec3 vBPL = vec3(-dx,-dx,-dx)*sliceSize;
for(int i = 0; i < loops; i++) {
if (doBlur) {
colorSample = texture3D(intensityVol,samplePos+vTAR);
colorSample += texture3D(intensityVol,samplePos+vTAL);
colorSample += texture3D(intensityVol,samplePos+vTPR);
colorSample += texture3D(intensityVol,samplePos+vTPL);
colorSample += texture3D(intensityVol,samplePos+vBAR);
colorSample += texture3D(intensityVol,samplePos+vBAL);
colorSample += texture3D(intensityVol,samplePos+vBPR);
colorSample += texture3D(intensityVol,samplePos+vBPL);
colorSample *= 0.125; //average of 8 sample locations
} else
colorSample = texture3D(intensityVol,samplePos);
colorSample.a = 1.0-pow((1.0 - colorSample.a), opacityCorrection);
colorSample.rgb *= colorSample.a;
//accumulate color
colAcc = (1.0 - colAcc.a) * colorSample + colAcc;
samplePos += deltaDir;
lengthAcc += stepSize;
// terminate if opacity > 95% or the ray is outside the volume
if ( lengthAcc >= len || colAcc.a > 0.95 ) break;
}
colAcc.rgb = mix(clearColor,colAcc.rgb,colAcc.a);
gl_FragColor = colAcc;
}