एक साथ एमएस ऑफिस में एक फ़ाइल का नाम बदलने और पुराने संस्करण को हटाने के लिए कैसे?

Question

Microsoft Office में, जब पिछली फ़ाइल नाम की एक प्रति रखे बिना फ़ाइल को किसी भिन्न फ़ाइल नाम में सहेजना चाहते हैं, तो ऐसा करने के लिए दो चरणों की आवश्यकता होती है:

• सबसे पहले, फ़ाइल -> इस रूप में सहेजें ... और नया नाम चुनें। फ़ाइल की एक प्रति बनाई जाती है।
• फिर, विंडोज एक्सप्लोरर में जाएं और पुरानी फ़ाइल को पुराने नाम से हटा दें।

मैं इन चरणों को "एक ही चरण में, Office से" फ़ाइल का नाम बदलकर सरल करना चाहूंगा। मैं ये कैसे करूं?

अधिक मनोरंजक और गूढ़ संस्करण के लिए, संशोधन 1 देखें ।

Comments

@ राममाउंड मुझे लगता है कि मैं यह देखने में विफल रहता हूं कि यह कैसे एक समाधान के साथ कोई समस्या नहीं है (ट्रैविस के पास एक बेहतर समाधान है कि मैं क्या कर रहा हूं और रोविउसर बनाता है ऐसा लगता है कि यह सबसे अच्छा उत्तर या तो वीबीए मैक्रो है - जो मैं कर सकता हूं, मैं किसी कारण के लिए ऐसा करने के लिए नहीं सोचा था - या एक वास्तविक VSTO संकलित ऐड-ऑन)

— एंडरलैंड

एक साथ ? खैर, जब आपको जवाब मिल जाए तो एक बार में दो जगहों पर होने का मेरा तरीका बताएं :-)

— MDMoore313

आप नहीं कर सकते क्योंकि यूरोपीय संघ ने उस एकीकरण को सीमित कर दिया है जिसे एमएस को अपने उत्पादों के बीच बनाने की अनुमति है। एक फ़ाइल का नाम बदलने के लिए कार्यालय की अनुमति देना उन नियमों को तोड़ देगा और इसे एक मोनोपली बना देगा

— चाड

@ क्या तुम यहाँ मजाक कर रहे हो? मेरा मतलब है कि OpenOffice सिर्फ एक नाम बदलने का कार्य भी कर सकता है।

— Heinrich5991

Answer 1

इसका उत्तर देने का "सबसे आसान" तरीका इस उत्तर पर महत्वपूर्ण रूप से निर्मित होता है ।

1. सामान्य .otm टेम्पलेट में निम्नलिखित कोड डालें ( C:\Documents and Settings\user name\Application Data\Microsoft\Templatesवर्ड के लिए विंडोज 7 के लिए पाया गया )
2. Normal.dotm को सेव करें
3. इसे वर्ड में क्विकलैन्च टूलबार में जोड़ें।
4. वैकल्पिक - इसके लिए एक कीबोर्ड शॉर्टकट को रीमैप करें
5. वैकल्पिक - डिजिटल रूप से अपने टेम्पलेट पर हस्ताक्षर करें (अनुशंसित)

ध्यान दें कि यह वास्तव में पुरानी फ़ाइल को पूरी तरह से ट्रैश करने के बजाय रीसायकल बिन में ले जाता है और नई फ़ाइल का नाम बहुत सुविधाजनक तरीके से सेट करता है।

---

Option Explicit

 'To send a file to the recycle bin, we'll need to use the Win32 API
 'We'll be using the SHFileOperation function which uses a 'struct'
 'as an argument. That struct is defined here:
Private Type SHFILEOPSTRUCT
    hwnd As Long
    wFunc As Long
    pFrom As String
    pTo As String
    fFlags As Integer
    fAnyOperationsAborted As Long
    hNameMappings As Long
    lpszProgressTitle As Long
End Type

 ' function declaration:
Private Declare Function SHFileOperation Lib "shell32.dll" Alias "SHFileOperationA" (lpFileOp As SHFILEOPSTRUCT) As Long

 'there are some constants to declare too
Private Const FO_DELETE = &H3
Private Const FOF_ALLOWUNDO = &H40
Private Const FOF_NOCONFIRMATION = &H10
Private Const FOF_SILENT = &H4

Function RecycleFile(FileName As String, Optional UserConfirm As Boolean = True, Optional HideErrors As Boolean = False) As Long
     'This function takes one mandatory argument (the file to be recycled) and two
     'optional arguments: UserConfirm is used to determine if the "Are you sure..." dialog
     'should be displayed before deleting the file and HideErrors is used to determine
     'if any errors should be shown to the user

    Dim ptFileOp As SHFILEOPSTRUCT
     'We have declared FileOp as a SHFILEOPSTRUCT above, now to fill it:
    With ptFileOp
        .wFunc = FO_DELETE
        .pFrom = FileName
        .fFlags = FOF_ALLOWUNDO
        If Not UserConfirm Then .fFlags = .fFlags + FOF_NOCONFIRMATION
        If HideErrors Then .fFlags = .fFlags + FOF_SILENT
    End With
     'Note that the entire struct wasn't populated, so it would be legitimate to change it's
     'declaration above and remove the unused elements. The reason we don't do that is that the
     'struct is used in many operations, some of which may utilise those elements

     'Now invoke the function and return the long from the call as the result of this function
    RecycleFile = SHFileOperation(ptFileOp)

End Function


Sub renameAndDelete()

    ' Store original name
    Dim sOriginalName As String
    sOriginalName = ActiveDocument.FullName

    ' Save As
    Dim sFilename As String, fDialog As FileDialog, ret As Long
    Set fDialog = Application.FileDialog(msoFileDialogSaveAs)

    'set initial name so you don't have to navigate to
    fDialog.InitialFileName = sOriginalName

    ret = fDialog.Show

    If ret <> 0 Then
        sFilename = fDialog.SelectedItems(1)
    Else
        Exit Sub
    End If

    Set fDialog = Nothing

    'only do this if the file names are different...
    If (sFilename <> sOriginalName) Then
        'I love vba's pretty code
         ActiveDocument.SaveAs2 FileName:=sFilename, FileFormat:= _
            wdFormatXMLDocument, LockComments:=False, Password:="", AddToRecentFiles _
            :=True, WritePassword:="", ReadOnlyRecommended:=False, EmbedTrueTypeFonts _
            :=False, SaveNativePictureFormat:=False, SaveFormsData:=False, _
            SaveAsAOCELetter:=False, CompatibilityMode:=14

        ' Delete original (don't care about errors, I guess)
        Dim hatersGonnaHate As Integer
        hatersGonnaHate = RecycleFile(sOriginalName, False, True)

    End If

End Sub

Comments

अच्छा कार्य। इस तरह के सवाल और जवाब सुपरयूजर के बारे में क्या हैं।

— xdumaine

मैं इसे बड़े पैमाने पर इस्तेमाल कर रहा हूं। धन्यवाद सुपरयुजर!

— एंडरलैंड

Answer 2

आप इसे कार्यक्षमता में निर्मित नहीं कर सकते। जैसा कि कार्यालय में यह प्रलेखन है

फ़ाइल का नाम बदलने से मौजूदा फ़ाइल का फ़ाइल नाम बदल जाता है। आप किसी फ़ाइल का नाम नहीं बदल सकते हैं जबकि किसी के पास किसी भी कार्यक्रम में खुला है। फ़ाइल बंद होनी चाहिए, और यदि यह एक साझा फ़ाइल है, तो इसे अवश्य चेक किया जाना चाहिए। आप एक खुली फ़ाइल को एक नए नाम से सहेज सकते हैं, लेकिन मूल नाम के साथ फ़ाइल की एक प्रतिलिपि अभी भी मौजूद होगी।

ऐसा लगता है कि VSTO या VBA (ओलिवर के जवाब में) के साथ एक कस्टम "Rename As ..." फंक्शन बनाकर ऐसा कुछ बनाया जा सकता है । आपको बस एक नई प्रति सहेजने के लिए इसे प्रोग्राम करना होगा, फिर पुरानी को हटा दें।

Answer 3

यहाँ एक छोटा सा VBA मैक्रो है जिसे मैंने एक साथ फेंक दिया है जो आपको बहुत पसंद है:

Sub Macro1()
    ' Store original name
    Dim sOriginalName As String
    sOriginalName = ActiveDocument.FullName

    ' Save As
    Dim sFilename As String, fDialog As FileDialog, ret As Long
    Set fDialog = Application.FileDialog(msoFileDialogSaveAs)
    ret = fDialog.Show
    If ret <> 0 Then
        sFilename = fDialog.SelectedItems(1)
    Else
        Exit Sub
    End If
    Set fDialog = Nothing

    ' Don't replace the original file
    If sFilename = sOriginalName Then Exit Sub

     ActiveDocument.SaveAs2 FileName:=sFilename, FileFormat:= _
        wdFormatXMLDocument, LockComments:=False, Password:="", AddToRecentFiles _
        :=True, WritePassword:="", ReadOnlyRecommended:=False, EmbedTrueTypeFonts _
        :=False, SaveNativePictureFormat:=False, SaveFormsData:=False, _
        SaveAsAOCELetter:=False, CompatibilityMode:=14

    ' Delete original
    Kill sOriginalName
End Sub

Comments

क्रेडिट जहां यह कारण है। मैं यह कोशिश करने के लिए तैयार नहीं था। VBA इतना बदसूरत है।

— xdumaine

Answer 4

नहीं, यह बिल्ट इन फंक्शन नहीं है।

चारों ओर एक काम नए नाम के साथ फ़ाइल को सहेजना होगा। फिर फ़ाइल पर वापस जाएं, इस रूप में सहेजें और पुरानी फ़ाइल को हटा दें जो इसे आपके दस्तावेज़, एक्सप्लोरर, नाम बदलने, पुन: खोलने से अधिक कुशल बना देगा।

Comments

ड्राइविंग पर जाने के लिए उस एक्सप्लोरर में जाने से यह एक बेहतर विकल्प है।

— एंडरलैंड

Answer 5

यहाँ @Travis उत्तर पर थोड़ी भिन्नता है।

फिर, यह एक निर्मित कार्य नहीं है।

1. Word में, फ़ाइल को बंद करें, यदि आवश्यक हो तो परिवर्तनों को सहेजने की पुष्टि करें।
2. अभी भी वर्ड में, फ़ाइल खोलने के लिए क्लिक करें।
3. यदि आवश्यक हो, तो फ़ाइल पर नेविगेट करें और फ़ाइल को राइट-क्लिक करें और उसका नाम बदलें।
4. फ़ाइल ओपन डायलॉग में अभी भी, नाम बदला हुआ फ़ाइल खोलें।
   

यह समाधान:

1. पुरानी फ़ाइल को हटाने के लिए विंडोज एक्सप्लोरर में लंबी अकेली ड्राइव को हटा देता है।
2. फ़ाइल ओपन / सेव-अस डायलॉग के लिए केवल एक यात्रा है।
3. केवल सेव-अस ऑपरेशन की तुलना में केवल कुछ और माउस-क्लिक के साथ ऑपरेशन को पूरा करता है।
4. VBA या इसी तरह के समाधान से केवल कुछ और माउस-क्लिक के साथ ऑपरेशन पूरा करता है।