प्रतिबिंब
एक गीला शेड बनाने के लिए, आपको पहले एक प्रतिबिंब बनाने की आवश्यकता है।
आप एक प्रतिबिंब जांच या एक मिररफ्लेशन 3 का उपयोग कर सकते हैं लेकिन, मैं यहां एक नकली प्रतिबिंब (क्यूब मैप) का उपयोग करता हूं क्योंकि शेडर का उपयोग तब मोबाइल पर किया जा सकता है।
Shader "Smkgames/TransparentCubeMap" {
Properties {
_Color("Color",Color) = (1,1,1,1)
_Cube ("Cubemap", CUBE) = "" {}
_Metallic("Metallic",Range(0,1)) = 1
_Smoothness("Smoothness",Range(0,1)) = 1
_Alpha("Alpha",Range(0,1)) = 1
}
SubShader {
Tags {"RenderType"="Transparent" "Queue"="Transparent"}
LOD 200
Pass {
ColorMask 0
}
ZWrite Off
Blend SrcAlpha OneMinusSrcAlpha
ColorMask RGB
CGPROGRAM
#pragma surface surf Standard fullforwardshadows alpha:fade
struct Input {
float2 uv_MainTex;
float3 worldRefl;
};
sampler2D _MainTex;
samplerCUBE _Cube;
float4 _Color;
float _Metallic;
float _Smoothness;
float4 _EmissionColor;
float _Alpha;
void surf (Input IN, inout SurfaceOutputStandard o) {
fixed4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color;
o.Albedo = c.rgb * 0.5 * _Color;
o.Emission = texCUBE (_Cube, IN.worldRefl).rgb*_Color;
o.Metallic = _Metallic;
o.Smoothness = _Smoothness;
o.Alpha = _Alpha;
}
ENDCG
}
Fallback "Diffuse"
}
विरूपण
अपने प्रतिबिंब में विकृति को जोड़ने के लिए, आप सामान्य मानचित्र और गुणा कर सकते हैं worldRefl:
float3 distortion = tex2D(_Distortion, IN.uv_Distortion);
o.Emission = texCUBE(_Cube, IN.worldRefl*distortion).rgb
प्रक्रियात्मक आकार
आप प्रक्रियात्मक आकार बनाने के लिए शोर का उपयोग कर सकते हैं :
यहाँ एक फ्रैक्टल ब्राउनियन मोशन (FBM) ट्यूटोरियल है ।
Shader "Smkgames/FbmNoise"
{
Properties
{
_TileAndOffset("Tile and Offset",Vector) = (1,1,0,0)
}
SubShader
{
Tags { "RenderType"="Opaque" }
LOD 100
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
// make fog work
#pragma multi_compile_fog
#include "UnityCG.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 uv : TEXCOORD0;
};
struct v2f
{
float2 uv : TEXCOORD0;
UNITY_FOG_COORDS(1)
float4 vertex : SV_POSITION;
};
float4 _TileAndOffset;
float _Step,_Min,_Ma;
v2f vert (appdata v)
{
v2f o;
o.vertex = UnityObjectToClipPos(v.vertex);
o.uv = v.uv*_TileAndOffset.xy+_TileAndOffset.zw;
UNITY_TRANSFER_FOG(o,o.vertex);
return o;
}
// Author @patriciogv - 2015
// http://patriciogonzalezvivo.com
float random (in float2 st) {
return frac(sin(dot(st.xy,
float2(12.9898,78.233)))*
43758.5453123);
}
// Based on Morgan McGuire @morgan3d
// https://www.shadertoy.com/view/4dS3Wd
float noise (in float2 st) {
float2 i = floor(st);
float2 f = frac(st);
// Four corners in 2D of a tile
float a = random(i);
float b = random(i + float2(1.0, 0.0));
float c = random(i + float2(0.0, 1.0));
float d = random(i + float2(1.0, 1.0));
float2 u = f * f * (3.0 - 2.0 * f);
return lerp(a, b, u.x) +
(c - a)* u.y * (1.0 - u.x) +
(d - b) * u.x * u.y;
}
#define OCTAVES 6
float fbm (in float2 st) {
// Initial values
float value = 0.0;
float amplitude = .5;
float frequency = 0.;
//
// Loop of octaves
for (int i = 0; i < OCTAVES; i++) {
value += amplitude * noise(st);
st *= 2.;
amplitude *= .5;
}
return value;
}
fixed4 frag (v2f i) : SV_Target
{
float2 st =i.uv;
float3 color = float3(0,0,0);
color += fbm(st*3.0);
return float4(color,1.0);
}
ENDCG
}
}
}
उपरोक्त FBM को सीधे आपके shader में उपयोग नहीं किया जाना चाहिए क्योंकि इसमें कई GPU गणनाएँ होती हैं और प्रदर्शन कम हो जाता है। सीधे उपयोग करने के बजाय, आप परिणाम को रेंडरटेक्स्चर के साथ एक बनावट को सौंप सकते हैं ।
Shadertoy कई पास का उपयोग करता है , "बफर" प्रति एक। जैसा कि नाम से संकेत मिलता है, यह पास एक बफर में परिणाम संग्रहीत करता है, जो सिर्फ एक बनावट है। एकता आपको बनावट को भी प्रस्तुत करने देगी।
मास्क बनाना
आप इन कार्यों के साथ एक मोटी और चिकनी मुखौटा बना सकते हैं:
चरण
आउटपुट 1 यदि [A]इससे कम या इसके बराबर है [B], अन्यथा आउटपुट 0 है।
Smoothstep
दो मानों के बीच सुगमता से मिश्रण होता है, जहां एक तीसरा मान उस सीमा के आधार पर होता है, 0 और 1. के बीच मानों का आउटपुट होता है। इसे एक स्मूथ आउटपुट आउटपुट के साथ एक क्लैम्पड प्रतिलोम लार्प के रूप में सोचें।
नतीजा
/* Warning: don't use this shader because this is for preview only.
It has many GPU calculations so if you want use this in your game you should
remove the FBM noise functions or render it to texture, or you can use an FBM texture
*/
//Created By Seyed Morteza Kamaly
Shader "Smkgames/WetShader" {
Properties{
_MainTex("MainTex",2D) = "white"{}
_Distortion("Distortion",2D) = "bump"{}
_Cube("Cubemap", CUBE) = "" {}
_BumpMap("Bumpmap", 2D) = "bump" {}
_Metallic("Metallic",Range(0,1)) = 0
_Smoothness("Smoothness",Range(0,1)) = 1
_ReflectAlpha("ReflectAlpha",Range(0,1)) = 1
scaleX("UV.X scale",Float) = 10.0
scaleY("UV.Y scale",Float) = 10.0
_Smooth("Smooth",Float) = 0.4
_Intensity("Intensity",Float) = 1
}
SubShader{
Tags{ "RenderType" = "Transparent" "Queue" = "Transparent" }
LOD 200
Pass{
ColorMask 0
}
ZWrite Off
Blend SrcAlpha OneMinusSrcAlpha
ColorMask RGB
CGPROGRAM
#pragma surface surf Standard fullforwardshadows alpha:fade
struct Input {
float2 uv_MainTex;
float2 uv_Distortion;
float3 worldRefl;
float2 uv_BumpMap;
INTERNAL_DATA
};
sampler2D _MainTex, _Distortion;
samplerCUBE _Cube;
float _Metallic,_Smoothness;
float4 _EmissionColor;
sampler2D _NormalMap;
uniform fixed scaleX, scaleY, _Smooth, _Intensity,_Alpha,_ReflectAlpha;
static const float2x2 m = float2x2(-0.5, 0.8, 1.7, 0.2);
float hash(float2 n)
{
return frac(sin(dot(n, float2(95.43583, 93.323197))) * 65536.32);
}
float noise(float2 p)
{
float2 i = floor(p);
float2 u = frac(p);
u = u*u*(3.0 - 2.0*u);
float2 d = float2 (1.0, 0.0);
float r = lerp(lerp(hash(i), hash(i + d.xy), u.x), lerp(hash(i + d.yx), hash(i + d.xx), u.x), u.y);
return r*r;
}
float fbm(float2 p)
{
float f = 0.0;
f += 0.500000*(0.5 + 0.5*noise(p));
return f;
}
float fbm2(float2 p)
{
float f = 0.0;
f += 0.500000*(0.6 + 0.45*noise(p)); p = p*2.02; p = mul(p, m);
f += 0.250000*(0.6 + 0.36*noise(p));
return f;
}
void surf(Input IN, inout SurfaceOutputStandard o) {
fixed4 c = tex2D(_MainTex, IN.uv_MainTex);
o.Metallic = _Metallic;
o.Smoothness = _Smoothness;
o.Alpha = 1;
float t = fbm2(float2(IN.uv_MainTex.x*scaleX, IN.uv_MainTex.y*scaleY));
float fbmMask = step(t, _Smooth)*_Intensity;
float3 distortion = tex2D(_Distortion, IN.uv_Distortion);
o.Emission = texCUBE(_Cube, IN.worldRefl*distortion).rgb*_ReflectAlpha*fbmMask;
o.Albedo = float4(1.0, 1.0, 1.0, 1.0)*tex2Dlod(_MainTex, float4(IN.uv_MainTex, 0.0, 0.0));
}
ENDCG
}
Fallback "Diffuse"
}
मैप्स का उपयोग करना
शारीरिक रूप से आधारित छायांकन
यहाँ एक उपयोगी परिभाषा है:
खुरदरापन
वस्तु के सूक्ष्मदर्शी का वर्णन करता है। सफेद 1.0 मोटा और काला 0.0 चिकना होता है। यदि सूक्ष्मदर्शी प्रकाश किरणों को बिखेर सकता है और प्रकाश को मंद और अधिक व्यापक बना सकता है। सतह पर आते ही प्रकाश ऊर्जा की समान मात्रा परावर्तित होती है। इस नक्शे में सबसे कलात्मक स्वतंत्रता है। यहां कोई गलत जवाब नहीं है। यह मानचित्र संपत्ति को सबसे अधिक चरित्र देता है क्योंकि यह सतह का सही-सही वर्णन करता है जैसे खरोंच, अंगुलियों के निशान, धब्बा, चूना आदि।
चमक
यह नक्शा खुरदुरे नक्शे का विलोम है। सफेद 1.0 चिकना और 0.0 काला मोटा होता है। वस्तु के सूक्ष्मदर्शी का वर्णन करता है। यदि सूक्ष्मदर्शी प्रकाश किरणों को बिखेर सकता है और प्रकाश को मंद और अधिक व्यापक बना सकता है। सतह पर आते ही प्रकाश ऊर्जा की समान मात्रा परावर्तित होती है। इस नक्शे में सबसे कलात्मक स्वतंत्रता है। यहां कोई गलत जवाब नहीं है। यह मानचित्र संपत्ति को सबसे अधिक चरित्र देता है क्योंकि यह सतह का सही-सही वर्णन करता है जैसे खरोंच, अंगुलियों के निशान, धब्बा, चूना आदि।
स्पेक्युलर
इस मानचित्र में धातु और डाइलेक्ट्रिक्स (गैर धातु) दोनों सतहों के लिए परावर्तन जानकारी है। यह धातु / खुरदरी और कल्पना / चमक वर्कफ़्लो में एक महत्वपूर्ण अंतर है। वही नियम लागू होते हैं। आपको धातुओं के लिए मापा मूल्यों का उपयोग करने की आवश्यकता है और अधिकांश सभी ढांकता हुआ 0.04 - 4% रेंज के साथ गिर जाएगा। यदि धातु पर गंदगी है, तो प्रतिबिंबित मूल्य को भी कम करने की आवश्यकता है। हालाँकि, आप ढांकता हुआ सामग्री के लिए विशिष्ट मानचित्र में भिन्न मान जोड़ सकते हैं क्योंकि आपके पास मानचित्र को लिखने के लिए नियंत्रण है।
https://forum.allegorithmic.com/index.php?topic=3243.0
बेअदबी
मुझे पता नहीं क्यों, लेकिन एकता मानक shader में एक चिकनाई नक्शा नहीं है, इसलिए मैंने एक बुनियादी shader लिखा और इस नक्शे को जोड़ा।
Shader "Smkgames/SimpleSurface" {
Properties {
_Color ("Color", Color) = (1,1,1,1)
_MainTex ("Albedo (RGB)", 2D) = "white" {}
_GlossMap("GlossMap",2D) = "white"{}
_Glossiness ("Smoothness", Float) = 1.5
_Metallic ("Metallic", Float) = 0.5
_MetallicMap("MetallicMap",2D) = "white"{}
}
SubShader {
Tags { "RenderType"="Opaque" }
LOD 200
CGPROGRAM
#pragma surface surf Standard fullforwardshadows
#pragma target 3.0
sampler2D _MainTex;
struct Input {
float2 uv_MainTex;
};
half _Glossiness,_Metallic;
fixed4 _Color;
sampler2D _GlossMap,_MetallicMap;
UNITY_INSTANCING_CBUFFER_START(Props)
UNITY_INSTANCING_CBUFFER_END
void surf (Input IN, inout SurfaceOutputStandard o) {
fixed4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color;
o.Albedo = c.rgb;
o.Metallic = _Metallic*tex2D(_MetallicMap,IN.uv_MainTex);
o.Smoothness = _Glossiness*tex2D(_GlossMap,IN.uv_MainTex);
o.Alpha = c.a;
}
ENDCG
}
FallBack "Diffuse"
}
मुझे लगता है कि एकता में खुरदरापन नहीं है, इसमें केवल धातु है, लेकिन अल्फा चैनल खुरदरापन के लिए है और लाल चैनल धातु के लिए है। आप चिकनाई के साथ तीव्रता को बदल सकते हैं।
GitHub पर स्रोत ।
उपयोगी कड़ियाँ
https://80.lv/articles/how-to-create-wet-mud-in-substance-designer/
https://www.fxguide.com/featured/game-environments-partc/
