Awk का उपयोग करके दो फ़ाइलों को संसाधित करना

Question

मैंने यूनिक्स और ऑक का उपयोग करते हुए दो फाइलों की तुलना की । यह वाकई दिलचस्प है। मैंने इसे पढ़ा और परीक्षण किया, लेकिन मैं इसे पूरी तरह से समझ नहीं पाया और अन्य मामलों में इसका उपयोग कर सकता हूं।

मेरे पास दो फाइलें हैं। file1एक के पास एक खेत है और दूसरे के पास 16 खेत हैं। मैं file1 के तत्वों को पढ़ना चाहता हूं और उनकी 3 के क्षेत्र के साथ तुलना करना चाहता हूं file2। यदि प्रत्येक तत्व के लिए एक मैच था, तो मुझे फ़ील्ड 5 का मान मिला file2। उदहारण के लिए:

फ़ाइल 1

1
2
3

फ़ाइल 2

2 2 2 1 2
3 6 1 2 4 
4 1 1 2 3
6 3 3 3 4 

तत्व 1 के लिए, file1मैं 5 के मानों को जोड़ना चाहता हूँ, file2जहाँ फ़ील्ड 3 का मान 1 है। और तत्व 2 और 3 के लिए भी ऐसा ही करें file1। 1 के लिए आउटपुट (3 + 4 = 7) है और 2 के लिए 2 है और 3 के लिए 4 है।

मुझे नहीं पता कि मुझे इसे awk के साथ कैसे लिखना चाहिए।

Answer 1

यहाँ एक तरीका है। मैंने इसे एक awk script के रूप में लिखा है ताकि मैं टिप्पणियों को जोड़ सकूँ:

#!/usr/local/bin/awk -f

{
    ## FNR is the line number of the current file, NR is the number of 
    ## lines that have been processed. If you only give one file to
    ## awk, FNR will always equal NR. If you give more than one file,
    ## FNR will go back to 1 when the next file is reached but NR
    ## will continue incrementing. Therefore, NR == FNR only while
    ## the first file is being processed.
    if(NR == FNR){
      ## If this is the first file, save the values of $1
      ## in the array n.
      n[$1] = 0
    }
    ## If we have moved on to the 2nd file
    else{
      ## If the 3rd field of the second file exists in
      ## the first file.
      if($3 in n){
        ## Add the value of the 5th field to the corresponding value
        ## of the n array.
        n[$3]+=$5
      }
    }
}
## The END{} block is executed after all files have been processed.
## This is useful since you may have more than one line whose 3rd
## field was specified in the first file so you don't want to print
## as you process the files.
END{
    ## For each element in the n array
    for (i in n){
    ## print the element itself and then its value
    print i,":",n[i];
    }
}

आप इसे एक फ़ाइल के रूप में सहेज सकते हैं, इसे निष्पादन योग्य बना सकते हैं और इसे इस तरह चला सकते हैं:

$ chmod a+x foo.awk
$ ./foo.awk file1 file2
1 : 7
2 : 2
3 : 4

या, आप इसे एक-लाइनर में संघनित कर सकते हैं:

awk '
     (NR == FNR){n[$1] = 0; next}
     {if($3 in n){n[$3]+=$5}}
     END{for (i in n){print i,":",n[i]} }' file1 file2

Answer 2

awk '
  NR == FNR {n[$3] += $5; next}
  {print $1 ": " n[$1]}' file2 file1

Comments

यह गैर मिलान वाले क्षेत्रों को जोड़कर कुछ अतिरिक्त काम करता है।

— इमैनुएल

@ इमानुएल, यह अभी भी फ़ाइल 2 की प्रति लाइन एक awk निर्देश है, जो इसे टेर्डन की तुलना में छोटा और तेज़ बनाता है

— स्टीफन चेज़लस

शानदार समाधान!

— रोनाल्ड पॉफर्ट