जवाबों:
तुम्हारा मतलब है:
Wscript.Echo "Like this?"यदि आप wscript.exe(.vbs एक्सटेंशन के लिए डिफ़ॉल्ट हैंडलर) के तहत इसे चलाते हैं , तो यदि आप स्क्रिप्ट पर डबल-क्लिक करते हैं तो आपको क्या मिलेगा) आपको इसमें अपने पाठ के साथ एक "मैसेजबॉक्स" संवाद मिलेगा। यदि आप इसे चलाते हैं cscript.exeतो आपको अपने कंसोल विंडो में आउटपुट मिलेगा।
WScript.Echo जाना चाहिए WScriptया नहीं CScript। यही कारण है कि, वहाँ नहीं है CScript.Echo, मामले में भविष्य के googlers आश्चर्य है। ( बहुत खुश msgboxes चले गए हैं [जब cscript] के साथ , हालांकि, धन्यवाद।)
WScript.Echo। मुझे लगता है, अगर आप पूरी तरह से WScript के भीतर रहना चाहते थे, तो आप एक्सबॉक्स की तरह एक भयानक प्रक्रिया से कुछ भयानक तरीके से चकमा दे सकते थे, MessageBox को बंद करने के लिए मूल प्रक्रिया को "SendKeys" करने के लिए।
popupविधि मिली । बहुत ही समान है, echoलेकिन यह आपको एक टाइमआउट निर्दिष्ट करने की अनुमति देता है जिसके बाद यह स्वचालित रूप से पॉपअप बॉक्स को बंद कर देगा। बहुत सुविधाजनक और प्रयोग करने में आसान: Technet.microsoft.com/en-us/library/ee156593.aspx
यह ड्रैगन-आईटी लिपियों और कोड रिपोजिटरी पर पाया गया था ।
आप इसे निम्न के साथ कर सकते हैं और cscript / wscript अंतर से दूर रह सकते हैं और आपको एक ही कंसोल आउटपुट प्राप्त करने की अनुमति देता है जो एक बैच फ़ाइल में होगा। यह मदद कर सकता है यदि आपका कॉलिंग VBS एक बैच फ़ाइल से है और इसे सहज दिखने की आवश्यकता है।
Set fso = CreateObject ("Scripting.FileSystemObject")
Set stdout = fso.GetStandardStream (1)
Set stderr = fso.GetStandardStream (2)
stdout.WriteLine "This will go to standard output."
stderr.WriteLine "This will go to error output."WScript.Echo। वास्तव में, अंतर बढ़ाया जाता है, क्योंकि स्क्रिप्ट अब WScript के तहत बिल्कुल नहीं चलेगी। इसकी एक वैध तकनीक जिसके उपयोग हैं, उदाहरण के लिए अगर किसी को StdErr पर लिखना है, लेकिन इस उत्तर के संदर्भ में, यह भ्रामक है।
WScript.Echo: cscript //b foobar.vbs चलाता है foobar.vbsकिसी भी सांत्वना उत्पादन के बिना, लेकिन रोब की विधि द्वारा आप उत्पादन भी हो सकता है जब गुजर \\bकरने के लिएcscript.exe
आपको केवल wscript के बजाय cscript को बल देने की आवश्यकता है। मैं हमेशा इस टेम्पलेट का उपयोग करता हूं। फ़ंक्शन ForceConsole () आपके vbs को सिस्क्रिप्ट में निष्पादित करेगा, साथ ही आपके पास टेक्स्ट को प्रिंट और स्कैन करने के लिए अच्छा उपनाम है।
Set oWSH = CreateObject("WScript.Shell")
vbsInterpreter = "cscript.exe"
Call ForceConsole()
Function printf(txt)
WScript.StdOut.WriteLine txt
End Function
Function printl(txt)
WScript.StdOut.Write txt
End Function
Function scanf()
scanf = LCase(WScript.StdIn.ReadLine)
End Function
Function wait(n)
WScript.Sleep Int(n * 1000)
End Function
Function ForceConsole()
If InStr(LCase(WScript.FullName), vbsInterpreter) = 0 Then
oWSH.Run vbsInterpreter & " //NoLogo " & Chr(34) & WScript.ScriptFullName & Chr(34)
WScript.Quit
End If
End Function
Function cls()
For i = 1 To 50
printf ""
Next
End Function
printf " _____ _ _ _____ _ _____ _ _ "
printf "| _ |_| |_ ___ ___| |_ _ _ _| | | __|___ ___|_|___| |_ "
printf "| | | '_| . | | --| | | | . | |__ | _| _| | . | _|"
printf "|__|__|_|_,_|___|_|_|_____|_____|___| |_____|___|_| |_| _|_| "
printf " |_| v1.0"
printl " Enter your name:"
MyVar = scanf
cls
printf "Your name is: " & MyVar
wait(5)मैं इस पोस्ट पर आया और एक दृष्टिकोण पर वापस गया जो मैंने कुछ समय पहले उपयोग किया था जो @ MadAntrax के समान है।
मुख्य अंतर यह है कि यह एक वीबीएसस्क्रिप्ट उपयोगकर्ता-परिभाषित वर्ग का उपयोग करता है जो सीएसस्क्रिप्ट पर स्विच करने और पाठ को कंसोल पर आउटपुट करने के लिए सभी तर्क को लपेटता है, इसलिए यह मुख्य स्क्रिप्ट को थोड़ा क्लीनर बनाता है।
यह मानता है कि आपका उद्देश्य संदेश बॉक्स पर जाने के बजाय कंसोल को आउटपुट स्ट्रीम करना है।
CCONSOLE वर्ग नीचे है। इसका उपयोग करने के लिए, अपनी स्क्रिप्ट के अंत में पूरी कक्षा को शामिल करें, और फिर इसे स्क्रिप्ट की शुरुआत में तुरंत लिख दें। यहाँ एक उदाहरण है:
Option Explicit
'// Instantiate the console object, this automatically switches to CSCript if required
Dim CONS: Set CONS = New cCONSOLE
'// Now we can use the Consol object to write to and read from the console
With CONS
'// Simply write a line
.print "CSCRIPT Console demo script"
'// Arguments are passed through correctly, if present
.Print "Arg count=" & wscript.arguments.count
'// List all the arguments on the console log
dim ix
for ix = 0 to wscript.arguments.count -1
.print "Arg(" & ix & ")=" & wscript.arguments(ix)
next
'// Prompt for some text from the user
dim sMsg : sMsg = .prompt( "Enter any text:" )
'// Write out the text in a box
.Box sMsg
'// Pause with the message "Hit enter to continue"
.Pause
End With
'= =========== End of script - the cCONSOLE class code follows hereयहाँ cCONSOLE वर्ग के लिए कोड है
CLASS cCONSOLE
'= =================================================================
'=
'= This class provides automatic switch to CScript and has methods
'= to write to and read from the CSCript console. It transparently
'= switches to CScript if the script has been started in WScript.
'=
'= =================================================================
Private oOUT
Private oIN
Private Sub Class_Initialize()
'= Run on creation of the cCONSOLE object, checks for cScript operation
'= Check to make sure we are running under CScript, if not restart
'= then run using CScript and terminate this instance.
dim oShell
set oShell = CreateObject("WScript.Shell")
If InStr( LCase( WScript.FullName ), "cscript.exe" ) = 0 Then
'= Not running under CSCRIPT
'= Get the arguments on the command line and build an argument list
dim ArgList, IX
ArgList = ""
For IX = 0 to wscript.arguments.count - 1
'= Add the argument to the list, enclosing it in quotes
argList = argList & " """ & wscript.arguments.item(IX) & """"
next
'= Now restart with CScript and terminate this instance
oShell.Run "cscript.exe //NoLogo """ & WScript.ScriptName & """ " & arglist
WScript.Quit
End If
'= Running under CScript so OK to continue
set oShell = Nothing
'= Save references to stdout and stdin for use with Print, Read and Prompt
set oOUT = WScript.StdOut
set oIN = WScript.StdIn
'= Print out the startup box
StartBox
BoxLine Wscript.ScriptName
BoxLine "Started at " & Now()
EndBox
End Sub
'= Utility methods for writing a box to the console with text in it
Public Sub StartBox()
Print " " & String(73, "_")
Print " |" & Space(73) & "|"
End Sub
Public Sub BoxLine(sText)
Print Left(" |" & Centre( sText, 74) , 75) & "|"
End Sub
Public Sub EndBox()
Print " |" & String(73, "_") & "|"
Print ""
End Sub
Public Sub Box(sMsg)
StartBox
BoxLine sMsg
EndBox
End Sub
'= END OF Box utility methods
'= Utility to center given text padded out to a certain width of text
'= assuming font is monospaced
Public Function Centre(sText, nWidth)
dim iLen
iLen = len(sText)
'= Check for overflow
if ilen > nwidth then Centre = sText : exit Function
'= Calculate padding either side
iLen = ( nWidth - iLen ) / 2
'= Generate text with padding
Centre = left( space(iLen) & sText & space(ilen), nWidth )
End Function
'= Method to write a line of text to the console
Public Sub Print( sText )
oOUT.WriteLine sText
End Sub
'= Method to prompt user input from the console with a message
Public Function Prompt( sText )
oOUT.Write sText
Prompt = Read()
End Function
'= Method to read input from the console with no prompting
Public Function Read()
Read = oIN.ReadLine
End Function
'= Method to provide wait for n seconds
Public Sub Wait(nSeconds)
WScript.Sleep nSeconds * 1000
End Sub
'= Method to pause for user to continue
Public Sub Pause
Prompt "Hit enter to continue..."
End Sub
END CLASSटेक्स्ट को कंसोल में आउटपुट करने के पांच तरीके हैं:
Dim StdOut : Set StdOut = CreateObject("Scripting.FileSystemObject").GetStandardStream(1)
WScript.Echo "Hello"
WScript.StdOut.Write "Hello"
WScript.StdOut.WriteLine "Hello"
Stdout.WriteLine "Hello"
Stdout.Write "Hello"WScript.Echo कंसोल के लिए आउटपुट करेगा, लेकिन केवल तभी जब स्क्रिप्ट को स्क्रिप्टस्क्रिप्ट का उपयोग शुरू किया जाए। यदि यह wscript.exe का उपयोग करना शुरू कर देता है तो यह संदेश बॉक्सों के लिए आउटपुट होगा।
WScript.StdOut.Write और WScript.StdOut.WriteLine हमेशा कंसोल के लिए आउटपुट देगा।
StdOut.Write और StdOut.WriteLine भी हमेशा कंसोल के लिए आउटपुट देगा। इसके लिए अतिरिक्त ऑब्जेक्ट निर्माण की आवश्यकता होती है लेकिन यह WScript.Echo की तुलना में लगभग 10% तेज है।
MsgBox("text")याMsgBox(object.property)लेकिनWscript.Echoलिखने के लिए आसान है। धन्यवाद।