zsh टैब खाली लाइन पर पूरा हो रहा है

Question

मुझे ऐसा tcsh'ism चाहिए, जो मुझे नहीं मिला है: बिना किसी सामग्री वाली रिक्त रेखा पर, मैं टैब कुंजी दबाकर और ls के बराबर देखना चाहता हूं। यह कहना है कि मैं चाहता हूँ

$ <tab>

कुछ और करने के लिए फिर मुझे \ t दे रहा है। मुझे कमांड पूरा होने के लिए शानदार संसाधन मिले हैं, लेकिन इस बेस केस के लिए नहीं। इस पर किसी भी तरह मदद बहुत अच्छा होगा! धन्यवाद।

Answer 1

# expand-or-complete-or-list-files
function expand-or-complete-or-list-files() {
    if [[ $#BUFFER == 0 ]]; then
        BUFFER="ls "
        CURSOR=3
        zle list-choices
        zle backward-kill-word
    else
        zle expand-or-complete
    fi
}
zle -N expand-or-complete-or-list-files
# bind to tab
bindkey '^I' expand-or-complete-or-list-files

Comments

बहुत साफ़। क्या किसी तरह से सूची को फिर से छिपाना संभव होगा? टैब-टू-शो तब टैब से छुपाना अच्छा होगा।

— पार्कर

धन्यवाद जॉन, मैंने आपका समाधान ढूंढा और यहां stackoverflow.com/questions/28729851/…

— lolesque

Answer 2

Tabएक पंक्ति की शुरुआत में व्यवहार शैली द्वारा नियंत्रित किया जाता है । हालाँकि, केवल दो समर्थित व्यवहार हैं:insert-tab

• हमेशा की तरह पूरा, के तहत zstyle ':completion:*' insert-tab false
• के तहत एक टैब डालें zstyle ':completion:*' insert-tab true
• या तो एक या दूसरे के तहत zstyle ':completion:*' insert-tab pending[=N]

यदि आप बस उस स्थिति में कमांड को पूरा करना चाहते हैं, तो zstyle ':completion:*' insert-tab trueकरेंगे। यदि आप कुछ अलग चाहते हैं, जैसे वर्तमान निर्देशिका में फ़ाइलों को सूचीबद्ध करना, तो आपको संशोधित करना होगा _main_complete।

हाल ही में ज़ेड-वर्कर्स की सूची पर एक सूत्र ने चर्चा की insert-tab।

Comments

बहुत खुबस! _Main_complete द्वारा ऐसा लगता है कि आप C कोड में कहीं संदर्भित कर रहे हैं? मैं गूंगा सवाल के लिए माफी चाहता हूँ, लेकिन वह कहाँ मिलेगा?

@ user535759: नहीं, _main_completezsh कोड का हिस्सा है जो पूरा होने पर लागू होता है। यह Completion/Base/Core/_main_completeस्रोत के पेड़ में है, आमतौर पर जैसे स्थान में स्थापित किया गया है /usr/share/zsh/functions/Completion/Base/_main_complete।

— गिल्स एसओ- बुराई को रोकें '31

@llua -command-वर्तमान निर्देशिका में फ़ाइलों को सूचीबद्ध करने के लिए <Tab> का कारण नहीं है। आपके द्वारा किए गए सभी मैचों को कमांड नामों से बाहर निकालने के लिए प्रतिबंधित करना है। लेकिन केवल इस स्थिति में पूरी की जाने वाली चीजें सूचीबद्ध हैं, इसलिए वर्तमान निर्देशिका में फाइलें नहीं हैं (केवल निर्देशिका और निष्पादन पर निर्भर करता है ) autocdऔर PATH।

— गाइल्स का SO- बुराई को रोकना '

Answer 3

जब आप खाली लाइन पर टैब दबाते हैं, तो zsh में tsh का ऑटोलॉजिस्ट का पूरा कार्यान्वयन होता है

% <TAB>

यह रहा:

# list dir with TAB, when there are only spaces/no text before cursor,
# or complete words, that are before cursor only (like in tcsh)
tcsh_autolist() { if [[ -z ${LBUFFER// } ]]
    then BUFFER="ls " CURSOR=3 zle list-choices
    else zle expand-or-complete-prefix; fi }
zle -N tcsh_autolist
bindkey '^I' tcsh_autolist

यदि आप tcsh को अधिक बारीकी से अनुकरण करना चाहते हैं, तो इसे अपने .zshrc में भी जोड़ें:

unsetopt always_last_prompt       # print completion suggestions above prompt

Answer 4

मैंने यह zsh विजेट लिखा है जो TAB के उपयोग को बढ़ाता है, न केवल एक खाली लाइन पर, बल्कि जब आप एक कमांड टाइप कर रहे होते हैं।

• यह एक खाली कमांड लाइन पर और किसी भी कमांड के बीच में फाइलों को सूचीबद्ध करेगा ।
• यह खाली कमांड लाइन पर निर्देशिकाओं को सूचीबद्ध करेगा ।
• यह एक खाली कमांड लाइन पर निष्पादक को सूचीबद्ध करेगा ।

इसे वैश्विक चर वाले उन मामलों में "सीडी" या "./" को प्रीपेन्ड करने के लिए कॉन्फ़िगर किया जा सकता है।

export TAB_LIST_FILES_PREFIX

# List files in zsh with <TAB>
#
# Copyleft 2017 by Ignacio Nunez Hernanz <nacho _a_t_ ownyourbits _d_o_t_ com>
# GPL licensed (see end of file) * Use at your own risk!
#
# Usage:
#   In the middle of the command line:
#     (command being typed)<TAB>(resume typing)
#
#   At the beginning of the command line:
#     <SPACE><TAB>
#     <SPACE><SPACE><TAB>
#
# Notes:
#   This does not affect other completions
#   If you want 'cd ' or './' to be prepended, write in your .zshrc 'export TAB_LIST_FILES_PREFIX'
#   I recommend to complement this with push-line-or edit (bindkey '^q' push-line-or-edit)
function tab_list_files
{
  if [[ $#BUFFER == 0 ]]; then
    BUFFER="ls "
    CURSOR=3
    zle list-choices
    zle backward-kill-word
  elif [[ $BUFFER =~ ^[[:space:]][[:space:]].*$ ]]; then
    BUFFER="./"
    CURSOR=2
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER="  " CURSOR=2
  elif [[ $BUFFER =~ ^[[:space:]]*$ ]]; then
    BUFFER="cd "
    CURSOR=3
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER=" " CURSOR=1
  else
    BUFFER_=$BUFFER
    CURSOR_=$CURSOR
    zle expand-or-complete || zle expand-or-complete || {
      BUFFER="ls "
      CURSOR=3
      zle list-choices
      BUFFER=$BUFFER_
      CURSOR=$CURSOR_
    }
  fi
}
zle -N tab_list_files
bindkey '^I' tab_list_files

# uncomment the following line to prefix 'cd ' and './' 
# when listing dirs and executables respectively
#export TAB_LIST_FILES_PREFIX

# these two lines are usually included by oh-my-zsh, but just in case
autoload -Uz compinit
compinit

# uncomment the following line to complement tab_list_files with ^q
#bindkey '^q' push-line-or-edit

# License
#
# This script is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This script is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this script; if not, write to the
# Free Software Foundation, Inc., 59 Temple Place, Suite 330,
# Boston, MA  02111-1307  USA