पंक्ति और मिलान कॉलम नाम II में मिलान का मान ढूँढें

-1

मेरा प्रश्न इसके समान है, लेकिन इससे भिन्न है एक पंक्ति और रिटर्न कॉलम नाम में मिलान मूल्य ज्ञात कीजिए?

मेरे पास दो टैब के साथ एक स्प्रेडशीट है:

टैब ए में एक कॉलम है जो ईमेल पतों की एक सूची है (इस टैब में कई अन्य कॉलम हैं)
टैब बी में 4 कॉलम हैं, जिनमें से प्रत्येक में विभिन्न समूहों के ईमेल पते हैं। प्रत्येक स्तंभ में अद्वितीय ईमेल पते हैं (स्तंभों के बीच कोई डुप्लिकेट नहीं)। इसलिए ग्रुप 1 में कॉलम A में 50 ईमेल हैं, और ग्रुप 2 में कॉलम बी, आदि में 100 ईमेल हैं।

मैं टैब A में एक नए कॉलम में एक सूत्र सम्मिलित करना चाहूंगा, जो टैब बी के 4 कॉलमों में से प्रत्येक के ईमेल को देखता है और उनकी तुलना टैब ए में ईमेल पते से करता है। यदि कोई मेल मिलता है, तो कॉलम हेडर लिखें ।

किसी भी मदद के लिए बहुत बहुत धन्यवाद & gt;;;

microsoft-excel google-spreadsheets

— Goolie
स्रोत

1

क्या आप एक्सेल या Google स्प्रेडशीट में ऐसा कर रहे हैं?

— ale

2

और आपके साथ एक छोटा भी हो सकता है SUMPRODUCT:

=INDEX(Sheet2!$A$1:$D$1,SUMPRODUCT((A2=Sheet2!$A:$D)*1*{1,2,3,4}))

और मैंने यह भी देखा कि यदि कोई मेल नहीं मिलता है (जैसे इस उत्तर से पहले पोस्ट किए गए अन्य फॉर्मूले के साथ), तो वह फॉर्मूला के कॉलम इंडेक्स को स्वयं लौटा देगा (यानी यदि फॉर्मूला बी में है, तो यह नाम वापस कर देगा। कॉलम बी हैडर का)। इससे बचने का एक तरीका है उपयोग करना IF जैसा कि:

=INDEX(Sheet2!$A$1:$D$1,IF(SUMPRODUCT((A2=Sheet2!A2:D8)*1)=0,NA(),SUMPRODUCT((A2=Sheet2!A2:D8)*1*{1,2,3,4})))

यह थोड़ा लंबा है ^ ^;

— Jerry
स्रोत

+1 नाइस! (टिप्पणी के लिए और पाठ की जरूरत है)

— teylyn

1

निम्नलिखित सरणी सूत्र काम करना चाहिए। टैब ए में नए कॉलम की पंक्ति 2 सेल में दर्ज करें, और फिर इसे ईमेल की टैब ए सूची के नीचे कॉपी करें।

  =INDEX(Sheet2!$A$1:$D$1,1,SUM((A2=Sheet2!$A$2:$A$50)*1+(A2=Sheet2!$B$2:$B$100)*2+(A2=Sheet2!$C$2:$C$50)*3+(A2=Sheet2!$D$2:$D$50)*4))

एक सरणी सूत्र के रूप में, इसके साथ प्रवेश करने की आवश्यकता है नियंत्रण - खिसक जाना - दर्ज कुंजी संयोजन।

सूत्र के कुछ हिस्सों को तोड़ने के लिए, एक क्षण के लिए मान लें कि टैब बी में ईमेल डेटा का केवल एक कॉलम है, उदाहरण के लिए, स्तंभ A:

$A2=Sheet2!$A$2:$A$50 टैब बी के कॉलम बी के सभी ईमेल के साथ टैब ए के सेल ए 2 में ईमेल की तुलना करता है, जिससे मैच परिणाम की एक सरणी का निर्माण होता है {False,True,False...False}। क्योंकि टैब बी में ईमेल अद्वितीय हैं, इसलिए अधिकतम 1 पर हो सकता है True सरणी में।
अगला, वह सरणी 1 से गुणा किया जाता है - ($A2=Sheet2!$A$2:$A$50)*1 - एक और सरणी '{0,1,0 ... 0}' का उत्पादन करने के लिए, जिसे "A2 में मान" के रूप में टैब बी के पहले कॉलम में डेटा रेंज की दूसरी पंक्ति में मूल्य के साथ मेल खाता है। ।
उस सरणी को सारांशित करने से मान 1 उत्पन्न होता है, जिसका उपयोग टैब बी के हेडर पंक्ति के पहले कॉलम में मान को बाहर निकालने के लिए किया जाता है: INDEX($A$1:$D$1,1,SUM(($A2=Sheet2!$A$2:$A$50)*1))।
हम टैब B के कॉलम B, C, और D के साथ समान सारणी की तुलना कर सकते हैं, परिणाम को 2, 3 और 4 से क्रमशः गुणा करके, टैब B के दूसरे, तीसरे, आदि कॉलम में एक मैच को सूचित करने के लिए।

— chuff
स्रोत

चफ़, बहुत बहुत धन्यवाद! मैंने एक vlookup फ़ंक्शन का उपयोग करके समाप्त किया, जो मेरे लिए बेहतर काम करता है, क्योंकि मैंने उन 4 ईमेल कॉलमों को एक एकल कॉलम में ढहा दिया, और एक दूसरा कॉलम जोड़ा जिसमें समूह का नाम था। फिर से मैं वास्तव में इसकी सराहना करता हूं!

— Goolie

+1। इसके अलावा, किसी भी कारण से केवल कॉलम B में 2: 100 से पंक्तियों की सीमा है? :)

— Jerry

1

आप यह भी कर सकते हैं कि A2 = श्रेणी के बजाय काउंटिफ () का उपयोग करते हुए एक बिना सरणी सूत्र के साथ:

=INDEX(Sheet2!$A$1:$D$1,(COUNTIF(Sheet2!$A:$A,Sheet1!$A2)*1)+(COUNTIF(Sheet2!$B:$B,Sheet1!A2)*2)+(COUNTIF(Sheet2!$C:$C,Sheet1!A2)*3)+(COUNTIF(Sheet2!$D:$D,Sheet1!A2)*4))

— teylyn
स्रोत

+1 काम करता है और बिना सरणियों के भी!

— Jerry