Outlook2010 में, क्या वर्तमान में स्नूज़िंग रिमाइंडर देखने का कोई तरीका है?

Question

क्या आउटलुक 2010 में उन वस्तुओं की सूची को खींचने का कोई तरीका है जो वर्तमान में स्नूज़ हैं? उदाहरण के लिए, मान लें कि दो सप्ताह बाद मैंने शुक्रवार को एक महत्वपूर्ण लंच मीटिंग के लिए शुक्रवार को पॉप अप करने के लिए रिमाइंडर सेट किया (मुझे सप्ताहांत से पहले सोमवार के कार्यों की याद दिलाना पसंद है)। जब अनुस्मारक शुक्रवार को पॉप अप होता है, तो मैं इसे तीन दिनों के लिए स्नूज़ करता हूं ताकि यह सोमवार को दोपहर के भोजन से ठीक पहले फिर से पॉप हो जाए। तब मंडे इधर-उधर घूमता है और मेरी याददाश्त फीकी हो जाती है और मैं थोड़ा पागल हो जाता हूं कि मैंने गलती से शुक्रवार को सही तरीके से इसे छीनने के बजाय रिमाइंडर को खारिज कर दिया था। मैं अभी भी अपने कैलेंडर पर मूल नियुक्ति देख सकता हूं, लेकिन मुझे यह सुनिश्चित करने की आवश्यकता है कि मैं वास्तव में रिमाइंडर पॉप अप करने जा रहा हूं जब मुझे उम्मीद है कि मैं अपनी बैठक को याद नहीं करूंगा।

आउटलुक 2010 में किसी भी तरह से अनुस्मारक की सूची को खींचना है जो वर्तमान में स्नूज़ किया गया है? यह उन मामलों के लिए भी मददगार होगा जहां मैं एक कार्य पूरा करता हूं, जिसका अनुस्मारक मैंने बाद तक सूंघ लिया था, और अब मैं स्नूज किए गए अनुस्मारक को खींचना चाहता हूं और इसे रद्द करना चाहता हूं।

Answer 1

Sub SnoozedReminders()

' http://www.jpsoftwaretech.com/check-your-outlook-reminders-in-vba/

Dim MyReminder As Outlook.Reminder
Dim MyReminders As Outlook.Reminders
Dim Report As String
Dim i As Long

Set MyReminders = Outlook.Reminders

i = 0

For Each MyReminder In MyReminders

    If HasReminderFired(MyReminder) = True Then
        i = i + 1
        Report = Report & i & ": " & MyReminder.Caption & vbCr & _
            "     Snoozed to " & MyReminder.NextReminderDate & vbCr & vbCr
    End If

Next MyReminder

CreateReportAsEmail "Snoozed Items", Report

End Sub


Function HasReminderFired(rmndr As Outlook.Reminder) As Boolean
    HasReminderFired = (rmndr.OriginalReminderDate <> rmndr.NextReminderDate)
End Function


' VBA SubRoutine which displays a report inside an email
' Programming by Greg Thatcher, http://www.GregThatcher.com

Public Sub CreateReportAsEmail(Title As String, Report As String)

    On Error GoTo On_Error

    Dim Session As Outlook.Namespace
    Dim mail As MailItem
    Dim MyAddress As AddressEntry
    Dim Inbox As Outlook.folder 

    Set Session = Application.Session
    Set Inbox = Session.GetDefaultFolder(olFolderInbox)
    Set mail = Inbox.items.Add("IPM.Mail")

    mail.Subject = Title
    mail.Body = Report

    mail.Save
    mail.Display

Exiting:
    Set Session = Nothing
    Set Inbox = Nothing
    Set mail = Nothing
    Exit Sub

On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
    Resume Exiting

End Sub

यदि आप VBA से अपरिचित हैं तो स्लिपस्टिक के स्पष्टीकरण पृष्ठ देखें । आपको इसके बारे में जानकारी मिलेगी:

• मैक्रो सुरक्षा सेटिंग्स;
• कोड कहाँ रखा जाए (आप इन्सर्ट के साथ एक नियमित मॉड्यूल का उपयोग कर सकते हैं। मॉड्यूल); तथा
• कैसे एक बटन बनाने के लिए।

Comments

यह स्थापित करने के लिए थोड़ा अधिक काम है, लेकिन परिणाम बहुत बढ़िया हैं! मैंने अपने आउटलुक टूलबार में एक बटन जोड़ा है जो इसे उपयोग करने के लिए एक हवा बनाता है।

— RSW

Answer 2

इस दृश्य स्नूज़्ड आइटम फ़ोरम पोस्ट के अनुसार, स्नूज़ किए गए आइटम की सूची देखना संभव नहीं है। पोस्ट से पता चलता है कि आप एक कस्टम दृश्य बनाकर सीमित मात्रा में उपयोगी जानकारी देख सकते हैं जो कुछ अनुस्मारक फ़ील्ड प्रदर्शित करता है।

Answer 3

कैलेंडर टैब पर क्लिक करके देखें और बदलें दृश्य का चयन करें। फिर सूची का चयन करें। यह सभी अनुस्मारक की सूची प्रदर्शित करता है।

Comments

सुपरयूज़र में आपका स्वागत है। यह उत्तर प्रश्न को पूरी तरह से संबोधित नहीं करता है। कृपया इसे ओपी के विशिष्ट प्रश्न को संबोधित करने के लिए संपादित करें।

— मैं कहता हूं कि मोनिका