MCMC में उच्च स्वावलंबन का प्रबंधन

मैं R और JAGS का उपयोग करके मेटा-विश्लेषण के लिए एक जटिल जटिल पदानुक्रमित बायेसियन मॉडल का निर्माण कर रहा हूं। थोड़ा सरल बनाने, मॉडल के दो प्रमुख स्तर है जहां है endpoint की वें अवलोकन (इस मामले में जीएम बनाम गैर-जीएम फसल की पैदावार) के एक अध्ययन में , अध्ययन के लिए प्रभाव है ,

y_{i j} = α_{j} + ϵ_{i}

$y_{ij} = \alpha_j + \epsilon_i$

α_{j} = \sum_{h} γ_{h (j)} + ϵ_{j}

$\alpha_j = \sum_h \gamma_{h(j)} + \epsilon_j$

y_{i j}

$y_{ij}$

i

$i$

j

$j$

α_{j}

$\alpha_j$

j

$j$

γ

$\gamma$ विभिन्न अध्ययन स्तर के चर (देश के आर्थिक विकास की स्थिति जहां अध्ययन किया गया था, फसल प्रजातियों, अध्ययन विधि, आदि) कार्यों के एक परिवार द्वारा अनुक्रमित के लिए इफेक्ट होते हैं

, और

रों त्रुटि शब्द हैं। ध्यान दें कि डमी चरों पर

गुणांक नहीं है। इसके बजाय, विभिन्न अध्ययन-स्तरीय मूल्यों के लिए अलग-अलग

चर हैं। उदाहरण के लिए, वहाँ है

विकासशील देशों और के लिए

h

$h$

ϵ

$\epsilon$

γ

$\gamma$

γ

$\gamma$

γ_{d e v e l o p i n g}

$\gamma_{developing}$

γ_{d e v e l o p e d}

$\gamma_{developed}$ विकसित देशों के लिए।

मैं मुख्य रूप से के मूल्यों का आकलन में दिलचस्पी रखता हूँ रों। इसका मतलब है कि मॉडल से अध्ययन-स्तर के चर को छोड़ना एक अच्छा विकल्प नहीं है। $\gamma$

अध्ययन-स्तर के कई चरों के बीच उच्च सहसंबंध है, और मुझे लगता है कि यह मेरी MCMC श्रृंखलाओं में बड़े ऑटोकरेक्लेशन पैदा कर रहा है। यह डायग्नोस्टिक प्लॉट श्रृंखला प्रक्षेपवक्र (बाएं) और परिणामी ऑटोकैरेलेशन (दाएं) को दिखाता है:

स्वतःसंबंध के परिणामस्वरूप, मुझे प्रत्येक 10,000 नमूनों में से 4 श्रृंखलाओं से 60-120 के प्रभावी नमूने आकार मिल रहे हैं।

मेरे दो प्रश्न हैं, एक स्पष्ट रूप से वस्तुनिष्ठ और दूसरा व्यक्तिपरक।

पतले होने के अलावा, अधिक श्रृंखलाओं को जोड़ना, और लंबे समय तक नमूना चलाने वाला, मैं इस ऑटोकॉर्लेशन समस्या का प्रबंधन करने के लिए किन तकनीकों का उपयोग कर सकता हूं? "प्रबंधन" से मेरा मतलब है "उचित समय में उचित अनुमान का उत्पादन करना।" कंप्यूटिंग शक्ति के संदर्भ में, मैं इन मॉडलों को मैकबुक प्रो पर चला रहा हूं।
स्वायत्तता की यह डिग्री कितनी गंभीर है? जॉन क्रूसके के ब्लॉग पर यहाँ और दोनों पर चर्चा से पता चलता है कि, यदि हम अभी मॉडल को बहुत पहले चलाते हैं, तो "क्लैपी ऑटोकरेलेशन संभवतः सभी को छोड़ दिया गया है" (क्रूसके) और इसलिए यह वास्तव में एक बड़ी बात नहीं है।

यहां उस मॉडल के लिए JAGS कोड है, जिसने उपरोक्त प्लॉट का निर्माण किया है, बस अगर किसी को विवरण के माध्यम से उतारा जाना चाहिए, तो वह पर्याप्त रुचि रखता है:

model {
for (i in 1:n) {
    # Study finding = study effect + noise
    # tau = precision (1/variance)
    # nu = normality parameter (higher = more Gaussian)
    y[i] ~ dt(alpha[study[i]], tau[study[i]], nu)
}

nu <- nu_minus_one + 1
nu_minus_one ~ dexp(1/lambda)
lambda <- 30

# Hyperparameters above study effect
for (j in 1:n_study) {
    # Study effect = country-type effect + noise
    alpha_hat[j] <- gamma_countr[countr[j]] + 
                    gamma_studytype[studytype[j]] +
                    gamma_jour[jourtype[j]] +
                    gamma_industry[industrytype[j]]
    alpha[j] ~ dnorm(alpha_hat[j], tau_alpha)
    # Study-level variance
    tau[j] <- 1/sigmasq[j]
    sigmasq[j] ~ dunif(sigmasq_hat[j], sigmasq_hat[j] + pow(sigma_bound, 2))
    sigmasq_hat[j] <- eta_countr[countr[j]] + 
                        eta_studytype[studytype[j]] + 
                        eta_jour[jourtype[j]] +
                        eta_industry[industrytype[j]]
    sigma_hat[j] <- sqrt(sigmasq_hat[j])
}
tau_alpha <- 1/pow(sigma_alpha, 2)
sigma_alpha ~ dunif(0, sigma_alpha_bound)

# Priors for country-type effects
# Developing = 1, developed = 2
for (k in 1:2) {
    gamma_countr[k] ~ dnorm(gamma_prior_exp, tau_countr[k])
    tau_countr[k] <- 1/pow(sigma_countr[k], 2)
    sigma_countr[k] ~ dunif(0, gamma_sigma_bound)
    eta_countr[k] ~ dunif(0, eta_bound)
}

# Priors for study-type effects
# Farmer survey = 1, field trial = 2
for (k in 1:2) {
    gamma_studytype[k] ~ dnorm(gamma_prior_exp, tau_studytype[k])
    tau_studytype[k] <- 1/pow(sigma_studytype[k], 2)
    sigma_studytype[k] ~ dunif(0, gamma_sigma_bound)
    eta_studytype[k] ~ dunif(0, eta_bound)
}

# Priors for journal effects
# Note journal published = 1, journal published = 2
for (k in 1:2) {
    gamma_jour[k] ~ dnorm(gamma_prior_exp, tau_jourtype[k])
    tau_jourtype[k] <- 1/pow(sigma_jourtype[k], 2)
    sigma_jourtype[k] ~ dunif(0, gamma_sigma_bound)
    eta_jour[k] ~ dunif(0, eta_bound)
}

# Priors for industry funding effects
for (k in 1:2) {
    gamma_industry[k] ~ dnorm(gamma_prior_exp, tau_industrytype[k])
    tau_industrytype[k] <- 1/pow(sigma_industrytype[k], 2)
    sigma_industrytype[k] ~ dunif(0, gamma_sigma_bound)
    eta_industry[k] ~ dunif(0, eta_bound)
}
}

— दान हिक्स
स्रोत

इसके लायक होने के लिए, जटिल बहुस्तरीय मॉडल बहुत अधिक कारण हैं कि स्टेन मौजूद हैं, ठीक उसी कारणों से जो आप पहचानते हैं।

— साइकोरैक्स का कहना है कि मोनिका

मैंने शुरुआत में कई महीनों पहले स्टेन में इसे बनाने की कोशिश की थी। अध्ययन में अलग-अलग संख्या में निष्कर्ष शामिल हैं, जो (कम से कम उस समय; मैंने यह देखने के लिए जांच नहीं की है कि क्या चीजें बदल गई हैं) कोड में जटिलता की एक और परत जोड़ने की आवश्यकता है और इसका मतलब है कि स्टेन मैट्रिक्स गणनाओं का लाभ नहीं उठा सकते हैं। यह इतनी तेजी से बनाते हैं।

— डैन हिक्स

मैं गति के बारे में इतना नहीं सोच रहा था, जितनी दक्षता के साथ एचएमसी पीछे की ओर खिसकता है। मेरी समझ यह है कि क्योंकि एचएमसी इतने अधिक जमीन को कवर कर सकता है, प्रत्येक पुनरावृत्ति में कम ऑटोक्रेलेशन है।

— साइकोरैक्स का कहना है कि मोनिका

ओह, हाँ, यह एक दिलचस्प बिंदु है। मैं कोशिश करने के लिए चीजों की अपनी सूची में डाल देंगे।

— डैन हिक्स

User777 के सुझाव के बाद, ऐसा लगता है कि मेरे पहले प्रश्न का उत्तर "स्टेन का उपयोग करें" है। स्टेन में मॉडल को फिर से लिखने के बाद, यहां प्रक्षेपवक्र (जलने के बाद 4 चेन x 5000 पुनरावृत्तियों) हैं:
और ऑटोकॉर्लेशन प्लॉट:

काफी बेहतर! पूर्णता के लिए, यहाँ स्टेन कोड है:

data {                          // Data: Exogenously given information
// Data on totals
int n;                      // Number of distinct finding i
int n_study;                // Number of distinct studies j

// Finding-level data
vector[n] y;                // Endpoint for finding i
int study_n[n_study];       // # findings for study j

// Study-level data
int countr[n_study];        // Country type for study j
int studytype[n_study];     // Study type for study j
int jourtype[n_study];      // Was study j published in a journal?
int industrytype[n_study];  // Was study j funded by industry?

// Top-level constants set in R call
real sigma_alpha_bound;     // Upper bound for noise in alphas
real gamma_prior_exp;       // Prior expected value of gamma
real gamma_sigma_bound;     // Upper bound for noise in gammas
real eta_bound;             // Upper bound for etas
}

transformed data {
// Constants set here
int countr_levels;          // # levels for countr
int study_levels;           // # levels for studytype
int jour_levels;            // # levels for jourtype
int industry_levels;        // # levels for industrytype
countr_levels <- 2;
study_levels <- 2;
jour_levels <- 2;
industry_levels <- 2;
}

parameters {                    // Parameters:  Unobserved variables to be estimated
vector[n_study] alpha;      // Study-level mean
real<lower = 0, upper = sigma_alpha_bound> sigma_alpha;     // Noise in alphas

vector<lower = 0, upper = 100>[n_study] sigma;          // Study-level standard deviation

// Gammas:  contextual effects on study-level means
// Country-type effect and noise in its estimate
vector[countr_levels] gamma_countr;     
vector<lower = 0, upper = gamma_sigma_bound>[countr_levels] sigma_countr;
// Study-type effect and noise in its estimate
vector[study_levels] gamma_study;
vector<lower = 0, upper = gamma_sigma_bound>[study_levels] sigma_study;
vector[jour_levels] gamma_jour;
vector<lower = 0, upper = gamma_sigma_bound>[jour_levels] sigma_jour;
vector[industry_levels] gamma_industry;
vector<lower = 0, upper = gamma_sigma_bound>[industry_levels] sigma_industry;


// Etas:  contextual effects on study-level standard deviation
vector<lower = 0, upper = eta_bound>[countr_levels] eta_countr;
vector<lower = 0, upper = eta_bound>[study_levels] eta_study;
vector<lower = 0, upper = eta_bound>[jour_levels] eta_jour;
vector<lower = 0, upper = eta_bound>[industry_levels] eta_industry;
}

transformed parameters {
vector[n_study] alpha_hat;                  // Fitted alpha, based only on gammas
vector<lower = 0>[n_study] sigma_hat;       // Fitted sd, based only on sigmasq_hat

for (j in 1:n_study) {
    alpha_hat[j] <- gamma_countr[countr[j]] + gamma_study[studytype[j]] + 
                    gamma_jour[jourtype[j]] + gamma_industry[industrytype[j]];
    sigma_hat[j] <- sqrt(eta_countr[countr[j]]^2 + eta_study[studytype[j]]^2 +
                        eta_jour[jourtype[j]] + eta_industry[industrytype[j]]);
}
}

model {
// Technique for working w/ ragged data from Stan manual, page 135
int pos;
pos <- 1;
for (j in 1:n_study) {
    segment(y, pos, study_n[j]) ~ normal(alpha[j], sigma[j]);
    pos <- pos + study_n[j];
}

// Study-level mean = fitted alpha + Gaussian noise
alpha ~ normal(alpha_hat, sigma_alpha);

// Study-level variance = gamma distribution w/ mean sigma_hat
sigma ~ gamma(.1 * sigma_hat, .1);

// Priors for gammas
gamma_countr ~ normal(gamma_prior_exp, sigma_countr);
gamma_study ~ normal(gamma_prior_exp, sigma_study);
gamma_jour ~ normal(gamma_prior_exp, sigma_study);
gamma_industry ~ normal(gamma_prior_exp, sigma_study);
}

— दान हिक्स
स्रोत