हर बार जब हम Windows पुनर्स्थापित, यह एक नई सिड उपयोगकर्ता के लिए भी उपयोगकर्ता नाम के रूप में है पैदा करेगा ही पहले की तरह।
// example (not real SID format, just show the problem)
user SID
--------------------
liuyan S-old-501 // old SID before reinstall
liuyan S-new-501 // new SID after reinstall
पुनः स्थापित करने के बाद कष्टप्रद समस्या NTFS फ़ाइल owerhip है और हार्ड ड्राइव डिस्क पर अनुमतियाँ अभी भी पुराने उपयोगकर्ता के SID के साथ जुड़ी हुई हैं।
मैं NTFS फ़ाइलों के स्वामित्व और अनुमति सेटिंग को रखना चाहता हूं, फिर नए उपयोगकर्ता को पुराने उपयोगकर्ता का SID लेने देना चाहता हूं, ताकि मैं अनुमति की समस्या के बिना पहले की तरह फ़ाइलों तक पहुंच बना सकूं।
caclsकमांड लाइन टूल,, ऐसी स्थिति में नहीं किया जा सकता क्योंकि फ़ाइल करता है नया उपयोगकर्ता के अंतर्गत आता है तो यह के साथ विफल होगा पहुंच अस्वीकृत कर दी त्रुटि। और यह स्वामित्व नहीं बदल सकता है।
यहां तक कि अगर मैं SubInACLउपकरण के माध्यम से सत्ता को बदल सकता हूं , caclsतो पुराने उपयोगकर्ता की अनुमति को नहीं हटा सकता क्योंकि पुराने उपयोगकर्ता नई स्थापना पर मौजूद नहीं है, और नए उपयोगकर्ता के लिए पुराने उपयोगकर्ता की अनुमति की प्रतिलिपि नहीं बना सकता है ।
तो, क्या हम पुराने उपयोगकर्ता के SID को नए उपयोगकर्ता को नए सिरे से स्थापित विंडोज पर बांध सकते हैं?
नमूना परीक्षण बैच
@echo off
REM Additional tools used in this script
REM PsGetSid http://technet.microsoft.com/en-us/sysinternals/bb897417
REM SubInACL http://www.microsoft.com/en-us/download/details.aspx?id=23510
REM
REM make sure these tools are added into PATH
set account=MyUserAccount
set password=long-password
set dir=test
set file=test.txt
echo Creating user [%account%] with password [%password%]...
pause
net user %account% %password% /add
psgetsid %account%
echo Done !
echo Making directory [%dir%] ...
pause
mkdir %dir%
dir %dir%* /q
echo Done !
echo Changing permissions of directory [%dir%]: only [%account%] and [%UserDomain%\%UserName%] has full access permission...
pause
cacls %dir% /G %account%:F
cacls %dir% /E /G %UserDomain%\%UserName%:F
dir %dir%* /q
cacls %dir%
echo Done !
echo Changing ownership of directory [%dir%] to [%account%]...
pause
subinacl /file %dir% /setowner=%account%
dir %dir%* /q
echo Done !
echo RunAs [%account%] user to write a file [%file%] in directory [%dir%]...
pause
runas /noprofile /env /user:%account% "cmd /k echo some text %DATE% %TIME% > %dir%\%file%"
dir %dir% /q
echo Done !
echo Deleting and Recreating user [%account%] (reinstall simulation) ...
pause
net user %account% /delete
net user %account% %password% /add
psgetsid %account%
echo Done ! %account% is recreated, it has a new SID now
echo Now, use this "same" account [%account%] to access [%dir%], it will failed with "Access is denied"
pause
runas /noprofile /env /user:%account% "cmd /k cacls %dir%"
REM runas /noprofile /env /user:%account% "cmd /k type %dir%\%file%"
echo Done !
echo Changing ownership of directory [%dir%] to NEW [%account%]...
pause
subinacl /file %dir% /setowner=%account%
dir %dir%* /q
cacls %dir%
echo Done ! As you can see, "Account Domain not found" is actually the OLD [%account%] user
echo Deleting user [%account%] ...
pause
net user %account% /delete
echo Done !
echo Deleting directory [%dir%]...
pause
rmdir %dir% /s /q
echo Done !