विंडो से टाइटलबार, फ्रेम आदि हटाने के लिए विंडोज प्रोग्राम?

Question

मुझे फुल स्क्रीन के विपरीत, विंडो मोड में कंप्यूटर गेम खेलना पसंद है। मुझे टाइटल बार, फ्रेम और अन्य UI रद्दी को घूरना पसंद नहीं है। मुझे खिड़की के आसपास अपने डेस्कटॉप पर अन्य सामान देखना भी पसंद नहीं है। क्या एक साधारण विंडोज प्रोग्राम है जो कुछ अन्य एप्लिकेशन से यूआई क्रोम को एक मनमानी खिड़की से दूर कर देगा? डेस्कटॉप के नीचे, खिड़की के नीचे एक काली स्क्रीन लगाने का एक आसान तरीका के लिए अतिरिक्त अंक।

नोट: मैं विशेष रूप से उन विंडोज़ को संभालने के लिए देख रहा हूं जो मेरे डेस्कटॉप आकार से छोटे हैं। विभिन्न प्रकार के 'विंडोयुक्त अधिकतम' विकल्प हैं जो विंडो को बिल्कुल डेस्कटॉप के आकार का बनाते हैं, और सभी यूआई सजावट स्क्रीन से दूर हैं। (जैसे: ShiftWindow)। मैं एक खिड़की से सभी सजावट को दूर करने की कोशिश कर रहा हूं जो डेस्कटॉप आकार से छोटा है।

Comments

आपके विशेष उपयोग के लिए, हालांकि, यह किस खेल पर निर्भर करता है। खेल एक नियमित कार्यक्रम की तरह व्यवहार नहीं करते हैं, जब खिड़की की ओर। कुछ भी इस खिड़की की सजावट को नहीं संभालते हैं, और स्क्रीन के ऊपरी बाएं कोने पर सीधे आकर्षित करते हैं, उदाहरण के लिए। तथ्य यह है कि, "सार्वभौमिक" समाधान ढूंढना कठिन हो सकता है, क्योंकि यह इस बात पर निर्भर कर सकता है कि खेल कैसे प्रस्तुत किया जाता है, और प्रत्येक विंडो मोड को कैसे संभालता है।

— ग्नूपी

Answer 1

बस कुछ छोटा है जो मैंने अपने उद्देश्यों के लिए voodoomsr की टिप्पणी पढ़ने के बाद बनाया है। इसे बाएं कोने में जाने के लिए बनाता है और मेरे पूर्ण रिज़ॉल्यूशन का आकार बदलता है। पहले जैसा था वैसा ही पुनर्स्थापित करता है। एक ही समय में कई ऐप्स के साथ उपयोग नहीं किया जा सकता है।

धन्यवाद voodoomsr

;-Caption
LWIN & LButton::
SetTitleMatchMode, 2
WinGetPos, X, Y, Width, Height, A
WinSet, Style, -0xC00000, A
WinMove,A,,0,0,1920,1080
return
;

;+Caption
LWIN & RButton::
WinSet, Style, +0xC00000, A
WinMove,A,,%X%,%Y%,%Width%,%Height%
Sleep, 1000
Sleep, 1000
return
;

संपादित करें:

टीबीएच मैंने खिड़कियों के लिए कुछ उपयोगी खोजने की कोशिश की, जो आकार नहीं देता है, लेकिन कुछ भी नहीं मिल रहा है (यह कहते हुए कि यह संभव नहीं है, यह वास्तव में मेरी पहली ऑटोहॉट्की स्क्रिप्ट थी)।

किसी भी तरह मैंने अनावश्यक नींद को दूर करने जैसे कुछ ट्विक्स किए, नेल्सन ने जिस शैली का सुझाव दिया और उसे केवल एक बटन के साथ काम किया, इसलिए डबल-क्लिक किए गए सहेजे गए चर को ओवरराइड नहीं करेंगे।

#SingleInstance force

; Exclude the desktop
; Note: Also excludes "My Computer" browsing windows.
;       Better detection might be needed to differentiate the parent explorer "ahk_id" from child windows.
;       Also seems to disregard accidental Metro interface clicks (Win 8+)
#IfWinNotActive ahk_exe explorer.exe

; Set your resolution (minus decorations like start bars if you wish to leave those on-screen.
w = 1920
h = 1080
w_wasted = 6 ; width used by resize bars
h_wasted = 29 ; width used by caption frame and resize bars

; Window to fullscreen
LWIN & LButton::
  SetTitleMatchMode, 2
  WinGet Style, Style, A

  ; 0xC40000 = WS_BORDER (0x800000) + WS_DLGFRAME (0x400000) + WS_SIZEBOX aka WS_THICKFRAME (0x040000)
  if(Style & 0xC00000) { ; if has WS_CAPTION. Ignore sizebox value.
    WinGetPos, X, Y, Width, Height, A
    WinSet, Style, -0xC40000, A ; removes attributes, including sizebox...doesn't do a strict subtraction
    WinMove,A,,0,0,w,h
  } else {
    WinSet, Style, +0xC40000, A
    ; Note: will set WS_SIZEBOX even if not previously present
    if(Width > w - w_wasted) { 
      Width := %w%-%w_wasted%
    }
    if(Height > h - h_wasted) {
      Height := %h%-%h_wasted%
    }
    WinMove,A,,%X%,%Y%,%Width%,%Height%
  }
  WinSet Redraw
  Return

Comments

धन्यवाद, यह वही है जो मैं चाहता था! केवल एक चीज जो अच्छी तरह से काम नहीं करती है वह है अगर विंडो आकार बदलने से इनकार करती है: यह पीछे दिखाई देने वाले डेस्कटॉप के साथ ऊपरी बाईं ओर समाप्त होता है। पीछे काले रंग के साथ केंद्रित बेहतर होगा। लेकिन अगर विंडो रेजिजेबल है तो यह बहुत अच्छा है। एक मामूली ट्विक: स्टाइल 0xC40000 बेहतर काम करने लगता है, यह रिसाइज़ हैंडल को भी हटा देता है। इसके अलावा, आपने कुछ नींद छोड़ दी: क्या वे आवश्यक हैं?

— नेल्सन

@ नेल्सन विंडोज़ के लिए आकार बदलने से इनकार करते हैं, हो सकता है कि हम सिर्फ WinMaxmize और WinRestroe (auot-hide task-bar के साथ) का उपयोग कर सकते हैं।

— कमजोर

आपकी दूसरी स्क्रिप्ट विंडोज 10 पर पूरी तरह से काम करती है। बहुत बहुत धन्यवाद, वास्तव में मैं क्या देख रहा था!

— लुकास

@ लुकास मदद करने के लिए खुश है, फिर भी खुद भी इसका इस्तेमाल कर रहा है!

— मिकुज़

यदि मैं गलती से अपने डेस्कटॉप के साथ सक्रिय विंडो के रूप में इस स्क्रिप्ट का उपयोग करता हूं, तो पहले डेस्कटॉप पर कैप्शन बार मिलता है और आइकन नीचे आते हैं। यदि मैं इसे फिर से चलाता हूं, तो मेरे आइकन फ्लैट-आउट गायब हो जाते हैं। इसलिए, यह पता लगाने के लिए कुछ होना चाहिए कि क्या विंडो मुख्य एक्सप्लोरर है। कुंजी + मूसस्ट्रोक को अनदेखा करें। (विंडोज़ 8.1 क्लासिक-प्रकार इंटरफ़ेस का उपयोग करके

— जीतें

Answer 2

बस इस autohotkey स्क्रिप्ट का उपयोग करें:

;-Caption
LWIN & LButton::
WinSet, Style, -0xC00000, A
return
;

;+Caption
LWIN & RButton::
WinSet, Style, +0xC00000, A
return
;

आप यहाँ से autohotkey डाउनलोड कर सकते हैं http://www.autohotkey.com/download/ । फ़ाइल को एक एक्सटेंशन .ahk के साथ सहेजें और किसी भी एप्लिकेशन की तरह चलाएं।

उपयोग:

शीर्षक बार LWindowButton + बाएँ क्लिक को हटाने के लिए

शीर्षक बार LWindowButton + राइट क्लिक को पुनर्स्थापित करने के लिए

Comments

यह अन्य मामलों के लिए काम करता है, जैसे मेरा यह सवाल: superuser.com/questions/664559/… हालांकि, यह Google Chrome या इसके विंडो वाले ऐप्स पर कोई प्रभाव नहीं डालता है। यहाँ कोई संकेत? मुझे लगता है कि वे कस्टम मेड बार हैं ...

— igorsantos07

Answer 3

यहाँ एक प्रोग्राम है जो किसी भी विंडो के लिए टाइटलबार को हटा सकता है। ऐसा करने के लिए आपको 'स्टाइल' टैब पर स्विच करने की बजाय WinExplorer ट्री व्यू में गेम्स विंडो को चुनना होगा और WS_DLGFRAME को चेक करना होगा।

Comments

यह इंटरनेट पर सबसे अच्छे कार्यक्रमों में से एक है। मैं इसे सालों से इस्तेमाल कर रहा हूं। मैं वास्तव में चाहता हूं कि इसमें सिस्टम ट्रे में चलने और विशिष्ट एप्लिकेशन के लिए आपके द्वारा निर्धारित सभी सेटिंग्स को पुनर्स्थापित करने की क्षमता थी। यानी, किसी तरह का प्रोफाइल सपोर्ट।

— डेविल्स एडवोकेट

क्या आपको इस कार्यक्रम को चलाना है और हर बार जब आप खेल को चलाते हैं?

— निकोलाई लेसचोव

Answer 4

AutoHotKey और एक ऑटो-छिपाने वाले टास्कबार का उपयोग करना।

LWin & f::

WinGet Style, Style, A
if(Style & 0xC40000) {
  WinSet, Style, -0xC40000, A
  WinMaximize, A 

} else {
  WinSet, Style, +0xC40000, A
  WinRestore, A
}
return

क्यों उपयोग करें WinMaxmize? असद के जवाब की टिप्पणियाँ देखें ।

Comments

ठीक काम करता है। मैं दो कुंजियों को बर्बाद करने के बजाय टॉगल मोड को पसंद करता हूं।

— छत

Answer 5

Skrommel द्वारा CutAway आप क्या चाहते हो सकता है।

Answer 6

मैंने इसे HydrogenAudio मंचों पर पाया:

यहाँ विंडो शीर्षक बार के बिना Foobar 2000 का स्क्रीनशॉट है:

उपयोग किए जाने वाले प्रोग्राम को फ्लैश डेस्कटॉप (शेयरवेयर) कहा जाता है

दुर्भाग्य से वे वास्तव में लक्ष्य प्राप्त करने के लिए कार्यक्रम की सेटिंग्स पर विस्तृत नहीं होते हैं, बल्कि एक टाइटलबार के बिना चलती खिड़कियों की समस्या पर। WindowBlinds का भी उल्लेख किया गया है।

Answer 7

यदि आप कोड कर सकते हैं और आप विस्टा या नया चला रहे हैं, तो यह एक प्रोग्राम बनाना बहुत आसान है जो एक DWM थंबनेल को एप्लिकेशन में पंजीकृत करता है और फिर आप इस थंबनेल में केवल बॉर्डर्स के बिना विंडो सामग्री दिखा सकते हैं। आपको इस ओवरलेइंग प्रोग्राम से गेम तक किसी तरह से सभी इनपुट को फॉरवर्ड करना होगा लेकिन यह सुपर कॉम्प्लेक्स भी नहीं है।

Answer 8

मैं अब विंडोज नहीं चलाता, इसलिए यह परीक्षण नहीं कर सकता, लेकिन बॉर्डरलेस गेमिंग एक आशाजनक दिखने वाला ओपन सोर्स ऐप है जो इस समस्या को हल करता है। यह चल रहे अनुप्रयोगों की एक सूची दिखाता है और आपको विंडोज़ में हेरफेर करने के लिए एक का चयन करने देता है।

Comments

10 लाइनों AutoHotKey के लिए बहुत कोड।

— छत

Answer 9

मैं एक विशेष विंडो के साथ समस्या कर रहा था, जो @ कमजोर विधि और मिकूज़ फ्रेमवर्क के साथ अधिकतम विंडो के लिए सही विंडो का आकार लेगा, लेकिन सही स्थिति में नहीं जाएगा।

यहाँ मेरा आह समाधान है

;
; AutoHotkey Version: 1.x
; Language:       English
; Platform:       Win2000+
; Author:         mpag derived from Mikuz
;
; Script Function:
;    Window to "supermaximized". mpag solution from http://superuser.com/q/38687/319748
;    If you want fullscreen (no toolbars) try replacing calls to function WinSuperMax with WinFullscreen
; This script may still be in development
; Bugs:
;    1) Doesn't display scrollbars in standard maximized screen if it lost them upon supermax (unless you restore and re-maximize)
;    2) If supermaxing a background window that has menus within the Caption bar (e.g. firefox), you functionally just maximize but lose the min/restore/close buttons. Probably has something to do with the Style value.
; Memory Management/Clarity:
;    3) Doesn't clear G_ variable values before each run. if the number of monitors (virtual or otherwise) reduces, values for higher monitor numbers will still be set, but MonCount should still be valid and restrict use. also picks first match.

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
#SingleInstance force

SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

MonGetCoords() {
  global ; for setting
  SysGet G_MonCount, MonitorCount
  loop %G_MonCount% {
    SysGet G_MonWA%A_Index%, MonitorWorkArea, %A_Index%
    SysGet G_MonFS%A_Index%, Monitor, %A_Index%
  }
}

GetMon4xy(ByRef x="", ByRef y="", ByRef m="") {
  global ; getting
  local l:=0, u:=0
  m := 0 ; even if sent, we want to clear it
  loop %G_MonCount% {
    l := G_MonFS%A_Index%Left
    u := G_MonFS%A_Index%Right
    if x not between %l% and %u%
      continue 
    l := G_MonFS%A_Index%Top
    u := G_MonFS%A_Index%Bottom
    if y not between %l% and %u%
      continue 
    m := A_Index
    break
  }
}

WinSetSz(d, mp) {
  global
  local l, r, t, b
  l := %mp%Left
  r := %mp%Right
  t := %mp%Top
  b := %mp%Bottom
  WinMove ahk_id %d%, , l, t, r - l + 1, b - t + 1
  return
}

WinSuperMax(d, m) {
  mp = G_MonWA%m% ; the text of the name of the pointer
  WinSetSz(d, mp)
  return
}

WinFullscreen(d, m) {
  mp = G_MonFS%m%
  WinSetSz(d, mp)
  return
}

; Exclude the desktop
; Note: Also excludes "My Computer" browsing windows.
;       Better detection might be needed to differentiate the parent explorer "ahk_id" from child windows.
;       Also seems to disregard accidental Metro interface clicks (Win 8+).
;       May wish to verify that not only is explorer not the active window, but it wasn't the clicked-in window.

#IfWinNotActive ahk_exe explorer.exe

LWIN & LButton::
RCtrl & LButton::
  SetTitleMatchMode, 2

; monitor bounds and clicked window hwnd
  cm = %A_CoordModeMouse% ; not autoset in older AHK, but shouldn't matter as default is Screen
  CoordMode Mouse, Screen
  MouseGetPos mpx, mpy, d ; was d := WinExist("A") but that would go for the active window, rather than the clicked-in-window
  CoordMode Mouse, %cm%
  MonGetCoords()
  GetMon4xy(mpx, mpy, mpm)

; toggle the style
  WinGet Style, Style, ahk_id %d%
; 0xC40000 = WS_BORDER (0x800000) + WS_DLGFRAME (0x400000) + WS_SIZEBOX or WS_THICKFRAME (0x040000)
  if(Style & 0xC00000) { ; if has WS_CAPTION (WS_BORDER+WS_DLGFRAME) we want to supermax it
    v%d%decs := Style & 0x040000 ; decorations, specifically WS_SIZEBOX
    WinGet v%d%mm, MinMax, ahk_id %d% ; -1=min, 0=normal, 1=max
    WinSet Style, -0xC40000, ahk_id %d% ; removes most window decoration, including WS_SIZEBOX if applicable
; if a "normal" window, get the coords and maximize. If minimized, maximize. If maximized, make sure correctly positioned
    if(!v%d%mm) { ; normal window
      WinGetPos v%d%x, v%d%y, v%d%w, v%d%h, ahk_id %d%
    } if(v%d%mm < 1) { ; normal or minimized
      WinMaximize ahk_id %d% ; set flag to maximized to preserve windows' restore button functionality upon un-supermax to maximized screen
    } 
    WinSuperMax(d, mpm) ; it is now supermaximized. Now make sure it's positioned correctly
  } else { ; it's super-maximized already, so need to restore it to former position.
    if (v%d%decs) {
      WinSet Style, +0xC40000, A ; set WS_SIZEBOX and WS_CAPTION
    } else {
      WinSet Style, +0xC00000, A ; set only WS_CAPTION
    }
    if(v%d%mm = 0) { ; not either previously Maximized nor previously Minimized
      WinRestore ahk_id %d% ; restore standard window + set MinMax flag to non-maxxed 
    } else {
      WinSuperMax(d, mpm) ; Maximized flag should still be set
    }
  }
  WinSet Redraw
;  ListVars
  Return

Answer 10

यदि आप एक खिड़की चाहते हैं, जिसके चारों ओर कोई विंडोज यूआई नहीं है, और एक काली पृष्ठभूमि, यानी खेल और कुछ भी नहीं है, लेकिन खेल है, तो केवल पूर्ण स्क्रीन मोड में क्यों नहीं? केवल एक ही चीज़ के बारे में विडों किया गया मोड आपको उस परिस्थिति में मिल रहा है, यदि आप बैकग्राउंड में एक और ऐप चला रहे हैं, तो ऑल्ट-टैब प्रदर्शन थोड़ा तेज़ है?

यदि यह एक प्लेइंग स्क्रीन है, जो स्क्रीन के आकार से छोटी है और इसके बाद आपके ध्यान में नहीं आने वाली गड़बड़ी है, तो (आप एलसीडी स्क्रीन का उपयोग कर रहे हैं) आप सामान्य रूप से गेम की फुल स्क्रीन मोड में चला सकते हैं, लेकिन रिज़ॉल्यूशन को थोड़ा कम करें आपके एलसीडी के मूल रिज़ॉल्यूशन की तुलना में, कई एलसीडी स्क्रीन परिणामस्वरूप स्क्रीन को उसके चारों ओर एक काली सीमा के साथ दिखाएंगे।

Comments

मैं तेज Alt-Tab प्रदर्शन की तलाश कर रहा हूं। वास्तव में इससे अधिक; मेरे पास एक दूसरा मॉनिटर है और मैं अपने माउस को उस पर ले जाने में सक्षम होना चाहता हूं।

— नेल्सन

पर्याप्त रूप से, मैं दोहरे मॉनिटर सेटअप पर खेलता हूं और अधिकांश गेम को एक ही कारण से विंडो मोड में चलाता हूं। व्यक्तिगत रूप से मैं सामान्य रूप से गेम के रेस को उस स्क्रीन के रेस के समान बनाता हूं, और मैन्युअल रूप से इसे खींचें ताकि शीर्षक बार स्क्रीन के शीर्ष से दूर हो।

— गठरन