Google स्प्रेडशीट के साथ एक क्वेरी कैसे करें, यह एक तारीख के लिए जाँच करता है

11

मेरे पास एक सीमा है जो इससे जाती है B4:H124। स्तंभ B की सभी कोशिकाएँ दिनांक हैं। मैं एक पंक्ति ( B:H) से डेटा पुनर्प्राप्त करना चाहूंगा , जहां DATE एक विशिष्ट सेल की सामग्री के बराबर है, Q4 कहता है।

मैं एक उचित क्वेरी कैसे बनाऊं?

अब तक, मैं इसे लेकर आया हूं:

=QUERY(B2:G124; "select * where B = date '2012-02-28'")

यह काम करता है, भले ही बी में कोशिकाओं का प्रारूप डीडी / एमएम / वाईवाईवाई है।

मैं कैसे बदल सकता हूँ 2012-02-28करने के लिए $Q4? जब मैं कोशिश करता हूं, मुझे निम्न त्रुटि मिलती है:

=QUERY(B2:G124; "select * where B = date '"&Q4&"'")

Invalid query: Invalid date literal [10/02/2012]. Date literals should be of form yyyy-MM-dd.

जब मैं सेल को देखता हूं, तो प्रारूप है yyyy-mm-dd, लेकिन जब मैं इसे डबल क्लिक करता हूं, तो प्रारूप बदल जाता है DD-MM-YYYY।

मुझे क्या करना चाहिए?

इसके अलावा, मैं कॉलम B को शामिल किए बिना क्वेरी से मूल्यों को कैसे जोड़ सकता हूं?

google-sheets google-sheets-query

— Kenci
स्रोत

3

मैं अभी तक काम करने के लिए वास्तविक तिथि सेल के लिए चाल नहीं पा सके, लेकिन आप अगर एकल उद्धरण (जोड़कर और कुछ नहीं के चारों ओर एक काम हो सकता था ') एक प्रारूप में की तारीख से पहले: YYYY-MM-DDमें Q4सेल।

उस एकल उद्धरण का मतलब है कि इसे स्ट्रिंग के रूप में पार्स किया जाएगा।

— लिपिस
स्रोत

11

आप इस तरह की तारीख को प्रारूपित कर सकते हैं:

=QUERY(B2:G124; "select * where B = date '" & text(Q4,"yyyy-MM-dd") & "'")

स्तंभ C में मानों को योग करने के लिए, यह करें:

=QUERY(B2:G124; "select sum(C) where B = date '" & text(Q4,"yyyy-MM-dd") & "'")

नहीं यकीन है कि कैसे कई कॉलम योग करने के लिए - अभी भी अपने आप को बहुत नया!

— s6mike
स्रोत

2

यह काम करना चाहिए:

=QUERY(B2:G124; "select * where B = date '"&text(Q4;"yyyy-MM-dd")&"'")

वैसे भी, मुझे वही समस्या थी और आखिरकार इसने मेरे लिए काम किया।

बात यह है कि आप संदेश से भ्रमित हो जाते हैं

Invalid query: Invalid date literal [10/02/2012]. Date literals should be of form yyyy-MM-dd.

ऐसा इसलिए है क्योंकि आपके Q4 सेल का दिनांक प्रारूप dd / MM / yyyy है। मेरे पास एक ही बात है: यहां तक कि अगर यह dd / MM / yyyy होने जैसा दिखता है, तो आपको इसे ऐसे ही रखना होगा जैसे कि यह मेरे उत्तर की दूसरी पंक्ति में ऊपर दिया गया है।

— एंड्रीको डैन
स्रोत

1

Q3इस फॉर्मेट में अपनी इच्छित तिथि को एक नए सेल में रखें :2/28/2012

फिर Q4कोशिका के प्रकार में=YEAR(Q3) & "-" & DEC2OCT(MONTH(Q3), 2) & "-" & DAY(Q3)

यह Q3सेल से दिनांक प्राप्त करेगा और इसे Q4सेल में एक स्ट्रिंग में बदल देगा ।

यदि आप वर्तमान तिथि चाहते हैं तो यह अधिक उपयोगी है। Q3अपने तिथि से प्राप्त करने के बजाय now()आज की तारीख प्राप्त करने के लिए उपयोग कर सकते हैं :=YEAR(now()) & "-" & DEC2OCT(MONTH(now()), 2) & "-" & DAY(now())

— ब्रैड सी।
स्रोत

1

अंतिम होना चाहिए:

=QUERY(B2:G124; "select * where B = date ' "  & text( Q4 ,"yyyy-MM-dd") & "'")

जहाँ Q4 एक सामान्य दिनांक स्वरूपित सेल है जहाँ आप दिनांक में टाइप कर सकते हैं।

अपने नोटपैड पर उपरोक्त कॉपी करें और सभी के बारे में फ़ॉन्ट आकार बढ़ाएं।

यहां 'डबल के भीतर सिंगल देखना मुश्किल "है।

— raymond703
स्रोत

0

आप स्ट्रिंग के बाहर की तारीख की गणना भी कर सकते हैं और dateउदाहरण के लिए ड्रॉप कर सकते हैं

=QUERY(B2:G124; "select * where B = '" & Q4)

Q4 प्रभावी रूप से एक पूर्णांक के रूप में उत्तीर्ण होता है, जो कि वैसे भी दृश्यों के पीछे की तारीख को बदल देता है।

— मैक्स गनीस
स्रोत

0

Google के QUERY फ़ंक्शन का उपयोग करना:

करने के लिए sum एकाधिक स्तंभों , इसे शामिल करने के लिए महत्वपूर्ण है labelक्वेरी के अंत में पैरामीटर

=QUERY(B2:G124; "select sum(C) + sum(D) + sum(E) + sum(F) + sum(G) label sum(C) + sum(D) + sum(E) + sum(F) + sum(G) '' ")

नोट: कॉलम संदर्भ केस संवेदी हैं और क्वेरी के अंत में 2 एकल उद्धरण आवश्यक हैं।

whereएक सेल दिनांक मान संदर्भित क्लॉज जोड़ने के लिए : s6mikes समाधान से

=QUERY(B2:G124; "select * where B = date '" & text(Q4,"yyyy-MM-dd") & "')

संयुक्त 2 प्रश्न ...

=QUERY(B2:G124; "select sum(C) + sum(D) + sum(E) + sum(F) + sum(G) where B = date '" & text(Q4,"yyyy-MM-dd") & "' label sum(C) + sum(D) + sum(E) + sum(F) + sum(G) '' ")

— रंबल मछली
स्रोत

-1

आपको अपने संदर्भ सेल में डेटा के प्रकार को टेक्स्ट में बदलना होगा। और यह सुचारू रूप से काम करेगा।

— telkontar
स्रोत