वीपीएन कनेक्शन जैसे ओएसएक्स में स्वचालित कार्य?

Question

मैं नेटफ्लिक्स पर सर्फ करने के लिए अपने स्कूल की वीपीएन सेवा का उपयोग कर रहा हूं। मुझे ज्यादातर समय वीपीएन से कनेक्ट करना पड़ता है। मेरा स्कूल सिस्को AnyConnect सिक्योर मोबिलिटी क्लाइंट का उपयोग करता है। मुझे पासवर्ड दर्ज करना होगा और हर बार कनेक्ट होने पर एक बैनर स्वीकार करना होगा। क्या ओएस एक्स पर इस कनेक्शन को स्वचालित करने का एक तरीका है?

Answer 1

यदि आप अपने कनेक्शन को नियंत्रित करने के लिए OS X का उपयोग कर रहे हैं:

इसका कारण यह है कि आप जिस सिस्को बॉक्स से जुड़ रहे हैं वह बातचीत को मजबूर कर रहा है। यह वास्तव में सिस्को वीपीएन एग्रीगेटर पर एक सेटिंग है जो सुरक्षा को लागू करता है। Apple, Apple (Cisco और Apple दोनों के अनुसार) के साथ किए गए Cisco समझौते के हिस्से के रूप में (Apple Script / Automator) इसके लिए परिधि प्रदान नहीं करता है। मैंने पहले इसकी जांच की है और यह उत्तर मैं दोनों पक्षों द्वारा दिया गया था।

सिस्को ओएस एक्स वीपीएन क्लाइंट के साथ भी ऐसा ही है।

Answer 2

हां, आप AppleScript का उपयोग करके इसे स्वचालित कर सकते हैं।

यहाँ एक स्क्रिप्ट है जिसका मैं उपयोग करता हूँ:

-- 1. Place in ~/Library/Scripts and enable the Applescript menu via the Applescript Editor
--    (Or export to .app to run from spotlight.)
-- 2. Substitute "vpn.example.com", "username" and "redacted" for your VPN server and password
-- 3. Open Security & Privacy System Preferences, go to Privacy, Accessibility
-- 4. Enable Applescript Editor and System UI Server (or for this .app if so exported)
-- 5. Trigger script from the menu (or run from spotlight)
-- 6. Enjoy being connected
-- 7. Run script again to close connection


-- AnyConnect now refered to as targetApp
set targetApp to "Cisco AnyConnect Secure Mobility Client"


-- Determine if AnyConnect is currently running
tell application "System Events"
    set processExists to exists process targetApp
end tell


-- Close connection if running; else start connection and fill in password
if processExists is true then
    tell application targetApp
        quit
    end tell
else
    tell application targetApp
        activate
    end tell

    tell application "System Events"
        repeat until (window 1 of process targetApp exists)
            delay 1
        end repeat
        tell process targetApp
            keystroke ("vpn.example.com" as string)
            keystroke return
        end tell
        repeat until (window 2 of process targetApp exists)
            delay 1
        end repeat
        tell process targetApp
            keystroke (tab) using {shift down}
            keystroke ("username" as string)
            keystroke tab
            keystroke ("redacted" as string)
            keystroke return
        end tell
        delay 1
        tell process targetApp
            keystroke return
        end tell

    end tell
end if

यह एक स्क्रिप्ट है जिसे मैंने पाया और ट्वीक किया; मुझे यकीन नहीं है कि मूल लेखक कौन है क्योंकि आसपास कई संस्करण तैर रहे हैं। मैंने इसे https://gist.github.com/twksos/44b45abf5263635776ec से प्राप्त किया