जब भी कोई नया संस्करण जारी होता है, तो मैं अपने आप फ़्लैश प्लेयर को कैसे अपडेट कर सकता हूं?

Question

सारांश:

फ़्लैश प्लेयर अपडेट सेवा एक विश्वसनीय समय पर नहीं चलती है, और जब यह चलती है तो स्वचालित रूप से अपडेट डाउनलोड और लागू नहीं करती है ।

स्थापित फ़्लैश प्लेयर के अप-टू-डेट संस्करण होने के महत्व को देखते हुए (हम में से जो अपने निर्मित खिलाड़ी के साथ क्रोम का उपयोग नहीं करते हैं), मैं यह सुनिश्चित करने का एक तरीका खोजना चाहता हूं कि नए अपडेट का तुरंत पता लगाया जाए और स्थापित किया गया।

इस समस्या को हल करने के लिए मेरे प्रयासों का विवरण निम्नलिखित हैं ...

परिशिष्ट A: फ्लैश प्लेयर अपडेट सेवा

ठीक है, फ़्लैश प्लेयर 11.2 (या तो?) में वापस लौटें। एडोब ने फ़्लैश प्लेयर अपडेट सर्विस (FlashPlayerUpdateService.exe) को जोड़ा, यह फ़्लैश प्लेयर को अपडेट रखने वाला था ...

• स्थापना पर, FPUS को Windows सेवा के रूप में चलाने के लिए कॉन्फ़िगर किया गया है, जिसमें स्टार्ट टाइप मैनुअल से सेट है।

• हर घंटे इस सेवा को शुरू करने के लिए एक शेड्यूल्ड टास्क (Adobe Flash Player Updater.job) जोड़ा जाता है।

अब तक, बहुत अच्छा - यह सेट-अप लगातार चलने वाली सेवा से बचा जाता है, लेकिन यह सुनिश्चित करता है कि चेक किसी भी अपडेट को जल्दी से पकड़ने के लिए अक्सर चलाया जाता है। Google का सॉफ़्टवेयर अपडेटर समान रूप से कॉन्फ़िगर किया गया है, और यह ठीक काम करता है ...

... और फिर भी, जब मैंने अपने स्थापित फ़्लैश प्लेयर के संस्करण की जाँच की, तो मैंने पाया कि यह 11.6.602.180 था , जो, Tue, Mar 12,C:\Windows\System32\Macromed\Flash में पिछली बार अपडेट की गई (या स्थापित) फाइलों की टाइमस्टैम्प को देखने के आधार पर था , 2013 --- 3/12/13, 5:00:08 अपराह्न ।

मैंने यह अवलोकन थू, अप्रैल 25, 2013 --- 4/25/13, 7:00:00 बजे किया , और एडोब की वेबसाइट की जाँच करने पर पाया कि फ्लैश प्लेयर का वर्तमान संस्करण 11.7.700.169 था ।

पिछले अपडेट के एक महीने से अधिक समय हो गया है, वेबसाइट पर एक नया स्पष्ट रूप से उपलब्ध है लेकिन इस बात का कोई संकेत नहीं है कि मेरी मशीन पर चलने वाले प्रति घंटा चेक ने इसे देखा है या इसे डाउनलोड करने का कोई इरादा है।

परिशिष्ट बी: मैन्युअल रूप से फ्लैश प्लेयर अपडेटर चलाना

एक बार चलने पर, आपको एक इंस्टॉल बटन के साथ एक विंडो मिलेगी ; इसे दबाने से वर्तमान संस्करण के लिए इंस्टॉलर डाउनलोड हो जाएगा (स्वचालित रूप से, बिना ब्राउज़र खोले) और इसे चलाएं, फिर आप उस इंस्टॉलर पर क्लिक करेंगे और किया जाएगा। यह मैनुअल था, लेकिन यह काम किया! मेरे वर्तमान इंस्टॉलेशन को पुराने तरीके से देखना (परिशिष्ट A देखें), मैंने पहली बार इस मैनुअल अपडेट प्रक्रिया की कोशिश की। तथापि...FlashUtil32_<version>_Plugin.exe -update plugin

• रनिंग (मेरे मामले में, वह ) ... केवल डाउनलोड बटन के साथ एक विंडो प्रस्तुत करता है, उस डाउनलोड बटन पर क्लिक करने से मेरा ब्राउज़र URL https://get3.adobe.com/flashplayer/update/activex पर खुल जाता है ।FlashUtil32_<version>_ActiveX.exe -update activexFlashUtil32_11_6_602_180_ActiveX.exe -update activex

• रनिंग (मेरे मामले में, वह ) ... केवल एक डाउनलोड बटन के साथ एक विंडो प्रस्तुत करता है, उस डाउनलोड बटन पर क्लिक करने पर मेरा ब्राउज़र URL https://get3.adobe.com/flashplayer/update/plugin पर खुल जाता है ।FlashUtil32_<version>_Plugin.exe -update pluginFlashUtil32_11_6_602_180_Plugin.exe -update plugin

मैं इसे डाउनलोड किए गए पृष्ठ के साथ जारी रख सकता हूं, इसने मुझे फ़िस्टवेयर बॉक्स को अनचेक किया ("Free! McAfee Security Scan Plus"), उस इंस्टॉलर को डाउनलोड करें (ActiveX, no foistware: install_flashplayer11x32axau.mssd_aih.exe, Plugin, no foistware: install_flashplayer11x32aums.ms शायद एक अपडेट किया गया Flash है ... लेकिन फिर, यदि मुझे मैन्युअल रूप से किसी अन्य exe को डाउनलोड और चलाना है तो फ़्लैश प्लेयर अपडेट सेवा का क्या मतलब है ?

उपसंहार

जब से मुझे संदेह हुआ है कि अपडेट सेवा को मैन्युअल रूप से डाउनलोड पृष्ठ पर जल्दी अपनाने वालों को चलाने के लिए जानबूझकर शौक है। अगर यह सच है, तो मेरे अपने अपडेटर को लिखने की इस कमी का कोई समाधान नहीं है; उम्मीद है कि मैं गलत हूं।

Answer 1

शायद अपडेटर केवल 11.6.x रेंज में अपडेट लागू करता है?

आप हमेशा इंस्टॉलरों से सीधे लिंक का उपयोग कर सकते हैं, जो मुझे अधिक विश्वसनीय लगता है: ActiveX ; प्लगिन ।

Comments

आपका पहला वाक्य कोई मायने नहीं रखता है। यदि किसी प्रमुख संस्करण के रिलीज़ होने पर आपको मैन्युअल रूप से अपडेट करने की आवश्यकता होती है, तो ऑटो-अपडेट की बात क्या होगी? मैं हालांकि आपके दूसरे वाक्य से सहमत हूं। मैं स्वतः-अपडेट सेवा को पूरी तरह से अक्षम कर देता हूं और एक नियमित समय पर ActiveX और प्लगइन दोनों संस्करणों को मैन्युअल रूप से अपडेट करता हूं।

— करण

उन लिंक के लिए Thx इतना, विशेष रूप से "प्लगइन" लिंक (ध्यान दें: दोनों लिंक एक ही बाइनरी डाउनलोड करते हैं), जो मैं चाहता था उसका हिस्सा है। मैं आपको "उत्तर" नहीं दे सकता क्योंकि यह केवल "किस URL पर मुझे वर्तमान संस्करण को डाउनलोड करने के लिए उपयोग करना चाहिए, बिना फ़िस्टवेयर के किसी भी अवसर के बिना?" अंश। लेकिन उस URL के साथ, मैं अपना खुद का REAL Flash Player Auto-Updater लिख रहा हूँ ... और यदि SuperUser मुझे अनुमति देता है, तो मैं इसके लिए एक लिंक यहाँ पोस्ट करूँगा जब यह तैयार हो - संभवतः प्रश्न में, यदि यह बंद रहता है और मैं इसका जवाब नहीं दे सकता। एडोब के अनुसार, वे जानबूझकर 30 दिनों के लिए FPUS अपडेट अपडेट करेंगे!

— user219950

Answer 2

इस .bat फ़ाइल के साथ यह इंटरनेट एक्सप्लोरर, फ़ायरफ़ॉक्स (SeaMonkey और आदि), क्रोमियम आधारित (क्रोम, ओपेरा 15+ और आदि) के लिए स्वचालित रूप से फ़्लैश प्लेयर को अपडेट या इंस्टॉल करने की कोशिश करेगा :

del install_flash_player.exe
del install_flash_player_ax.exe
del install_flash_player_ppapi.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe
install_flash_player.exe -install
install_flash_player_ax.exe -install
install_flash_player_ppapi.exe -install

आवश्यक विजेट आप यहाँ डाउनलोड कर सकते हैं और इसे उसी निर्देशिका में रख सकते हैं जहाँ .bat रखा गया था।

---

ऑटोिट में लिखा गया थोड़ा और उन्नत उदाहरण ।

विशेषताएं: नए संस्करण के लिए सरल जांच, अगर यहां कोई नया संस्करण नहीं है तो डाउनलोड फ़्लैश प्लेयर इंस्टॉलर के बिना प्रोग्राम से बाहर निकलें। यदि डाउनलोड इंस्टॉलर विफल हो गया है तो त्रुटि और निकास के साथ संदेश बॉक्स दिखाएं। हिडन कमांड प्रॉम्प्ट विंडो। Wget की जरूरत नहीं है।

Autoit और Editor इंस्टॉल करने के बाद । डेस्कटॉप पर राइट क्लिक करें-> नया-> ऑटोिट स्क्रिप्ट। इस बनाई गई फ़ाइल पर राइट क्लिक करें-> संपादित करें। अब आपको स्काइट विंडो देखनी चाहिए और लाइन के बाद "अपना कोड यहां नीचे जोड़ें" यह कोड जोड़ें:

#NoTrayIcon
#include <WinAPIDiag.au3>
$flashplayerlink="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
$flashplayername="install_flash_player.exe"
$flashplayerlinkAX="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
$flashplayernameAX="install_flash_player_ax.exe"
updateflashplayer($flashplayerlink,$flashplayername)
updateflashplayer($flashplayerlinkAX,$flashplayernameAX)

$flashplayerlinkPPAPI="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
$flashplayernamePPAPI="install_flash_player_ppapi.exe"
updateflashplayer($flashplayerlinkPPAPI,$flashplayernamePPAPI)



Func updateflashplayer($link,$fname)
    if FileGetSize($fname)<>InetGetSize($link) then
        InetGet($link,$fname)
        if @error then
            MsgBox(16,"","Error: '"&_WinAPI_GetErrorMessage(@error)&"'"&@CRLF&$fname)
            Exit
        EndIf
        RunWait($fname&" -install","",@SW_HIDE)
    EndIf
EndFunc

उसके बाद SciTE विंडो प्रेस टूल्स में- F7 बनाएँ या दबाएँ। अब आपको उसी डायरेक्टरी में स्टैंडअलोन एक्जीक्यूटेबल मिलेगा, जहां ऑटोिट स्क्रिप्ट थी।

मैं इस "updater" के लिए नया फ़ोल्डर (राइट-एक्सेस अनुमति के साथ) बनाने की सलाह देता हूं। आप इस "updater" को शुरू करने के लिए शॉर्टकट भी जोड़ सकते हैं ।

यहाँ फ़्लैश प्लेयर की स्थापना रद्द करने के लिए एप्लिकेशन।

Answer 3

बस, मैं अपनी बैच स्क्रिप्ट आपके साथ साझा करना चाहता हूं, बस कोड के इस टुकड़े को अपने नोटपैड में सहेजें और इसे Download_Install_Last_Flash_Player.bat नाम दें

@echo off
REM Help page related to installation problems flash player windows (English)
REM English https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html
REM Page d'aide relative aux problèmes d'installation flash player windows (Français)
REM French https://helpx.adobe.com/fr/flash-player/kb/installation-problems-flash-player-windows.html
Mode 90,3 & color 9D
Title Download and install the latest version of Adobe Flash Player by Hackoo 2017
Set "Download_Folder=%~dp0Latest_Flash_Player_Installers"
Set "Uninstaller_Folder=%~dp0Uninstaller"
Set "Uninstaller_URL=https://fpdownload.macromedia.com/pub/labs/flashruntimes/flashplayer/uninstall_flash_player.exe"
Set "URL1=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
Set "URL2=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
Set "URL3=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
Set "URL_Help=https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html"
If Not Exist "%Uninstaller_Folder%" MD "%Uninstaller_Folder%"
If Not Exist "%Download_Folder%" MD "%Download_Folder%"
Call :Killing_Running_Browsers
Rem We Play radio just for fun and in order to let the user be patient until the download ended
Call :Play_DJ_Buzz_Radio
Call :Uninstalling_Flash_Player
Call :Download_and_Install_Flash_Player
REM Just to check (Check Button on the web page) if the latest Adobe Flash Player is installed successfully or not !
Start "Help page" "%URL_Help%" & Call :Stop_Radio & Exit
::***************************************************************************************************
:Uninstalling_Flash_Player
cls & echo( 
@For %%i in (%Uninstaller_URL%) do Set "Uninstaller_File=%%~nxi"
Call :Download "%Uninstaller_URL%" "%Uninstaller_Folder%\%Uninstaller_File%"
echo    Unistalling older and previous version of Adobe Flash Player ...
%Uninstaller_File% -uninstall
exit /b
::***************************************************************************************************
:Killing_Running_Browsers
set "Browsers_List=firefox chrome iexplore opera"
cls & echo(
echo     Killing any running instances of those browsers "%Browsers_List%" ...
@For %%i in (%Browsers_List%) Do ( 
    Taskkill /IM "%%i.exe" /F>nul 2>&1
)
exit /b
::***************************************************************************************************
:Download_and_Install_Flash_Player
@For %%i in (%URL1%) do Set "File1=%%~nxi"
Call :Download "%URL1%" "%Download_Folder%\%File1%"
Call :Installing_Flash_Player "%Download_Folder%\%File1%"
@For %%i in (%URL2%) do Set "File2=%%~nxi"
Call :Download "%URL2%" "%Download_Folder%\%File2%"
Call :Installing_Flash_Player "%Download_Folder%\%File2%"
@For %%i in (%URL3%) do Set "File3=%%~nxi"
Call :Download "%URL3%" "%Download_Folder%\%File3%"
Call :Installing_Flash_Player "%Download_Folder%\%File3%"
exit /b
::***************************************************************************************************
:Installing_Flash_Player <Install_File>
cls & color 9B
echo(
echo   Please wait a while ... installing "%~nx1" is in progress ...
%1 -install
exit /b
::***************************************************************************************************
:Download <url> <File>
cls & color 0A
echo(
echo      Please wait a while ... Downloading "%~n2" is in progress ...
Powershell.exe -command "(New-Object System.Net.WebClient).DownloadFile('%1','%2')"
exit /b
::***************************************************************************************************
:Play_DJ_Buzz_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
Set "vbsfile=%temp%\DJBuzzRadio.vbs"
Set "URL=http://www.chocradios.ch/djbuzzradio_windows.mp3.asx"
Call:Play "%URL%" "%vbsfile%"
Start "" "%vbsfile%"
Exit /b
::**************************************************************
:Play
(
echo Play "%~1"
echo Sub Play(URL^)
echo    Dim Sound
echo    Set Sound = CreateObject("WMPlayer.OCX"^)
echo    Sound.URL = URL
echo    Sound.settings.volume = 100
echo    Sound.Controls.play
echo    do while Sound.currentmedia.duration = 0
echo       wscript.sleep 100
echo    loop
echo    wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000
echo End Sub
)>%~2
exit /b
::**************************************************************
:Stop_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
If Exist "%vbsfile%" Del "%vbsfile%"
::**************************************************************