Google शीट में एक स्ट्रिंग में शब्दों की संख्या गिनें

9

मेरे पास कई टेक्स्ट स्ट्रिंग्स के साथ एक साधारण Google स्प्रेडशीट है। मैं सिर्फ प्रत्येक सेल में निहित शब्दों की संख्या चाहता हूं। क्या कोई अंतर्निहित Google स्प्रेडशीट फ़ंक्शन है जिसका मैं उपयोग कर सकता हूं?

— user0
स्रोत

9

Google स्प्रेडशीट में, मैं इसे थोड़ा अलग करूँगा।

सूत्र

=COUNTA(SPLIT(A1, " "))

व्याख्या की

SPLITसमारोह गूगल स्प्रैडशीट में ही उपलब्ध है और हर जगह पर सेल की सामग्री बंट जाएगा ( " ")। COUNTसमारोह बस उदाहरणों में रखा जाएगा।

एक्सेल सूत्र एक ही जवाब देता है, लेकिन थोड़ा अधिक श्रमसाध्य:

=LEN(TRIM(A1))-LEN(SUBSTITUTE(A1," ",""))+1

स्क्रीनशॉट

यहाँ छवि विवरण दर्ज करें

टिप्पणी

निम्नलिखित उत्तर देखें कि कौन से सूत्र Google स्प्रेडशीट के लिए अद्वितीय हैं:
https://webapps.stackexchange.com/a/44719/29140

— जैकब जान तुइस्ट्रा
स्रोत

1

अधिकांश भाग के लिए यह मेरे लिए (Google शीट्स में) काम कर रहा था ... केवल खाली सेल को छोड़कर 1 .. इसलिए मैंने इसे थोड़ा बदल दिया ताकि खाली सेल 0 वापस आए:=COUNTA(SPLIT(A1, " "))-IF(A1 = "",1,0)

— CenterOrbit

हम कुछ ऐसा ही करते हैं लेकिन यह तब काम नहीं करेगा जब रिक्त स्थान सामान्य रिक्त स्थान वर्ण (जैसे टैब, आदि) नहीं हैं। इसलिए मुझे शब्दों को गिनने का थोड़ा चतुर तरीका खोजना अच्छा लगेगा।

— एल्डो 'xoen' Giambelluca

हाय Aldo, सबसे अच्छा बस वेब अनुप्रयोग पर यहाँ अपना सवाल पूछना है !!!

— बजे जैकब जान तुइस्ट्रा

3

इस अन्य उत्तर में सूत्र में थोड़ा सुधार ताकि ए 1 खाली हो या अगर उसमें एक खाली स्ट्रिंग हो तो वह शून्य पर वापस आ जाएगा।

= IF (LEN (A1) = 0,0, COUNTA (SPLIT (A1, ""))

— रुबेन
स्रोत

0

यदि आप इसे एक सेल रेंज (यानी A1:A25) पर करना चाहते हैं, तो आप ऊपर दिए गए फॉर्मूला का उपयोग कर सकते हैं, जहां CHAR(32)स्पेस कैरेक्टर है" "

=COUNTA(SPLIT(ARRAYFORMULA(CONCATENATE(A1:A25&CHAR(32)));CHAR(32)))

यह रिक्त कोशिकाओं के साथ काम करता है, सिवाय इसके कि प्रारंभिक सेल रिक्त है।

— एनरिक रामिरेज़
स्रोत

0

एक और:

=COUNTA(SPLIT(TRIM(A1&" #")," "))-1

यह बस लक्ष्य सेल में जो कुछ भी है, के अंत में एक रिक्त स्थान और पाउंड के संकेत को जोड़ देता है , जिसमें एक अशक्त जोड़ना भी शामिल है , इसलिए गिनती को फेंकने में कभी कोई त्रुटि नहीं होती है। फिर हम अंत में उस अस्थायी "नकली स्थान" को वापस निकाल रहे हैं।

— एरिक टायलर
स्रोत

0

=ARRAYFORMULA(IF(LEN(A3:A), 
 MMULT(IF(IFERROR(SPLIT(IF(LEN(A3:A), A3:A, ), " "))<>"", 1, 0), 
 ROW(INDIRECT("A1:A"&COUNTA(IFERROR(
 QUERY(IF(IFERROR(SPLIT(IF(LEN(A3:A), A3:A, ), " "))<>"", 1, 0), "limit 1", 0)))))^0), ))

______________________________________________________________

=ARRAYFORMULA(IF(LEN(A3:A), LEN(REGEXREPLACE(A3:A, "[^\s]", ))+1, ))

— user0
स्रोत