एक्सेल: कई स्तंभों के साथ एक अनुक्रमित शीट को दो कॉलम में बदलना

Question

मेरे पास इस तरह की पंक्तियों के साथ एक एक्सेल शीट है:

Fruit     | Apple  | Banana | Grape | Peach
Vegetable | Cabbage| Lettuce| Carrot|

और इंडेक्स (पहला कॉलम) को डुप्लिकेट करते हुए दो कॉलम आउटपुट चाहेंगे:

Fruit     | Apple
Fruit     | Banana
Fruit     | Grape
Fruit     | Peach
Vegetable | Cabbage
Vegetable | Lettuce
Vegetable | Carrot

उपयोग की सादगी दक्षता से अधिक महत्वपूर्ण है क्योंकि डेटा छोटा है और उपयोगकर्ता अनुभवहीन हैं। धन्यवाद

Comments

क्या कोई ऐसा कार्यक्रम है जो उक्त प्रारूप में आउटपुट उत्पन्न कर रहा है? यदि डेटा सेट छोटा है, तो क्या आपने एक्सेल में कॉपी पेस्ट और ट्रांसपोज़ फंक्शन की कोशिश की है ?

— यमक

Answer 1

अगर हमारे पास यह शीट 1 में है :

और इस लघु मैक्रो को चलाएं:

Sub ReOrganize()
    Dim sh1 As Worksheet, sh2 As Worksheet
    Set sh1 = Sheets("Sheet1")
    Set sh2 = Sheets("Sheet2")
    Dim N As Long, M As Long, i As Long, j As Long, K As Long
    Dim t1 As String, t2 As String
    N = sh1.Cells(Rows.Count, "A").End(xlUp).Row
    K = 1

    For i = 1 To N
        t1 = sh1.Cells(i, 1).Value
        M = sh1.Cells(i, Columns.Count).End(xlToLeft).Column
        For j = 2 To M
            sh2.Cells(K, 1).Value = t1
            sh2.Cells(K, 2).Value = sh1.Cells(i, j)
            K = K + 1
        Next j
    Next i
End Sub

हम इसे शीट 2 में प्राप्त करेंगे :