मैं ज्यादातर इस फ़ंक्शन का उपयोग करता हूं:
cf() {
cd "$(osascript -e 'tell app "Finder" to POSIX path of (insertion location as alias)')"
}
आप नीचे दिए गए स्क्रिप्ट की तरह शॉर्टकट भी असाइन कर सकते हैं।
मौजूदा टैब का पुनः उपयोग करें या एक नई विंडो बनाएं (टर्मिनल):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if (exists window 1) and not busy of window 1 then
do script "cd " & quoted form of p in window 1
else
do script "cd " & quoted form of p
end if
activate
end tell
मौजूदा टैब का पुनः उपयोग करें या नया टैब बनाएं (टर्मिनल):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if not (exists window 1) then reopen
activate
if busy of window 1 then
tell application "System Events" to keystroke "t" using command down
end if
do script "cd " & quoted form of p in window 1
end tell
हमेशा एक नया टैब बनाएं (iTerm 2):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "iTerm"
if exists current terminal then
current terminal
else
make new terminal
end if
tell (launch session "Default") of result to write text "cd " & quoted form of p
activate
end tell
10.7 में जोड़ी गई सेवाओं की तुलना में पहले दो लिपियों के कुछ फायदे हैं:
- 10.9 तक, एक बग है, जहां इनपुट के रूप में फ़ोल्डर प्राप्त करने वाली सेवाएं स्तंभ दृश्य में सेवाओं के मेनू में कभी सूचीबद्ध नहीं होती हैं। यदि आप फ़ोल्डर सेवा में नया टर्मिनल टैब एक कीबोर्ड शॉर्टकट प्रदान करते हैं, तो यह कॉलम दृश्य में काम नहीं करता है।
- वे आपको पहले एक फ़ोल्डर का चयन करने की आवश्यकता के बजाय शीर्षक पट्टी पर फ़ोल्डर का उपयोग करते हैं।
- यदि वे व्यस्त नहीं हैं, तो वे सबसे सामने वाले टैब का पुन: उपयोग करते हैं, जैसे कि एक कमांड चलाना, एक मैन पेज प्रदर्शित करना, या एमएसीएस चलाना।
यदि आप 10.7 या 10.8 का उपयोग करते हैं, तो इसमें बदलें tell application "Finder" to set p to POSIX path of (insertion location as alias):
tell application "Finder"
if exists Finder window 1 then
set p to POSIX path of (target of Finder window 1 as alias)
else
set p to POSIX path of (path to desktop)
end if
end tell
10.7 और 10.8 (लेकिन 10.9 या 10.6 में नहीं) में एक बग है जहां खोजक ने पिछली बार ध्यान केंद्रित करने के बाद बनाई गई खिड़कियों की उपेक्षा की और insertion locationसंपत्ति प्राप्त करते समय किसी अन्य अनुप्रयोग और वापस ले जाया गया ।
