कैसे एक GLSL shader डीबग करने के लिए?

Question

मुझे एक GLSL प्रोग्राम डिबग करने की आवश्यकता है लेकिन मुझे नहीं पता कि इंटरमीडिएट परिणाम कैसे उत्पन्न किया जाए। क्या GLSL के साथ कुछ डिबग निशान (जैसे प्रिंटफ के साथ) बनाना संभव है?

Comments

... glslDevil जैसे बाहरी सॉफ़्टवेयर का उपयोग किए बिना।

— फ्रेंक फ्रीबर्गर

GLSL Fragment shader के फ्लोट चर और ग्रंथों के इस डिबग प्रिंट पर एक नज़र डालें, आपको केवल फॉन्ट के लिए सिंगल स्पेयर टेक्सचर यूनिट की जरूरत है और मुद्रित क्षेत्र में आउटपुट वैल्यू की निरंतर स्थिति

— Spektre

Answer 1

आप जीएलएसएल के भीतर से सीपीयू में आसानी से वापस संचार नहीं कर सकते हैं। GlslDevil या अन्य टूल का उपयोग करना आपकी सबसे अच्छी शर्त है।

जीएलएसएल कोड चलाने वाले जीपीयू से सीपीयू को वापस पाने के लिए एक प्रिंटफ की कोशिश करनी होगी। इसके बजाय, आप प्रदर्शन को आगे बढ़ाने का प्रयास कर सकते हैं। आउटपुट पाठ की कोशिश करने के बजाय, स्क्रीन पर कुछ विशिष्ट रूप से विशिष्ट आउटपुट करें। उदाहरण के लिए, आप किसी विशिष्ट रंग को केवल तभी पेंट कर सकते हैं जब आप अपने कोड के उस बिंदु पर पहुँच जाते हैं जहाँ आप प्रिंटफ़ जोड़ना चाहते हैं। यदि आपको कोई मान प्रिंट करने की आवश्यकता है तो आप उस मूल्य के अनुसार रंग सेट कर सकते हैं।

Comments

क्या होगा यदि आप अपने शेडर को डिबग करना चाहते हैं, क्योंकि स्क्रीन पर कुछ भी दिखाई नहीं दे रहा है?

— जेरोन

आप कुछ भी डिबेट क्यों करना चाहेंगे? क्योंकि इसका कोड और वह रन टाइम वैल्यूज की जांच करना चाहता है जिससे मुझे खतरा होगा ....

— रिचीएच

GLSL-Debugger glslDevil का एक खुला स्रोत कांटा है।

— मैग्नस

@ मैग्नस अब इसे सक्रिय रूप से बनाए नहीं रखा गया है, और केवल 1.20 तक GLSL का समर्थन करता है।

— रुस्लान

Answer 2

void main(){
  float bug=0.0;
  vec3 tile=texture2D(colMap, coords.st).xyz;
  vec4 col=vec4(tile, 1.0);

  if(something) bug=1.0;

  col.x+=bug;

  gl_FragColor=col;
}

Comments

यह एक डीबगिंग डिवाइस है। यदि आप जानना चाहते हैं कि दृश्य में प्रकाश की स्थिति कहाँ है, उदाहरण के लिए, जाएँ: if (lpos.x> 100) बग = 1.0। यदि प्रकाश की स्थिति 100 से अधिक है, तो दृश्य लाल हो जाएगा।

— चरण 3

Answer 3

मैंने ट्रांसफॉर्म फीडबैक को वर्टेक्स शेड्स डिबगिंग के लिए एक उपयोगी उपकरण के रूप में पाया है । आप इसका उपयोग वी.एस. आउटपुट के मूल्यों को पकड़ने के लिए कर सकते हैं, और सीपीयू की ओर से उन्हें वापस पढ़ सकते हैं, बिना रैस्टरएज़र के बिना।

यहां ट्रांसफॉर्मेशन फीडबैक के ट्यूटोरियल का एक और लिंक दिया गया है।

Answer 4

यदि आप स्क्रीन पर मान के भिन्नरूपों की कल्पना करना चाहते हैं, तो आप इसके समान हीटमैप फ़ंक्शन का उपयोग कर सकते हैं (मैंने इसे hlsl में लिखा था, लेकिन यह glsl के अनुकूल होना आसान है):

float4 HeatMapColor(float value, float minValue, float maxValue)
{
    #define HEATMAP_COLORS_COUNT 6
    float4 colors[HEATMAP_COLORS_COUNT] =
    {
        float4(0.32, 0.00, 0.32, 1.00),
        float4(0.00, 0.00, 1.00, 1.00),
        float4(0.00, 1.00, 0.00, 1.00),
        float4(1.00, 1.00, 0.00, 1.00),
        float4(1.00, 0.60, 0.00, 1.00),
        float4(1.00, 0.00, 0.00, 1.00),
    };
    float ratio=(HEATMAP_COLORS_COUNT-1.0)*saturate((value-minValue)/(maxValue-minValue));
    float indexMin=floor(ratio);
    float indexMax=min(indexMin+1,HEATMAP_COLORS_COUNT-1);
    return lerp(colors[indexMin], colors[indexMax], ratio-indexMin);
}

फिर अपने पिक्सेल shader में आप कुछ इस तरह से आउटपुट करते हैं:

return HeatMapColor(myValue, 0.00, 50.00);

और इस बात का अंदाजा लगा सकते हैं कि यह आपके पिक्सल में कैसे बदलता है:

बेशक आप अपनी पसंद के किसी भी रंग का उपयोग कर सकते हैं।

Answer 5

GLSL सैंडबॉक्स शेडर्स के लिए मेरे लिए बहुत उपयोगी रहा है।

प्रति डिबगिंग नहीं (जिसे अक्षम के रूप में उत्तर दिया गया है) लेकिन आउटपुट में बदलाव को जल्दी से देखना आसान है।

Answer 6

आप इसे आज़मा सकते हैं: https://github.com/msqrt/shader-printf जो एक कार्यान्वयन है जिसे उचित रूप से "GLSL के लिए सरल प्रिंटफ़ कार्यक्षमता" कहा जाता है।

आप ShaderToy को आज़माना भी चाह सकते हैं, और शायद "द आर्ट ऑफ़ कोड" YouTube चैनल से इस तरह ( https://youtu.be/EBrAdahFtuo ) एक वीडियो देखें, जहाँ आप कुछ ऐसी तकनीकों को देख सकते हैं जो डीबगिंग के लिए अच्छी तरह से काम करती हैं और visualizing। मैं उनके चैनल की जोरदार सिफारिश कर सकता हूं क्योंकि वह कुछ बहुत अच्छा सामान लिखते हैं और उनके पास उपन्यास में जटिल विचारों को प्रस्तुत करने के लिए एक नॉक भी है, अत्यधिक आकर्षक और प्रारूप को पचाने में आसान (उनका मैंडलब्रॉट वीडियो बिल्कुल उसी का एक शानदार उदाहरण है: https: // youtu.be/6IWXkV82oyY )

मुझे आशा है कि किसी को भी इस देर से जवाब देने का मन नहीं है, लेकिन सवाल जीएलएसएल डिबगिंग के लिए Google खोजों पर उच्च रैंक करता है और बहुत कुछ 9 सेकंड में बदल गया है :-)

पुनश्च: अन्य विकल्प भी NVIDIA nSight और AMD ShaderAnalyzer हो सकते हैं जो शेड्स के लिए एक पूर्ण कदम डिबगर प्रदान करते हैं।

Answer 7

मैं एक टुकड़ा shader उदाहरण साझा कर रहा हूं, मैं वास्तव में कैसे डीबग करता हूं।

#version 410 core

uniform sampler2D samp;
in VS_OUT
{
    vec4 color;
    vec2 texcoord;
} fs_in;

out vec4 color;

void main(void)
{
    vec4 sampColor;
    if( texture2D(samp, fs_in.texcoord).x > 0.8f)  //Check if Color contains red
        sampColor = vec4(1.0f, 1.0f, 1.0f, 1.0f);  //If yes, set it to white
    else
        sampColor = texture2D(samp, fs_in.texcoord); //else sample from original
    color = sampColor;

}

Answer 8

इस उत्तर के निचले भाग में GLSL कोड का एक उदाहरण है जो floatIEEE 754 को एन्कोडिंग के रूप में पूर्ण मूल्य को रंग के रूप में आउटपुट करने की अनुमति देता है binary32। मैं इसे इस प्रकार उपयोग करता हूं (यह स्निपेट yyमॉडलव्यू मैट्रिक्स का घटक देता है ):

vec4 xAsColor=toColor(gl_ModelViewMatrix[1][1]);
if(bool(1)) // put 0 here to get lowest byte instead of three highest
    gl_FrontColor=vec4(xAsColor.rgb,1);
else
    gl_FrontColor=vec4(xAsColor.a,0,0,1);

स्क्रीन पर इसे प्राप्त करने के बाद, आप बस किसी भी रंग बीनने वाले को ले जा सकते हैं, रंग को HTML के रूप में प्रारूपित कर सकते हैं ( यदि आपको उच्च परिशुद्धता की आवश्यकता नहीं है, तो मूल्य 00को जोड़कर rgb, और यदि आप करते हैं तो कम बाइट प्राप्त करने के लिए दूसरा पास कर सकते हैं), और आपको floatIEEE 754 के रूप में हेक्साडेसिमल प्रतिनिधित्व मिलता है binary32।

यहाँ वास्तविक कार्यान्वयन है toColor():

const int emax=127;
// Input: x>=0
// Output: base 2 exponent of x if (x!=0 && !isnan(x) && !isinf(x))
//         -emax if x==0
//         emax+1 otherwise
int floorLog2(float x)
{
    if(x==0.) return -emax;
    // NOTE: there exist values of x, for which floor(log2(x)) will give wrong
    // (off by one) result as compared to the one calculated with infinite precision.
    // Thus we do it in a brute-force way.
    for(int e=emax;e>=1-emax;--e)
        if(x>=exp2(float(e))) return e;
    // If we are here, x must be infinity or NaN
    return emax+1;
}

// Input: any x
// Output: IEEE 754 biased exponent with bias=emax
int biasedExp(float x) { return emax+floorLog2(abs(x)); }

// Input: any x such that (!isnan(x) && !isinf(x))
// Output: significand AKA mantissa of x if !isnan(x) && !isinf(x)
//         undefined otherwise
float significand(float x)
{
    // converting int to float so that exp2(genType) gets correctly-typed value
    float expo=float(floorLog2(abs(x)));
    return abs(x)/exp2(expo);
}

// Input: x\in[0,1)
//        N>=0
// Output: Nth byte as counted from the highest byte in the fraction
int part(float x,int N)
{
    // All comments about exactness here assume that underflow and overflow don't occur
    const float byteShift=256.;
    // Multiplication is exact since it's just an increase of exponent by 8
    for(int n=0;n<N;++n)
        x*=byteShift;

    // Cut higher bits away.
    // $q \in [0,1) \cap \mathbb Q'.$
    float q=fract(x);

    // Shift and cut lower bits away. Cutting lower bits prevents potentially unexpected
    // results of rounding by the GPU later in the pipeline when transforming to TrueColor
    // the resulting subpixel value.
    // $c \in [0,255] \cap \mathbb Z.$
    // Multiplication is exact since it's just and increase of exponent by 8
    float c=floor(byteShift*q);
    return int(c);
}

// Input: any x acceptable to significand()
// Output: significand of x split to (8,8,8)-bit data vector
ivec3 significandAsIVec3(float x)
{
    ivec3 result;
    float sig=significand(x)/2.; // shift all bits to fractional part
    result.x=part(sig,0);
    result.y=part(sig,1);
    result.z=part(sig,2);
    return result;
}

// Input: any x such that !isnan(x)
// Output: IEEE 754 defined binary32 number, packed as ivec4(byte3,byte2,byte1,byte0)
ivec4 packIEEE754binary32(float x)
{
    int e = biasedExp(x);
    // sign to bit 7
    int s = x<0. ? 128 : 0;

    ivec4 binary32;
    binary32.yzw=significandAsIVec3(x);
    // clear the implicit integer bit of significand
    if(binary32.y>=128) binary32.y-=128;
    // put lowest bit of exponent into its position, replacing just cleared integer bit
    binary32.y+=128*int(mod(float(e),2.));
    // prepare high bits of exponent for fitting into their positions
    e/=2;
    // pack highest byte
    binary32.x=e+s;

    return binary32;
}

vec4 toColor(float x)
{
    ivec4 binary32=packIEEE754binary32(x);
    // Transform color components to [0,1] range.
    // Division is inexact, but works reliably for all integers from 0 to 255 if
    // the transformation to TrueColor by GPU uses rounding to nearest or upwards.
    // The result will be multiplied by 255 back when transformed
    // to TrueColor subpixel value by OpenGL.
    return vec4(binary32)/255.;
}

Answer 9

एक बनावट के लिए ऑफ़लाइन प्रतिपादन करें और बनावट के डेटा का मूल्यांकन करें। आप संबंधित कोड को "रेंडर टू टेक्सटाइल" ओपेंगल के लिए पा सकते हैं, फिर आउटपुट को एक ऐरे में पढ़ने के लिए और उस पर अभिकथन करने के लिए glReadPixels का उपयोग करें (क्योंकि डीबगर में इतना बड़ा एरे आमतौर पर वास्तव में उपयोगी होता है)।

इसके अलावा, आप क्लैम्पिंग को आउटपुट मानों में अक्षम करना चाहते हैं जो 0 और 1 के बीच नहीं हैं, जो केवल फ़्लोटिंग पॉइंट टेक्सचर के लिए समर्थित है ।

मैं व्यक्तिगत रूप से थोड़ी देर के लिए शेडिंग डिबगिंग की समस्या से परेशान था। एक अच्छा तरीका प्रतीत नहीं होता है - अगर किसी को एक अच्छा (और पुराना / अपवित्र) डिबगर नहीं मिलता है, तो कृपया मुझे बताएं।

Comments

कोई भी उत्तर या टिप्पणी जो कहती है कि "google xyz" को Stackoverflow से मतदान या प्रतिबंधित किया जाना चाहिए।

— gregoiregentil

Answer 10

मौजूदा उत्तर सभी अच्छे सामान हैं, लेकिन मैं एक और छोटे मणि को साझा करना चाहता था जो जीएलएसएल शेडर में ट्रिकी सटीक मुद्दों को डिबग करने में मूल्यवान हो। फ्लोटिंग पॉइंट के रूप में प्रतिनिधित्व करने वाले बहुत बड़े इंटों की संख्या के साथ, एक सटीक इंट में राउंड () को लागू करने के लिए फर्श (एन) और फर्श (एन + 0.5) का सही तरीके से उपयोग करने के लिए देखभाल करने की आवश्यकता होती है। इसके बाद फ्लोट मूल्य को प्रस्तुत करना संभव है जो बाइट घटकों को आर, जी, और बी आउटपुट मूल्यों में पैक करने के लिए निम्न तर्क द्वारा एक सटीक इंट है।

  // Break components out of 24 bit float with rounded int value
  // scaledWOB = (offset >> 8) & 0xFFFF
  float scaledWOB = floor(offset / 256.0);
  // c2 = (scaledWOB >> 8) & 0xFF
  float c2 = floor(scaledWOB / 256.0);
  // c0 = offset - (scaledWOB << 8)
  float c0 = offset - floor(scaledWOB * 256.0);
  // c1 = scaledWOB - (c2 << 8)
  float c1 = scaledWOB - floor(c2 * 256.0);

  // Normalize to byte range
  vec4 pix;  
  pix.r = c0 / 255.0;
  pix.g = c1 / 255.0;
  pix.b = c2 / 255.0;
  pix.a = 1.0;
  gl_FragColor = pix;