बैश से zsh में जाना [बंद]

Question

मैं बैश से जश की ओर बढ़ने पर विचार कर रहा हूं क्योंकि मैं अक्सर जश की प्रशंसा करते हुए पोस्ट पर आता हूं। मैं एक अनुभवी कमांड लाइन उपयोगकर्ता हूं और मैं मान रहा हूं कि मूल बातें बहुत अधिक हैं, इसलिए मैं आगे बढ़ने के लाभों को प्राप्त करने के लिए सलाह की तलाश कर रहा हूं, और किसी भी गोच को जागरूक होने के लिए।

कृपया प्रति उत्तर केवल एक सलाह दें। मैं काटने के आकार की चोंच की तलाश कर रहा हूँ जहाँ मैं वापस आ सकता हूँ और एक बार में यह जानने की कोशिश करने के बजाय स्थिर गति से जानकारी के अतिरिक्त बिट्स को अपने शेल उपयोग में एकीकृत कर सकता हूं।

Comments

मुझे यह जानकर अच्छा लगेगा कि क्या उबंटू के कमांड-इन-ज़ेड को ज़ेड के साथ एकीकृत करना संभव है। मैं इस (और कई अन्य परेशानियों) के कारण वापस बैश में चला गया।

— Marius Gedminas

अन्य स्टैक एक्सचेंज साइटों पर संबंधित थ्रेड्स: आकस्मिक उपयोग के लिए zsh पर स्विच करना? आपके .zshrc में क्या है? आप किस zsh फीचर्स का उपयोग करते हैं? Zsh की तुलना में बैश की अनूठी विशेषताएं क्या zsh के ऊपर बैश का उपयोग करने का कोई कारण है? क्या विशेषताएं zsh में हैं और बैश से गायब हैं, या इसके विपरीत?

— गिल्स

दो और दिलचस्प लिंक: "ZSH FAQ" zsh.sourceforge.net/FAQ & "ZSH आपका मित्र है" mikegrouchy.com/blog/zsh-is-your-friend.html

— Shadok

@ मार्गीगेडमिनस: ( यहां से ) zsh इसका समर्थन करता है, लेकिन आपको इसे मैन्युअल रूप से सक्षम करना होगा। बस source /etc/zsh_command_not_foundअपने को जोड़ो .zshrc।

— naught101

Answer 1

जैसा कि आप कहते हैं, zshकई मामलों में समान है bash। इसमें कुछ विशेषताएं हैं जो आपको नहीं मिलेंगी bash, और इसे शक्तिशाली तरीकों से बढ़ाया जा सकता है। एक तरह की क्रांति के रूप में आगे बढ़ने के बारे में न सोचें, बल्कि एक विकासवादी कदम की श्रृंखला के रूप में, जो आपके दैनिक कार्यों में आपकी मदद करें। यहाँ मेरे कुछ संकेत हैं .zshrc। यद्यपि आप कहते हैं कि आप सलाह के एकल टुकड़े पसंद करते हैं, यह पोस्ट एक लंबी सूची है। फिर भी एक-एक करके अंकों के माध्यम से जाना एक अच्छा विचार है। बस दिलचस्प बिट्स को अपने ~/.zshrcसाथ जोड़ें और पुनः लोड करें source ~/.zshrc। एक अंतिम टिप: के zshडिफ़ॉल्ट ("Emacs") कीबोर्ड शॉर्टकट के कीस्ट्रोक्स सीखें ^A ^E ^W Alt-F Alt-B Alt-P ^L ^R:। आप Altदो अलग-अलग कीस्ट्रोक्स द्वारा प्रतिस्थापित कर सकते हैं : Alt-Pके बराबर है ESC P।

---

यह आपको अधिक व्यापक टैब पूर्णता प्रदान करता है।

autoload -U compinit
compinit

दोनों सिरों से पूरा होने वाला टैब।

setopt completeinword

टैब पूरा होना केस-असंवेदनशील होना चाहिए।

zstyle ':completion:*' matcher-list 'm:{a-zA-Z}={A-Za-z}'

किलकारी के लिए बेहतर समापन।

zstyle ':completion:*:killall:*' command 'ps -u $USER -o cmd'

"शब्द" की परिभाषा में परिवर्तन, उदाहरण के लिए ^ W के साथ।

autoload select-word-style
select-word-style shell

एलएस के लिए रंग।

if [[ -x "`whence -p dircolors`" ]]; then
  eval `dircolors`
  alias ls='ls -F --color=auto'
else
  alias ls='ls -F'
fi

एलएस के लिए शॉर्टकट।

alias ll='ls -l'
alias la='ls -a'

सभी खुले गोले के लिए एक इतिहास; 10,000 प्रविष्टियाँ संग्रहीत करें। यह आपके लिए पिछली बार उपयोग किए गए आदेशों को खोजने के लिए एक उपयोगी मेमोरी सहायता में बनाता है ./configure। Alt-P का उपयोग करें (इस तरह शुरू होने वाली कमांड खोजें) और ^ आर (इतिहास में खोज) उदारतापूर्वक।

HISTFILE=~/.zhistory
HISTSIZE=SAVEHIST=10000
setopt sharehistory
setopt extendedhistory

विस्तारित ग्लोबिंग के सभी प्रकार को सक्षम करता है, जैसे कि ls ** / *। Txt (सभी पाठ फ़ाइलों को ढूंढें), ls -d *(D)(("" के साथ शुरू होने वाली सभी फ़ाइलों को दिखाएं)। अधिक जानने के लिए man zshexpn, "FILENAME उत्पत्ति" अनुभाग पर जाएँ।

# superglobs
setopt extendedglob
unsetopt caseglob

यह आपके इतिहास में आदेशों को याद किए बिना उन्हें याद रखने के लिए उपयोगी है।

setopt interactivecomments # pound sign in interactive prompt

टाइप करें ".." के बजाय "सीडी ..", "/ यूएसआर / शामिल करें" के बजाय "सीडी / यूएसआर / शामिल करें"।

setopt auto_cd

अच्छा शीघ्र।

PS1='[%T] %n@%m:%~# '

10 सेकंड से अधिक समय लेने वाले आदेशों के लिए CPU उपयोग आँकड़े प्रदर्शित करें

REPORTTIME=10

कुछ आदेशों का आप उबंटू में बड़े पैमाने पर उपयोग करते हैं।

alias 'a=sudo aptitude'
alias 'ai=sudo aptitude install'
alias 'ar=sudo aptitude remove'
alias 'au=sudo aptitude update'
alias 'ag=sudo aptitude safe-upgrade'
alias 'as=apt-cache search'
alias 'aw=apt-cache show'

अपने आकार के अनुसार क्रमबद्ध संकुल सूची - यह तय करते समय कि कौन सा संकुल आपको डिस्क स्थान पर ले जा रहा है।

function apt-list-packages {
  dpkg-query -W --showformat='${Installed-Size} ${Package} ${Status}\n' | grep -v deinstall | sort -n | awk '{print $1" "$2}'
}

Comments

उपयोगी होने के लिए +1। -1 अधिशेष emacs वकालत के लिए!

— त्रिफलक

आपको [ github.com/robbyrussell/oh-my-zshades(oh-my-zsh) भी पसंद आ सकता है जो zsh में बहुत सारे प्लगइन्स जोड़ता है।

— RedPixel

Answer 2

मैं पुस्तक को bash से Z Shell तक सुझाऊँगा । यह आपके शेल को स्विच करने के लिए आवश्यक सभी सलाह है। यह दोनों गोले के अंतर को स्पष्ट करता है और एक नए ज़शर के लिए आसान बनाता है।

Comments

पुस्तक समान रूप से बाश और zsh दोनों उपयोगकर्ताओं के लिए बढ़िया है। आपको यह पसंद करना होगा कि प्रत्येक अध्याय "बैश और ज़ीश दोनों यह सब कर सकता है" के साथ कैसे शुरू होता है और फिर एक और 30 पृष्ठों की ओर जाता है "और यहाँ zsh केवल सामान है"

— रिक

Answer 3

यहाँ मेरा .zshrc है और यह सबसे महत्वपूर्ण बात है! zsh के पास बहुत सारे विकल्प हैं जिनका आप उपयोग कर सकते हैं, इसलिए नेट के आस-पास के सभी उदाहरणों को देखें या Zsh होमपेज पर प्रलेखन पढ़ें ।

मेरे .zshrc में कमांड लाइन के दाहिने हिस्से में टाइमस्टैम्प के अलावा कोई भी बहुत अच्छी चीजें नहीं हैं।

Btw, हर जगह जहाँ कुछ उदाहरण टैब-तारीफ की कोशिश करना याद रखें:

mplayer -a[tab]

कुछ इस तरह दिखाएगा:

mplayer -a
 -ac                 -- force usage of a specific audio codec
 -af                 -- activate audio filters
 -afm                -- force usage of a specific audio codec family
 -alang              -- select the DVD audio language
 -ao                 -- specify audio driver
 -aop                -- specify audio output filter

और यदि आप पासवर्ड-रहित ssh- कीज़ या ssh- एजेंट का उपयोग करते हैं, तो आप इसे दूरस्थ दूरस्थ फ़ाइलों के लिए उपयोगी पा सकते हैं:

scp apollo:/home/user/[tab]
Desktop/ Documents/ Downloads/ Music/ Pictures/ Public/ Templates/ Videos/

सूची प्राप्त करने के बाद आप विभिन्न संभावनाओं के माध्यम से चक्र करने के लिए टैब को अधिक बार दबा सकते हैं।

लेकिन चेतावनी दी जाए, यह शेल आपको आलसी बना देगा और आपको महसूस कराएगा कि एक मानक शेल बेवकूफ और कष्टप्रद है!

Answer 4

विशेष रूप से उपयोगी विस्तारित दस्ताने की एक जोड़ी:

1 rmdir *(/^F)- वर्तमान निर्देशिका के तहत सभी गैर-खाली निर्देशिकाओं को हटा दें

2- grep traceback /srv/log/**/*(.m-2)- पिछले दो दिनों में संशोधित फाइलों में इस रेगेक्स को देखें

3- chmod g+w **/*(U^I)- मेरे द्वारा स्वामित्व वाली कोई भी फाइल बनाएं और समूह-लेखन योग्य न होकर समूह-लेखन योग्य हों

हां, निश्चित रूप से आप इसे लिख सकते हैं, findलेकिन इससे हटना आसान है। इसमें दो कमियां हैं, निष्पक्ष होना, दोनों को कमांड लाइन पर विस्तारित किया जाना है: यदि यह कई हजारों फाइलों से मेल खाती है तो कमांड लाइन बहुत लंबी हो जाएगी और यह विफल हो जाएगी, और दूसरी सभी फाइलें मिल जाती हैं फ़ाइल चलने से पहले।

(यदि आपको setopt extendedglobपहले से नहीं है तो आपको इसकी आवश्यकता होगी )

Answer 5

मुझे नहीं पता है कि बहुत मार के बारे में, इसलिए मैं गणना नहीं कर सकता। मेरे zsh config फाइल से कुछ स्निपेट।

कुछ विन्यास

HISTFILE=~/.zsh_history
HISTSIZE=1000
SAVEHIST=1000
REPORTTIME=10 # print elapsed time when more than 10 seconds
setopt NO_HUP
setopt NO_LIST_BEEP
setopt LOCAL_OPTIONS # allow functions to have local options
setopt LOCAL_TRAPS # allow functions to have local traps
setopt HIST_VERIFY
setopt SHARE_HISTORY # share history between sessions ???
setopt EXTENDED_HISTORY # add timestamps to history
setopt PROMPT_SUBST
setopt CORRECT
setopt COMPLETE_IN_WORD
setopt IGNORE_EOF

setopt APPEND_HISTORY # adds history
setopt INC_APPEND_HISTORY SHARE_HISTORY  # adds history incrementally and share it across sessions
setopt HIST_IGNORE_ALL_DUPS  # don't record dupes in history
setopt HIST_REDUCE_BLANKS
# Leave some chars out of the out of WORDCHARS so ^W acts more nicely 
WORDCHARS='*?_-[]~\!#$%^(){}<>|`@#$%^*()+:?'

शीघ्र में पकड़ें

if [[ -n $SSH_CONNECTION ]]; then
  export PS1='%m:%3~$(git_info_for_prompt)%# '
else
  export PS1='%3~$(git_info_for_prompt)%# '
fi

कुछ हॉटकीज़, लाइन की शुरुआत में कुछ टेक्स्ट डालें।

insert_sudo     () { zle beginning-of-line; zle -U "sudo "         }
insert_apt      () { zle beginning-of-line; zle -U "sudo apt-get " }
insert_gem      () { zle beginning-of-line; zle -U "sudo gem "     }
insert_install  () { zle -U "install "     }

zle -N insert-sudo      insert_sudo
zle -N insert-apt       insert_apt
zle -N insert-gem       insert_gem
zle -N insert-install   insert_install

bindkey "^B" insert-gem
bindkey "^N" insert-install
bindkey "^k" insert-sudo
bindkey "^a" insert-apt

फ़ंक्शंस, मैं तो ~ / .zsh / फ़ंक्शंस में संग्रहीत करता हूं

Git_info_for_prompt

local g="$(git rev-parse --git-dir 2>/dev/null)"
if [ -n "$g" ]; then
  local r
  local b
  if [ -d "$g/../.dotest" ]
  then
    if test -f "$g/../.dotest/rebasing"
    then
      r="|REBASE"
    elif test -f "$g/../.dotest/applying"
    then
      r="|AM"
    else
      r="|AM/REBASE"
    fi
    b="$(git symbolic-ref HEAD 2>/dev/null)"
  elif [ -f "$g/.dotest-merge/interactive" ]
  then
    r="|REBASE-i"
    b="$(cat "$g/.dotest-merge/head-name")"
  elif [ -d "$g/.dotest-merge" ]
  then
    r="|REBASE-m"
    b="$(cat "$g/.dotest-merge/head-name")"
  elif [ -f "$g/MERGE_HEAD" ]
  then
    r="|MERGING"
    b="$(git symbolic-ref HEAD 2>/dev/null)"
  else
    if [ -f "$g/BISECT_LOG" ]
    then
      r="|BISECTING"
    fi
    if ! b="$(git symbolic-ref HEAD 2>/dev/null)"
    then
      if ! b="tag: $(git describe --exact-match HEAD 2>/dev/null)"
      then
        b="$(cut -c1-7 "$g/HEAD")..."
      fi
    fi
  fi

  if [ -n "$1" ]; then
    printf "$1" "${b##refs/heads/}$r"
  else
    printf "[%s]" "${b##refs/heads/}$r"
  fi
fi

कुछ गितूब विकल्प

#compdef github

_github() {
  if (( CURRENT > 2 )); then
    # shift words so _arguments doesn't have to be concerned with second command
    (( CURRENT-- ))
    shift words
    # use _call_function here in case it doesn't exist
    _call_function 1 _github_${words[1]}
  else
    _values "github command" \
     "fetch[Fetch from a remote to a local branch.]" \
     "ignore[Ignore a SHA (from 'github network commits')]" \
     "fetch_all[Fetch all refs from a user]" \
     "info[Info about this project.]" \
     "browse[Open this repo in a web browser.]" \
     "home[Open this repo's master branch in a web browser.]" \
     "clone[Clone a repo.]" \
     "pull-request[Generate the text for a pull request.]" \
     "network[Project network tools.]" \
     "pull[Pull from a remote.]" \
     "track[Track another user's repository.]"
  fi
}

_github_pull() {
  _arguments \
    "--merge[Automatically merge remote's changes into your master.]"
}
_github_clone() {
  _arguments \
    "--ssh[Clone using the [e-mail] style url.]"
}

_github_track() {
  _arguments \
    "--private[Use [e-mail]: instead of git://github.com/.]" \
    "--ssh[Equivalent to --private.]"
}

_github_network() {
  if (( CURRENT > 2 )); then
    # shift words so _arguments doesn't have to be concerned with second command
    (( CURRENT-- ))
    shift words
    # use _call_function here in case it doesn't exist
    _call_function 1 _github_network_${words[1]}
  else
    _values "github network command" \
     "web[Open network in a web browser.]" \
     "list[List networked repositories.]" \
     "fetch[Fetched commits for a given networked repository.]" \
     "commits[List networked commits not pulled into this repo.]"
  fi
}

_github_network_commits() {
  _arguments \
    "--project[Filter commits on a certain project.]" \
    "--author[Filter commits on a email address of author.]" \
    "--common[Show common branch point.]" \
    "--nocache[Do not use the cached network data.]" \
    "--sort[How to sort : date(*), branch, author.]" \
    "--thisbranch[Look at branches that match the current one]" \
    "--applies[Filter commits to patches that apply cleanly.]" \
    "--limit[Only look through the first X heads - useful for really large projects]" \
    "--before[Only show commits before a certain date.]" \
    "--after[Only show commits after a certain date.]" \
    "--shas[Only show shas.]" \
    "--cache[Use the network data even if it's expired.]" \
    "--noapply[Filter commits to patches that do not apply cleanly.]"
}

Answer 6

मैं एक ही यात्रा में हूँ :)

अब तक मैंने पाया है कि बात एक अच्छी कॉन्फ़िगरेशन फ़ाइल (.zshrc) की है।

इसे एक उदाहरण के रूप में लें http://matt.blissett.me.uk/linux/zsh/zshrc , टिप्पणियों को देखें और अपने तरीके से हैक करें। Stackoverflow और severphault और अच्छी जगह भी खोज करने के लिए।

मुझे अभी तक http://dotfiles.org/.zshrc में डाइव करना है , लेकिन मेरे पास इतना समय नहीं है कि मैं ढीला हो जाऊं :)

Answer 7

विस्तारित ग्लोबिंग और पुनरावर्ती ग्लब्स के बारे में जानें।

Zstyle के बारे में थोड़ा जानें और कैसे विभिन्न चीजें (विशेष रूप से पूर्ण) आप zstyle का उपयोग करके उनके कॉन्फ़िगरेशन को ट्यून करते हैं।

सहयोगी सरणियों में देखें। इसके अलावा मानक सरणियों (बैश से मतभेदों से सावधान रहें, बेहतर के लिए!)

यदि आप नियमित अभिव्यक्तियों का उपयोग करते हैं, तो देखें =~(जिसमें बैश भी है) और विचार करें:setopt rematch_pcre

उन लिपियों को लिखने से बचें जो बहुत कम मात्रा में zsh के जादू पर निर्भर करती हैं, क्योंकि जब यह उपयोग करने के लिए शानदार है, तो zsh केवल लिखने की ओर जा सकता है। यदि आप बहुत अधिक उपयोग कर रहे हैं, तो इस बारे में सोचें कि पायथन जैसे भाषा में कब स्विच करना है।

Zsh मोहक है। यह अंधेरा पक्ष है। स्वागत हे।

Answer 8

बड़ा लाभ - कई कमांड के लिए प्री-पैकेज्ड पूर्ण स्क्रिप्ट के साथ उत्कृष्ट टैब पूरा। इसका उदाहरण यहां दिखाया गया है apt-get<TAB>:

apt-get
action
autoclean        build-dep        clean            dselect-upgrade  install          remove           update           
autoremove       check            dist-upgrade     help             purge            source           upgrade          

Answer 9

मैंने बातचीत का एक हिस्सा दिया है और कई लोगों को zsh में बदल दिया है। मैं एक स्टार्टर और गथूब में अपने स्वयं के ज़ीश विन्यास की एक प्रति के साथ-साथ मेरे (क्या फायदे हैं) नोटों का एक गितुब रेपो रखता हूँ।

http://github.com/mitechie/zshrc

Answer 10

एक और शानदार रेस्त्रा zsh प्रेमी पृष्ठ है (जो कि grml zsh साइट से आता है )।