कार्य पूरा होने तक स्क्रीन को ताज़ा करने से रोकें

Question

मेरे पास एक फ़ंक्शन है जो वर्तमान vim बफ़र में पाठ के बहुत सारे मूविंग और आउटपुट करता है, और जब मैं इसे चलाता हूं, तो यह सब देखकर कि अंधा गति से हो रहा है, थोड़ा डिस्कनेक्टिंग है।

फ़ंक्शन के पूरा होने तक मैं स्क्रीन को फ्रीज कैसे कर सकता हूं?

यहाँ सवाल में समारोह है:

function! MakeChoices()
    :let save_view = winsaveview()
    let start = line('.')

    "Locate previous *choice. (b=backwards, W=nowrap, n=doNot move cursor)
    let choiceStartLine = search('^*choice', 'bW')

    if !choiceStartLine
        echo "No *choice found. (*choice must not be indented. This is to avoid finding *choice blocks nested in another *choice block.)"
        return -1
    endif
    "return getline(target_line_num, target_line_num+4)
    "Locate end of *choice block
    "echo getline(choiceStartLine, choiceStartLine+2)
    let choiceEndLine = search('^\S.*', 'W') "End is first line that starts with non-whitespace

    "If above search fails, might be at bottom of buffer
    if choiceEndLine == 0
        let choiceEndLine = search('^$', 'W') "End is first empty line
    endif

    "Now go back up to the last *goto
    let choiceEndLine = search('*goto', 'bW')

    "Get the entire *choice block and put it in gotoBlock
    let gotoBlock = getline(choiceStartLine, choiceEndLine)

    "Make labelArray (contains all labels to goto)
    let labelArray = []

    for cur in gotoBlock
        if match(cur, '*goto') != -1
            "echo 'cur: '.cur
            let curParsed = matchlist(cur, '*goto \(\S\+\)')
            "echo curParsed
            if len(curParsed) > 1
                let curLabel = curParsed[1]
            else
                echo 'ERROR: Bad *goto ('.cur.')'
                return -1
            endif
            call add(labelArray, curLabel)  
        endif
    endfor

    "Restore window to what it looked like (in case the searches scrolled
    "it)
    call winrestview(save_view)

    "Make newline after choice block if needed
    if strlen(getline(choiceEndLine+1)) > 0
        echo 'big line: '.getline(choiceEndLine+1)
        call cursor(choiceEndLine, 1)
        put=''
    endif

    call cursor(choiceEndLine+1, 1)

    "Put the new label blocks
    let skippedLabels = ''
    let numNewLabels = 0
    for cur in labelArray
        if !search('*label '.cur, 'wn')
            let numNewLabels += 1
            put='*label '.cur
            put='[This option is yet to be written.]'
            put=''
        else
            let skippedLabels .= cur.' '
        endif
    endfor

    "Remove trailing blank lines (Up to a point)
    let nextlines = getline(line('.')+1, line('.')+3)
    if len(nextlines) == 3
        if nextlines[0] == '' && nextlines[1] == '' && nextlines[2] == ''
            normal "_3dd
        elseif nextlines[0] == '' && nextlines[1] == ''
            normal "_2dd
        elseif nextlines[0] == ''
            normal "_dd
        endif
    endif

    "Move to first label's text (use ctrl-v ctrl-m to input the <CR> at
    "end)
    if numNewLabels != 0
        call cursor(choiceEndLine, 1)
        normal /\[This option is yet to be written.\]
        let @/='\[This option is yet to be written\.\]'
    endif

    "Print status message
    if len(skippedLabels) > 0
        echo 'Skipped: '.skippedLabels
    else
        echo 'New labels created: '.numNewLabels
    endif
endfunction

Comments

:set lazyredrawमदद करता है?

— 22

नहीं, माफ करिए। यह केवल मैक्रोज़ के लिए मदद करता है। मैंने अभी इसकी कोशिश की, और यह मेरे कार्य के लिए काम नहीं किया।

— फ्लेरीविंड जूल

मुझे ऐसा करने का कोई तरीका नहीं पता, शायद टर्मिनल विंडो को फ्रीज करने के अलावा (जो कि जीवीएम के लिए काम नहीं करेगा)। लेकिन शायद कम स्क्रीन अपडेट के साथ अपने फ़ंक्शन को चलाने का एक और तरीका है? यह उपयोगी होगा यदि आप अपने फ़ंक्शन को पोस्ट करते हैं ;-)

— मार्टिन टूरनोइज़

आपने इसके लिए पूछा, @Carpetsmoker। ;-) समारोह जोड़ा गया। (यह लंबे समय तक है।)

— २३:२३ पर फ्लेरविंडेव

Answer 1

मुझे लगता है कि समस्या यह नहीं है :lazyredraw, जैसा कि मैं डॉक्स से समझता हूं, फ़ंक्शंस के लिए काम करना चाहिए (देखें :help :redraw, यह "स्क्रिप्ट या फ़ंक्शन को निष्पादित करने के लिए स्क्रीन आधे रास्ते को अपडेट करने के लिए उपयोगी है")।

समस्या यह है कि आप normalबफर अद्यतन करने के लिए उपयोग करते हैं और यह काम करता है जैसे कि आप वास्तव में कुछ टाइप करते हैं और यहां :lazyredrawकोई प्रभाव नहीं पड़ता है।

इसके बजाय normalआपको पाठ हेरफेर फ़ंक्शन (जैसे setline()) और पूर्व कमांड (जैसे :delete) का उपयोग करने की आवश्यकता है ।

इन दो कार्यों की तुलना करें, पहले एक, MakeChangesNorm()कुछ पागल स्क्रीन अपडेट करेंगे, जबकि दूसरा एक, MakeChangesFunctions()तुरंत अपडेट करेगा:

function! MakeChangesNorm()
    let lastline = line('$')
    norm gg
    let linenum = line('.')
    let lastline = line('$')
    while linenum < lastline
        norm ^
        norm s/choice/test/
        norm j
        normal "_3dd
        let linenum = line('.')
        let lastline = line('$')
    endwhile
endfunction


function! MakeChangesFunctions()
    norm gg
    let linenum = line('.')
    let lastline = line('$')
    while linenum < lastline
        let line = getline(linenum)
        " Substitute using substitute() and setline()
        let line = substitute(line, 'choice', 'test', '')
        call setline(linenum, line)
        " Delete lines using :delete
        execute '.,.+2delete _'
        let linenum = line('.')
        let lastline = line('$')
    endwhile
endfunction

फ़ाइल जिस पर मैंने परीक्षण किया, वह इस प्रकार है:

*choice test2 test3 super
*choice test2 test3 super
*choice test2 test3 super
*choice test2 test3 super
*choice test2 test3 super
*choice test2 test3 super
*choice test2 test3 super
*choice test2 test3 super
*choice test2 test3 super
*choice test2 test3 super
... 60 lines like this ...

Comments

स्पष्ट होना; क्या कई सामान्य कमांड जारी करने का कोई तरीका नहीं है और बाद में "स्क्रीन को पुनर्स्थापित करें" कमांड तक स्क्रीन को पूरी तरह से स्थगित करने का कोई तरीका नहीं है? मेरी समझ winsaveviewऔर winrestviewबस खिड़की में लाइन के कर्सर स्थान और सापेक्ष स्थिति को स्टोर करना है।

— ल्यूक डेविस

मैं इसे दूसरे प्रश्न में पूछूंगा।

— ल्यूक डेविस