एक विशिष्ट उपयोगकर्ता पर स्विच करने के लिए मैंने एक स्क्रिप्ट मंगा ली जो मुझे hints.macworld.com लेख की टिप्पणियों में मिली । मुझे इसके साथ समस्या थी इसलिए मैंने इसे काम करने के लिए प्राप्त किया। पासवर्ड किचेन में जमा होता है, इसलिए आपको क्लीयरटेक्स्ट में लॉगिन पासवर्ड स्टोर करने की चिंता नहीं करनी चाहिए। आप यहां गिस पा सकते हैं ।
--This script MUST be named "Switch to User.scpt", where User is the name of the user to switch to.
--You must first make a password item (a.k.a. a key) for the other user's password using Keychain Access, and call it "", where "user" is the other user's name and with the description "User Login". The script assumes that you make this key in your login.keychain, which is the default one.
--The first time you run this script, you will be prompted to allow Keychain Scripting to access the password of the key.
--This script requires "Enable access for assistive devices" to be enabled in the Universal Access system preference pane.
set username to word -1 of my findReplace(".scpt", "", (path to me as text))
-- Invoke Fast User Switching. The `id -ur username` part gets the uid number that corresponds to the username and substitutes it at the end of the CGSession command
do shell script "/System/Library/CoreServices/'Menu Extras'/User.menu/Contents/Resources/CGSession -switchToUserID `id -ur " & username & "`"
-- Use universal access to enter the text and to click the button
tell application "System Events"
repeat
if (do shell script "stat -f %Su /dev/console") is username then exit repeat
-- Get the password for the username
try
set pswd to (do shell script "security find-generic-password -g -s \"" & username & "\" -D \"User Login\" 2>&1 1>/dev/null | sed -e 's/password: \"//' -e 's/\"//'")
on error
exit repeat
end try
if exists window 1 of application process "SecurityAgent" then
tell process "SecurityAgent" to set value of text field 1 of window 1 to pswd
key code 36
exit repeat
else
tell application "SecurityAgent" to quit
do shell script "/System/Library/CoreServices/'Menu Extras'/User.menu/Contents/Resources/CGSession -switchToUserID `id -ur " & username & "`"
end if
end repeat
end tell
on findReplace(findText, replaceText, sourceText)
set ASTID to AppleScript's text item delimiters
set AppleScript's text item delimiters to findText
set sourceText to text items of sourceText
set AppleScript's text item delimiters to replaceText
set sourceText to sourceText as text
set AppleScript's text item delimiters to ASTID
return sourceText
end findReplace
केवल लॉगिन स्क्रीन को लागू करने के लिए मेरे पास एक और स्क्रिप्ट है। आप यहां गिस पा सकते हैं
do shell script "'/System/Library/CoreServices/Menu Extras/User.menu/Contents/Resources/CGSession' -suspend"
दोनों स्क्रिप्ट मेरे क्विकसिल्वर कैटलॉग में हैं। उपयोगकर्ता खातों के बीच स्विच करना कुछ सेकंड का मामला है।
