मुझे कई वैकल्पिक नामित तर्कों को स्वीकार करने के लिए अपने बैट फ़ाइल की आवश्यकता है।
mycmd.bat man1 man2 -username alice -otheroption
उदाहरण के लिए मेरे आदेश में 2 अनिवार्य पैरामीटर हैं, और दो वैकल्पिक पैरामीटर (-username) जिसमें एलिस और लॉरथेलियन का तर्क मूल्य है:
मैं इन मूल्यों को चर में बांधने में सक्षम होना चाहता हूं।
बस जो पहले से ही इसे हल कर लिया है, उसे कॉल आउट करें। मैन इन बैट फाइलें एक दर्द है।
http://web.archive.org/web/20090403050231/http://www.pcguide.com/vb/showthread.php?t=52323।
जवाबों:
हालाँकि मैं @AlekDavis की टिप्पणी से सहमत हूं , फिर भी NT शेल में ऐसा करने के कई तरीके हैं।
मैं SHIFT कमांड और IF सशर्त ब्रांचिंग का लाभ उठाऊंगा, कुछ इस तरह ...
@ECHO OFF
SET man1=%1
SET man2=%2
SHIFT & SHIFT
:loop
IF NOT "%1"=="" (
IF "%1"=="-username" (
SET user=%2
SHIFT
)
IF "%1"=="-otheroption" (
SET other=%2
SHIFT
)
SHIFT
GOTO :loop
)
ECHO Man1 = %man1%
ECHO Man2 = %man2%
ECHO Username = %user%
ECHO Other option = %other%
REM ...do stuff here...
:theend
SHIFT /2arg 2 से शुरू होने वाली शिफ्ट्स। यह दो बार शिफ्ट नहीं होती है। यह के साथ प्रतिस्थापित नहीं किया जाना चाहिए SHIFT & SHIFT?
mycmd.bat -username anyvalue -username myName -otheroption othervalue। परिणाम उपयोगकर्ता = myName, अन्य = othervalue होना चाहिए; लेकिन कोड उपयोगकर्ता = -username, अन्य = othervalue देता है। बग को बदलकर तय किया SHIFT /2गया है SHIFT & SHIFT।
;इसके बारे में गलत है - इसका उपयोग इसके स्थान पर नहीं किया जा सकता है &।
%1और %2"उपयोग" किया गया है। ख) SHIFTलाइन 11 में एकल %2नीचे की स्थिति का %1मान बढ़ाता है और फिर (फिर) के रूप में उपलब्ध है , और "अप्रयुक्त" मूल्य के %3रूप में उपलब्ध है %2। ग) IFलाइन 13 में यह पहले से ही "प्रयुक्त" मूल्य देखता है %2जिसमें से अब है %1। d) यदि लाइन 10 से "उपयोगकर्ता-नाम" दिखता है "-otheroption", तो इसे फिर से उपयोग किया जाएगा और otherनए मूल्य में सेट किया जाएगा %2, जो संभवतः अगले विकल्प का नाम था। --->
-otheroptionएक मूल्य का पालन नहीं किया गया था, इसलिए यह संभवतः एक -Flagप्रकार के विकल्प के रूप में था , और 2 तर्क का उपभोग नहीं करना चाहिए। 3: यदि तर्क %1को आंतरिक IFकथनों द्वारा नियंत्रित नहीं किया जाता है , तो इसे चुपचाप नजरअंदाज कर दिया जाता है। कोड को संभवतः एक संदेश प्रदर्शित करना चाहिए जो यह दर्शाता है कि यह एक वैध विकल्प नहीं था। यह आवश्यक हो सकता है SHIFTऔर आवश्यक GOTO :loopविवरणों को आंतरिक IFकथनों में जोड़कर या कथन जोड़कर किया जा सकता है ELSE।
चयनित उत्तर काम करता है, लेकिन यह कुछ सुधार का उपयोग कर सकता है।
मेरा समाधान एक विकल्प चर के निर्माण पर निर्भर करता है जो सभी विकल्पों और उनकी चूक को परिभाषित करता है। विकल्प का उपयोग यह जांचने के लिए भी किया जाता है कि क्या आपूर्ति का विकल्प मान्य है। कोड की एक जबरदस्त मात्रा को विकल्प के रूप में समान नाम वाले चर में विकल्प मानों को संग्रहीत करके बचाया जाता है। कितने विकल्पों को परिभाषित किया गया है, इसकी परवाह किए बिना कोड की मात्रा स्थिर है; केवल विकल्प की परिभाषा को बदलना होगा।
EDIT - इसके अलावा, यदि अनिवार्य स्थिति संबंधी तर्कों की संख्या में परिवर्तन होता है, तो लूप कोड बदलना होगा। उदाहरण के लिए, अक्सर सभी तर्कों का नाम लिया जाता है, जिस स्थिति में आप 3 के बजाय 1 से शुरू होने वाले तर्कों को पार्स करना चाहते हैं। इसलिए: लूप के भीतर, सभी 3 1 हो जाते हैं, और 4 2 हो जाते हैं।
@echo off
setlocal enableDelayedExpansion
:: Define the option names along with default values, using a <space>
:: delimiter between options. I'm using some generic option names, but
:: normally each option would have a meaningful name.
::
:: Each option has the format -name:[default]
::
:: The option names are NOT case sensitive.
::
:: Options that have a default value expect the subsequent command line
:: argument to contain the value. If the option is not provided then the
:: option is set to the default. If the default contains spaces, contains
:: special characters, or starts with a colon, then it should be enclosed
:: within double quotes. The default can be undefined by specifying the
:: default as empty quotes "".
:: NOTE - defaults cannot contain * or ? with this solution.
::
:: Options that are specified without any default value are simply flags
:: that are either defined or undefined. All flags start out undefined by
:: default and become defined if the option is supplied.
::
:: The order of the definitions is not important.
::
set "options=-username:/ -option2:"" -option3:"three word default" -flag1: -flag2:"
:: Set the default option values
for %%O in (%options%) do for /f "tokens=1,* delims=:" %%A in ("%%O") do set "%%A=%%~B"
:loop
:: Validate and store the options, one at a time, using a loop.
:: Options start at arg 3 in this example. Each SHIFT is done starting at
:: the first option so required args are preserved.
::
if not "%~3"=="" (
set "test=!options:*%~3:=! "
if "!test!"=="!options! " (
rem No substitution was made so this is an invalid option.
rem Error handling goes here.
rem I will simply echo an error message.
echo Error: Invalid option %~3
) else if "!test:~0,1!"==" " (
rem Set the flag option using the option name.
rem The value doesn't matter, it just needs to be defined.
set "%~3=1"
) else (
rem Set the option value using the option as the name.
rem and the next arg as the value
set "%~3=%~4"
shift /3
)
shift /3
goto :loop
)
:: Now all supplied options are stored in variables whose names are the
:: option names. Missing options have the default value, or are undefined if
:: there is no default.
:: The required args are still available in %1 and %2 (and %0 is also preserved)
:: For this example I will simply echo all the option values,
:: assuming any variable starting with - is an option.
::
set -
:: To get the value of a single parameter, just remember to include the `-`
echo The value of -username is: !-username!
वास्तव में इतना कोड नहीं है। ऊपर दिए गए अधिकांश कोड टिप्पणी हैं। यहां ठीक उसी कोड है, टिप्पणियों के बिना।
@echo off
setlocal enableDelayedExpansion
set "options=-username:/ -option2:"" -option3:"three word default" -flag1: -flag2:"
for %%O in (%options%) do for /f "tokens=1,* delims=:" %%A in ("%%O") do set "%%A=%%~B"
:loop
if not "%~3"=="" (
set "test=!options:*%~3:=! "
if "!test!"=="!options! " (
echo Error: Invalid option %~3
) else if "!test:~0,1!"==" " (
set "%~3=1"
) else (
set "%~3=%~4"
shift /3
)
shift /3
goto :loop
)
set -
:: To get the value of a single parameter, just remember to include the `-`
echo The value of -username is: !-username!
यह समाधान विंडोज बैच के भीतर यूनिक्स शैली के तर्क प्रदान करता है। यह विंडोज के लिए आदर्श नहीं है - बैच में आमतौर पर आवश्यक तर्कों से पहले के विकल्प होते हैं और विकल्पों के साथ उपसर्ग होता है /।
इस समाधान में उपयोग की जाने वाली तकनीकों को आसानी से विंडोज शैली के विकल्पों के लिए अनुकूलित किया जाता है।
%1, और यह तब तक जारी रहता है जब तक कि आर्ग 1 के साथ शुरू नहीं होता है//। SET /VAR=VALUEविफल रहता है SET "/VAR=VALUE"काम करता है। मैं पहले से ही अपने समाधान में यह कर रहा हूँ।/। इस सीमा को स्पष्ट रूप से परिभाषित //विकल्प को नियोजित करके समाप्त किया जा सकता है जो विकल्प पार्सिंग लूप से बाहर निकलने के लिए एक संकेत के रूप में कार्य करता है। //"विकल्प" के लिए कुछ भी संग्रहीत नहीं किया जाएगा ।
2015-12-28 अपडेट करें:! विकल्प मानों के लिए समर्थन
ऊपर दिए गए कोड में, प्रत्येक तर्क का विस्तार किया जाता है जबकि विलंबित विस्तार को सक्षम किया जाता है, जिसका अर्थ है कि !सबसे अधिक संभावना छीन ली गई है, या जैसे कुछ !var!का विस्तार किया गया है। इसके अलावा, ^अगर !मौजूद है तो भी छीन लिया जा सकता है। निम्न-टिप्पणी वाले कोड में निम्नलिखित छोटा संशोधन सीमा को हटा देता है !और ^विकल्प मानों में संरक्षित हैं।
@echo off
setlocal enableDelayedExpansion
set "options=-username:/ -option2:"" -option3:"three word default" -flag1: -flag2:"
for %%O in (%options%) do for /f "tokens=1,* delims=:" %%A in ("%%O") do set "%%A=%%~B"
:loop
if not "%~3"=="" (
set "test=!options:*%~3:=! "
if "!test!"=="!options! " (
echo Error: Invalid option %~3
) else if "!test:~0,1!"==" " (
set "%~3=1"
) else (
setlocal disableDelayedExpansion
set "val=%~4"
call :escapeVal
setlocal enableDelayedExpansion
for /f delims^=^ eol^= %%A in ("!val!") do endlocal&endlocal&set "%~3=%%A" !
shift /3
)
shift /3
goto :loop
)
goto :endArgs
:escapeVal
set "val=%val:^=^^%"
set "val=%val:!=^!%"
exit /b
:endArgs
set -
:: To get the value of a single parameter, just remember to include the `-`
echo The value of -username is: !-username!
यदि आप वैकल्पिक तर्कों का उपयोग करना चाहते हैं, लेकिन तर्कों का नाम नहीं है, तो यह दृष्टिकोण मेरे लिए काम करता है। मुझे लगता है कि यह पालन करने के लिए बहुत आसान कोड है।
REM Get argument values. If not specified, use default values.
IF "%1"=="" ( SET "DatabaseServer=localhost" ) ELSE ( SET "DatabaseServer=%1" )
IF "%2"=="" ( SET "DatabaseName=MyDatabase" ) ELSE ( SET "DatabaseName=%2" )
REM Do work
ECHO Database Server = %DatabaseServer%
ECHO Database Name = %DatabaseName%
IF "%1"==""यदि तर्क में उद्धरण शामिल हैं तो विफल हो जाएगा। इसके बजाय किसी अन्य गैर-विशेष प्रतीक का उपयोग करें, जैसे ._ = [] # आदि
पेशेवरों
%1, %2... %*चातुर्य में/argऔर -argशैली के लिए काम करता हैविपक्ष
setlocalस्थानीय स्कूपिंग के लिए उपयोग करें या एक साथ :CLEAR-ARGSदिनचर्या लिखें !--forceकरने के लिए -f)""तर्क समर्थन नहींयहाँ एक उदाहरण है कि निम्न तर्क कैसे .bat चर से संबंधित हैं:
>> testargs.bat /b 3 -c /d /e /f /g /h /i /j /k /bar 5 /foo "c:\"
echo %* | /b 3 -c /d /e /f /g /h /i /j /k /bar 5 /foo "c:\"
echo %ARG_FOO% | c:\
echo %ARG_A% |
echo %ARG_B% | 3
echo %ARG_C% | 1
echo %ARG_D% | 1
@echo off
setlocal
CALL :ARG-PARSER %*
::Print examples
echo: ALL: %*
echo: FOO: %ARG_FOO%
echo: A: %ARG_A%
echo: B: %ARG_B%
echo: C: %ARG_C%
echo: D: %ARG_C%
::*********************************************************
:: Parse commandline arguments into sane variables
:: See the following scenario as usage example:
:: >> thisfile.bat /a /b "c:\" /c /foo 5
:: >> CALL :ARG-PARSER %*
:: ARG_a=1
:: ARG_b=c:\
:: ARG_c=1
:: ARG_foo=5
::*********************************************************
:ARG-PARSER
::Loop until two consecutive empty args
:loopargs
IF "%~1%~2" EQU "" GOTO :EOF
set "arg1=%~1"
set "arg2=%~2"
shift
::Allow either / or -
set "tst1=%arg1:-=/%"
if "%arg1%" NEQ "" (
set "tst1=%tst1:~0,1%"
) ELSE (
set "tst1="
)
set "tst2=%arg2:-=/%"
if "%arg2%" NEQ "" (
set "tst2=%tst2:~0,1%"
) ELSE (
set "tst2="
)
::Capture assignments (eg. /foo bar)
IF "%tst1%" EQU "/" IF "%tst2%" NEQ "/" IF "%tst2%" NEQ "" (
set "ARG_%arg1:~1%=%arg2%"
GOTO loopargs
)
::Capture flags (eg. /foo)
IF "%tst1%" EQU "/" (
set "ARG_%arg1:~1%=1"
GOTO loopargs
)
goto loopargs
GOTO :EOF
:ARG-PARSERरूटीन की सामग्री को एक बाहरी .bat फ़ाइल में स्थानांतरित कर सकते हैं, जैसे arg-parser.batकि इसे अन्य स्क्रिप्ट के लिए भी उपलब्ध कराना।
एक बार मैंने एक प्रोग्राम लिखा था जो कि बैच फ़ाइल में शॉर्ट (-एच), लॉन्ग (--एचएलपी) और नॉन-ऑप्शन तर्कों को हैंडल करता है। इस तकनीकों में शामिल हैं:
एक विकल्प तर्क के बाद गैर-विकल्प तर्क।
उन विकल्पों के लिए शिफ्ट ऑपरेटर, जिनके पास '--help' की तरह कोई तर्क नहीं है।
उन विकल्पों के लिए दो टाइम शिफ्ट ऑपरेटर जिन्हें एक तर्क की आवश्यकता होती है।
सभी कमांड लाइन तर्कों को संसाधित करने के लिए एक लेबल के माध्यम से लूप।
स्क्रिप्ट से बाहर निकलें और उन विकल्पों के लिए प्रसंस्करण बंद कर दें, जिन्हें '--help' की तरह आगे की कार्रवाई की आवश्यकता नहीं है।
उपयोगकर्ता मार्गदर्शन के लिए मदद कार्य लिखा
यहाँ मेरा कोड है
set BOARD=
set WORKSPACE=
set CFLAGS=
set LIB_INSTALL=true
set PREFIX=lib
set PROGRAM=install_boards
:initial
set result=false
if "%1" == "-h" set result=true
if "%1" == "--help" set result=true
if "%result%" == "true" (
goto :usage
)
if "%1" == "-b" set result=true
if "%1" == "--board" set result=true
if "%result%" == "true" (
goto :board_list
)
if "%1" == "-n" set result=true
if "%1" == "--no-lib" set result=true
if "%result%" == "true" (
set LIB_INSTALL=false
shift & goto :initial
)
if "%1" == "-c" set result=true
if "%1" == "--cflag" set result=true
if "%result%" == "true" (
set CFLAGS=%2
if not defined CFLAGS (
echo %PROGRAM%: option requires an argument -- 'c'
goto :try_usage
)
shift & shift & goto :initial
)
if "%1" == "-p" set result=true
if "%1" == "--prefix" set result=true
if "%result%" == "true" (
set PREFIX=%2
if not defined PREFIX (
echo %PROGRAM%: option requires an argument -- 'p'
goto :try_usage
)
shift & shift & goto :initial
)
:: handle non-option arguments
set BOARD=%1
set WORKSPACE=%2
goto :eof
:: Help section
:usage
echo Usage: %PROGRAM% [OPTIONS]... BOARD... WORKSPACE
echo Install BOARD to WORKSPACE location.
echo WORKSPACE directory doesn't already exist!
echo.
echo Mandatory arguments to long options are mandatory for short options too.
echo -h, --help display this help and exit
echo -b, --boards inquire about available CS3 boards
echo -c, --cflag=CFLAGS making the CS3 BOARD libraries for CFLAGS
echo -p. --prefix=PREFIX install CS3 BOARD libraries in PREFIX
echo [lib]
echo -n, --no-lib don't install CS3 BOARD libraries by default
goto :eof
:try_usage
echo Try '%PROGRAM% --help' for more information
goto :eof
यहाँ तर्क पार्सर है। आप किसी भी स्ट्रिंग तर्क (अनछुए रखे गए) या बच गए विकल्प (एकल या विकल्प / मूल्य जोड़े) को मिला सकते हैं। इसे अंतिम 2 कथनों को अनियंत्रित करने के लिए परीक्षण करें और निम्नानुसार चलाएँ:
getargs anystr1 anystr2 /test$1 /test$2=123 /test$3 str anystr3
"_SEP_=/"यदि आवश्यक हो तो एस्केप चार को परिभाषित किया जाता है ।
@echo off
REM Command line argument parser. Format (both "=" and "space" separators are supported):
REM anystring1 anystring2 /param1 /param2=value2 /param3 value3 [...] anystring3 anystring4
REM Returns enviroment variables as:
REM param1=1
REM param2=value2
REM param3=value3
REM Leading and traling strings are preserved as %1, %2, %3 ... %9 parameters
REM but maximum total number of strings is 9 and max number of leading strings is 8
REM Number of parameters is not limited!
set _CNT_=1
set _SEP_=/
:PARSE
if %_CNT_%==1 set _PARAM1_=%1 & set _PARAM2_=%2
if %_CNT_%==2 set _PARAM1_=%2 & set _PARAM2_=%3
if %_CNT_%==3 set _PARAM1_=%3 & set _PARAM2_=%4
if %_CNT_%==4 set _PARAM1_=%4 & set _PARAM2_=%5
if %_CNT_%==5 set _PARAM1_=%5 & set _PARAM2_=%6
if %_CNT_%==6 set _PARAM1_=%6 & set _PARAM2_=%7
if %_CNT_%==7 set _PARAM1_=%7 & set _PARAM2_=%8
if %_CNT_%==8 set _PARAM1_=%8 & set _PARAM2_=%9
if "%_PARAM2_%"=="" set _PARAM2_=1
if "%_PARAM1_:~0,1%"=="%_SEP_%" (
if "%_PARAM2_:~0,1%"=="%_SEP_%" (
set %_PARAM1_:~1,-1%=1
shift /%_CNT_%
) else (
set %_PARAM1_:~1,-1%=%_PARAM2_%
shift /%_CNT_%
shift /%_CNT_%
)
) else (
set /a _CNT_+=1
)
if /i %_CNT_% LSS 9 goto :PARSE
set _PARAM1_=
set _PARAM2_=
set _CNT_=
rem getargs anystr1 anystr2 /test$1 /test$2=123 /test$3 str anystr3
rem set | find "test$"
rem echo %1 %2 %3 %4 %5 %6 %7 %8 %9
:EXIT