एक मैक्रो का उपयोग कर सीएसवी को ऑफिस एक्सेल टेबल निर्यात करें

Question

मैं Excel 2010 में एक्सेल टेबल्स का उपयोग कर रहा हूं। मैं इन तालिकाओं की सामग्री को * .csv पर जल्दी से निर्यात करना चाहूंगा।

मेरे वर्तमान वर्कफ़्लो: 1. मैन्युअल रूप से तालिका का चयन करें 2. एक नई कार्यपुस्तिका में सामग्री की प्रतिलिपि बनाएँ 3. कार्यपुस्तिका को * .csv फ़ाइल के रूप में सहेजें

वांछित कार्य: 1. मैन्युअल रूप से तालिका का चयन करें 2. एक मैक्रो चलाएँ जो एक पूर्व-निर्धारित फ़ाइल नाम को लिखता है

चूँकि तालिकाओं में अद्वितीय नाम होते हैं (उदाहरण के लिए CurrentDataTable), क्या कोई फ़ंक्शन है जो तालिका का नाम, लक्ष्य फ़ाइल और वांछित आउटपुट स्वरूप लेता है और आउटपुट फ़ाइल लिखता है?

Comments

क्या आपके आउटपुट के लिए एक निश्चित रास्ता है? क्या केवल एक टेबल प्रति शीट है?

— nixda

एक तय रास्ता है। आम तौर पर मैं प्रति तालिका एक तालिका तक सीमित नहीं होना पसंद करूंगा (मैं उनके नाम बनाम तालिका वे जिस शीट पर हैं, मैं चाहूंगा)

— vg425

Answer 1

कोई अंतर्निहित एक्सेल कमांड या फ़ंक्शन नहीं है जो आप चाहते हैं उस तरह का काम करेंगे, लेकिन आप इसे प्रोग्राम करने के लिए वीबीए का उपयोग कर सकते हैं।

निम्नलिखित कोड आपके लिए देख रहे हो सकता है:

Sub ExportTable()

    Dim wb As Workbook, wbNew As Workbook
    Dim ws As Worksheet, wsNew As Worksheet
    Dim wbNewName As String


   Set wb = ThisWorkbook
   Set ws = ActiveSheet

   Set wbNew = Workbooks.Add

   With wbNew
       Set wsNew = wbNew.Sheets("Sheet1")
       wbNewName = ws.ListObjects(1).Name
       ws.ListObjects(1).Range.Copy
       wsNew.Range("A1").PasteSpecial Paste:=xlPasteAll
       .SaveAs Filename:=wb.Path & "\" & wbNewName & ".csv", _
             FileFormat:=xlCSVMSDOS, CreateBackup:=False
   End With

End Sub

कोड मानता है कि आपके पास प्रत्येक कार्यपत्रक में एक तालिका है। यह एक नई कार्यपुस्तिका बनाता है, उस कार्यपुस्तिका के पत्रक 1 में तालिका की प्रतिलिपि बनाता है, और तालिका के समान नाम वाली कार्यपुस्तिका को CSV फ़ाइल के रूप में सहेजता है।

Answer 2

यहाँ Excel 2013 के लिए चफ़ के जवाब का मेरा संस्करण है। यह मोडल संवादों को भी निष्क्रिय करता है:

Sub ExportCSV()

   Dim wb As Workbook, wbNew As Workbook
   Dim ws As Worksheet, wsNew As Worksheet

   Set wb = ThisWorkbook
   Set ws = ActiveSheet

   Set wbNew = Workbooks.Add
   Application.DisplayAlerts = False
   With wbNew
       Set wsNew = wbNew.Sheets("Sheet1")
       ws.Rows.Copy
       wsNew.Paste
       .SaveAs Filename:=ws.name & ".csv", FileFormat:=xlCSV, CreateBackup:=True
       wsNew.Delete
   End With
   Windows(ws.name & ".csv").Activate
   ActiveWindow.Close
   Application.DisplayAlerts = True

End Sub

Answer 3

मुझे ऐसा ही करने की आवश्यकता थी, लेकिन यह निर्दिष्ट करने की आवश्यकता थी कि किन तालिकाओं को सीएसवी फ़ाइलों के रूप में निर्यात किया जाना था। मैंने VBA के साथ 'ExportTables' नाम की एक सीमा बनाई, जो इस प्रकार है:

Public Sub Export()
    Dim i       As Integer
    Dim iMax    As Integer
    Dim sTable  As String

    iMax = Range("ExportTables").Rows.Count

    For i = 1 To iMax
        sTable = Range("ExportTables").Cells(i, 1).Value
        Call ExportTable(sTable)
    Next i
End Sub

Public Sub ExportTable(tableName As String)
    Dim wkb         As Workbook
    Dim wkbNew      As Workbook
    Dim wks         As Worksheet
    Dim wksNew      As Worksheet

    Set wkb = ThisWorkbook

    Application.Goto Reference:=tableName
    Set wks = ActiveSheet

    Set wkbNew = Workbooks.Add
    Set wksNew = wkbNew.Sheets(1)

    wks.ListObjects(tableName).Range.Copy
    wksNew.Range("A1").PasteSpecial Paste:=xlPasteValues

    Application.DisplayAlerts = False

    wkbNew.SaveAs Filename:=wkb.Path & "\" & tableName & ".csv", _
        FileFormat:=xlCSV, CreateBackup:=False
    wkbNew.Close SaveChanges:=False

    Application.DisplayAlerts = True

    ' Release object variables.
    Set wkb = Nothing
    Set wkbNew = Nothing
    Set wks = Nothing
    Set wksNew = Nothing
End Sub