Coq सबूत में Cofix को खत्म करना

Question

Coq में coinductive प्रकारों का उपयोग करते हुए कुछ बुनियादी गुणों को साबित करने की कोशिश करते हुए, मैं निम्नलिखित समस्या में चल रहा हूं और मैं इसके आसपास नहीं पहुंच सकता। मैंने समस्या को एक सरल Coq स्क्रिप्ट में निम्न प्रकार से आसुत किया है।

टाइप ए के तत्वों के साथ लेबल वाली शाखाओं के साथ टाइप ट्री संभवतः अनंत पेड़ों को परिभाषित करता है । एक शाखा के सभी तत्वों के लिए परिभाषित करने की आवश्यकता नहीं एक । मान Univ हमेशा परिभाषित सभी A शाखाओं के साथ अनंत पेड़ है। isUniv परीक्षण हैं कि कोई पेड़ के बराबर है Univ । लेम्मा जो यह बताता है विश्वविद्यालय वास्तव में करता संतुष्ट isUniv ।

Parameter A : Set.

CoInductive Tree: Set := Node : (A -> option Tree) -> Tree.

Definition derv (a : A) (t: Tree): option Tree :=
  match t with Node f => f a end.

CoFixpoint Univ : Tree := Node (fun _ => Some Univ).

CoInductive isUniv : Tree -> Prop :=
  isuniv : forall (nf : A -> option Tree) (a : A) (t : Tree), 
    nf a = Some t -> 
    isUniv t -> 
    isUniv (Node nf).

Lemma UnivIsUniv : isUniv Univ.
Proof.
  cofix CH.    (* this application of cofix is fine *)
  unfold Univ. 

Admitted.

इस बिंदु पर मैं सबूत छोड़ देता हूं। वर्तमान लक्ष्य है:

CH : isUniv Univ
============================
isUniv (cofix Univ  : Tree := Node (fun _ : A => Some Univ))

मुझे नहीं पता कि उत्पादन ( लक्ष्य कुछ) करने के लिए लक्ष्य में cofix को खत्म करने के लिए कौन सी रणनीति लागू करनी है ताकि मैं isuniv को लागू कर सकूं ।

क्या कोई इस लेम्मा को साबित करने में मदद कर सकता है? ऐसी स्थिति में cofix
को खत्म करने के मानक तरीके क्या हैं ?

Comments

टैग "इंटरएक्टिव-प्रूफ" पर्याप्त नहीं है, क्योंकि यह आम तौर पर उनकी जटिलता-सिद्धांत संबंधी अर्थों में इंटरैक्टिव प्रूफ सिस्टम को संदर्भित करता है। मुझे लगता है कि सही शब्द "इंटरैक्टिव-प्रमेय-साबित", या "प्रमेय-साबित" है।

— Iddo Tzameret

फिक्स्ड, "प्रूफ-असिस्टेंट" का उपयोग करते हुए

— डेव क्लार्क

Answer 1

आप एक सहायक फ़ंक्शन का उपयोग करके cofix को समाप्त कर सकते हैं जो पैटर्न ट्री से मेल खाता है।

Definition TT (t:Tree) :=
  match t with
    | Node o => Node o
  end.

Lemma TTid : forall t: Tree, t = TT t.
  intro t.
  destruct t.
  reflexivity.
  Qed.

Lemma UnivIsUniv : isUniv Univ.
Proof.
  cofix.
  rewrite TTid.
  unfold TT.
  unfold Univ.

आप इस लक्ष्य को प्राप्त करेंगे, जो कि एक कदम है।

  UnivIsUniv : isUniv Univ
  ============================
   isUniv
     (Node
        (fun _ : A =>
         Some (cofix Univ  : Tree := Node (fun _ : A => Some Univ))))

मैंने इस तकनीक को http://adam.chlipala.net/cpdt/html/Coinductive.html से अनुकूलित किया

Comments

इसके लिए धन्यवाद। मैं उस पृष्ठ को उसी समय देख रहा था जब आपका उत्तर आया था। पागल, लेकिन यह काम करने लगता है ... और फिर मैं थोड़ा और अटक जाता हूं, लेकिन मैं थोड़ी देर के लिए उसके खिलाफ अपना सिर फोड़ूंगा।

— डेव क्लार्क

Answer 2

(* I post my answer as a Coq file. In it I show that supercoooldave's
   definition of a universal tree is not what he intended. His isUniv
   means "the tree has an infinite branch". I provide the correct
   definition, show that the universal tree is universal according to
   the new definition, and I provide counter-examples to
   supercooldave's definition. I also point out that the universal
   tree of branching type A has an infinite path iff A is inhabited.
   *)

Set Implicit Arguments.

CoInductive Tree (A : Set): Set := Node : (A -> option (Tree A)) -> Tree A.

Definition child (A : Set) (t : Tree A) (a : A) :=
  match t with
    Node f => f a
  end.

(* We consider two trees, one is the universal tree on A (always
   branches out fully), and the other is a binary tree which always
   branches to one side and not to the other, so it is like an
   infinite path with branches of length 1 shooting off at each node.  *)

CoFixpoint Univ (A : Set) : Tree A := Node (fun _ => Some (Univ A)).

CoFixpoint Thread : Tree (bool) :=
  Node (fun (b : bool) => if b then Some Thread else None).

(* The original definition of supercooldave should be called "has an
   infinite path", so we rename it to "hasInfinitePath". *)
CoInductive hasInfinitePath (A : Set) : Tree A -> Prop :=
  haspath : forall (f : A -> option (Tree A)) (a : A) (t : Tree A),
    f a = Some t ->
    hasInfinitePath t -> 
    hasInfinitePath (Node f).

(* The correct definition of universal tree. *)
CoInductive isUniv (A : Set) : Tree A -> Prop :=
  isuniv : forall (f : A -> option (Tree A)),
    (forall  a, exists t, f a = Some t /\ isUniv t) -> 
    isUniv (Node f).

(* Technicalities that allow us to get coinductive proofs done. *)
Definition TT (A : Set) (t : Tree A) :=
  match t with
    | Node o => Node o
  end.

Lemma TTid (A : Set) : forall t: Tree A, t = TT t.
  intros A t.
  destruct t.
  reflexivity.
  Qed.

(* Thread has an infinite path. *)
Lemma ThreadHasInfinitePath : hasInfinitePath Thread.
Proof.
  cofix H.
  rewrite TTid.
  unfold TT.
  unfold Thread.
  (* there is a path down the "true" branch leading to Thread. *)
  apply haspath with (a := true) (t := Thread).
  auto.
  auto.
Qed.

(* Auxiliary lemma *)
Lemma univChildNotNone (A : Set) (t : Tree A) (a : A):
  isUniv t -> (child t a <> None).
Proof.
  intros A t a [f H].
  destruct (H a) as [u [G _]].
  unfold child.
  rewrite G.
  discriminate.
Qed.

(* Thread is not universal. *)
Lemma ThreadNotUniversal: ~ (isUniv Thread).
Proof.
  unfold not.
  intro H.
  eapply univChildNotNone with (t := Thread) (a := false).
  auto.
  unfold Thread, child.
  auto.
Qed.

(* Now let us show that Univ is universal. *)
Lemma univIsuniv (A : Set): isUniv (Univ A).
Proof.
  intro A.
  cofix H.
  rewrite TTid.
  unfold TT.
  unfold Univ.
  apply isuniv.
  intro a.
  exists (Univ A).
  auto.
Qed.

(* By the way, it need not be the case that a universal tree has
   an infinite path! In fact, the universal tree of branching type
   A has an infinite path iff A is inhabited. *)

Lemma whenUnivHasInfiniteBranch (A : Set):
  hasInfinitePath (Univ A) <-> exists a : A, True.
Proof.
  intro A.
  split.
  intro H.
  destruct H as [f a t _].
  exists a.
  trivial.
  intros [a _].
  cofix H.
  rewrite TTid.
  unfold TT.
  unfold Univ.
  apply haspath with (t := Univ A); auto.
Qed.

Comments

कुछ हद तक शर्मनाक प्रतिक्रिया के लिए धन्यवाद। मैं एक समस्या में बसा हुआ था, लेकिन मैं उस तरह से चालाकी करने में कामयाब रहा। आश्चर्यजनक रूप से, ब्रह्मांड सामने नहीं आया।

— डेव क्लार्क

खैर, मैं अपनी प्रतिक्रिया से शर्मिंदा नहीं हूं :-) मुझे लगा कि अगर मैं एक देता हूं तो मैं एक व्यापक प्रतिक्रिया दे सकता हूं।

— बाउर

आपकी प्रतिक्रिया मेरे लिए शर्मनाक थी। लेकिन निश्चित रूप से बहुत सराहना की।

— डेव क्लार्क

मैं मजाक कर रहा था ... किसी भी तरह, इस बारे में शर्मिंदा होने की कोई बात नहीं है। मैंने और गलतियाँ की हैं। इसके अलावा, वेब लोगों को सोचने से पहले पोस्ट करने के लिए आमंत्रित करता है। मैंने स्वयं यहां आपकी परिभाषा का एक गलत निर्धारण पोस्ट किया है, लेकिन सौभाग्य से मैंने इसे आपके द्वारा किए जाने से पहले देखा।

— बाउर