कीबोर्ड शॉर्टकट का उपयोग करके एक्सेल सेल को कैसे अचयनित करें?

Question

कीबोर्ड शॉर्टकट Ctrl+ क्लिक का उपयोग करके एक से अधिक एक्सेल सेल (या तो सन्निहित या नहीं) का चयन कर सकते हैं ।

आप इन पहले से चयनित कोशिकाओं में से एक या अधिक का चयन कैसे रद्द कर सकते हैं?

Answer 1

SHIFT और / या CTRL कुंजी का उपयोग करके आप गैर-सन्निहित श्रेणियों का चयन कर सकते हैं। हालाँकि, यदि आप किसी कक्ष या क्षेत्र का चयन गलती से करते हैं, तो चयन से बिना हटाए और पूर्ण प्रारंभ किए बिना इसे निकालने का कोई तरीका नहीं है। यह पृष्ठ VBA प्रक्रियाओं, UnSelectActiveCell और UnSelectCurrentArea का वर्णन करता है, जो सक्रिय सेल या क्षेत्र को वर्तमान चयन से सक्रिय सेल वाले क्षेत्र को हटा देगा। चयन में अन्य सभी कक्ष चयनित रहेंगे।

आपकी सबसे अच्छी शर्त यह होगी कि आप इन्हें अपने व्यक्तिगत मैक्रो वर्कबुक में शामिल करें ताकि वे एक्सेल में सभी खुली कार्यपुस्तिकाओं के लिए उपलब्ध हों।

यह प्रक्रिया सक्रिय सेल को चयन से हटा देगी ।

Sub UnSelectActiveCell()
    Dim R As Range
    Dim RR As Range
    For Each R In Selection.Cells
        If StrComp(R.Address, ActiveCell.Address, vbBinaryCompare) <> 0 Then
            If RR Is Nothing Then
                Set RR = R
            Else
                Set RR = Application.Union(RR, R)
            End If
        End If
    Next R
    If Not RR Is Nothing Then
        RR.Select
    End If
End Sub

यह प्रक्रिया सक्रिय सेल वाले क्षेत्र को चयन से हटा देगी।

Sub UnSelectCurrentArea()
    Dim Area As Range
    Dim RR As Range

    For Each Area In Selection.Areas
        If Application.Intersect(Area, ActiveCell) Is Nothing Then
            If RR Is Nothing Then
                Set RR = Area
            Else
                Set RR = Application.Union(RR, Area)
            End If
        End If
    Next Area
    If Not RR Is Nothing Then
        RR.Select
    End If
End Sub

Comments

मुझे आश्चर्य है कि यदि आप UnSelectActiveCellतेजी से बना सकते हैं यदि आप श्रेणियों के आधार पर और केवल कोशिकाओं के माध्यम से लूप करते हैं तो Not Intersect(Area,ActiveCell) Is Nothing। यदि Intersectफ़ंक्शन फ़ंक्शन की तुलना StrCompमें कॉल में कमी की भरपाई नहीं कर सकता है, तो यह मामला नहीं हो सकता है Union।

— इंजीनियर टोस्ट

गॉड एक्सेल इतना पुराना

— लोल है

क्या अभी भी यही मामला है? मैं अपने जीवन के बारे में पता नहीं लगा सकता कि deselectसेल कैसी है । यह बिल्कुल हास्यास्पद है! मैं हर 2 वें कॉलम का चयन कर रहा हूं और अगर मैं कोई गलती करता हूं, तो मुझे शुरू करना होगा? वह% और * आईएनजी पागल है!

— pookie

Answer 2

कई कोशिकाओं को अचयनित करने का एक अधिक मजबूत तरीका इस एक्सटेंडऑफिस लेख में वर्णित है । इसमें एक अतिरिक्त संकेत शामिल है, लेकिन आप एक बार में कई सेल / चयनों की मनमानी संख्या का चयन रद्द कर सकते हैं (केवल सक्रिय कक्ष या क्षेत्र का चयन रद्द करने के बजाय)

मैं यहाँ स्क्रिप्ट पोस्ट कर रहा हूँ, एक छोटे प्रयोज्य सुधार के साथ (मूल रूप से मूल पोस्ट से अनावश्यक रूप से पहला संकेत हटा दिया गया है):

Sub DeselectCells()
    Dim rng As Range
    Dim InputRng As Range
    Dim DeleteRng As Range
    Dim result As Range
    xTitleId = "Deselect Cells"

    Set InputRng = Application.Selection
    If InputRng.Count <= 1 Then
        Set InputRng = Application.InputBox("Range :", xTitleId, InputRng.Address, Type:=8)
    End If
    Set DeleteRng = Application.InputBox("Delete Range", xTitleId, Type:=8)
    For Each rng In InputRng
        If Application.Intersect(rng, DeleteRng) Is Nothing Then
            If result Is Nothing Then
                Set result = rng
            Else
                Set result = Application.Union(result, rng)
            End If
        End If
    Next
    result.Select
End Sub

इसका इस्तेमाल करने के लिए, यदि आप कोई चयन, आह्वान DeselectCellsकिए जाने की मैक्रो (जो सबसे अच्छा आपके व्यक्तिगत मैक्रो पुस्तक में बचाया और एक शॉर्टकट को सौंपा जा रहा है) और सेल का चयन डी पॉपअप में चयनित दिखाई देने वाले:

Comments

अच्छा लगा, बढ़िया जवाब।

— बरगी

Answer 3

अब CTRL को गलती से चयनित सेल से अचयनित करना संभव है। यह Office 365 या हाल के संस्करणों में एक नया बनाया गया फ़ंक्शन है। आखिरकार!