जवाबों:
आप अपनी पसंदीदा स्क्रिप्टिंग भाषा के साथ मोज़िला वरीयताओं की फ़ाइलों का निर्माण या हेरफेर करके ऐसा कर सकते हैं।
इन फ़ाइलों के माध्यम से सेट की जा सकने वाली प्राथमिकताओं की सूची के लिए, मोज़िला प्राथमिकताएँ और इसके बारे में देखें: कॉन्फ़िगरेशन दस्तावेज़, हालाँकि जो आपकी सूची के अनुरूप हैं वे दिखाई देते हैं: -
browser.startup.homepage (डिफ़ॉल्ट होमपेज़)browser.search.defaultenginename (डिफ़ॉल्ट खोज इंजन)app.update.auto (ऑटो अपडेट को सक्षम / अक्षम करें)हालाँकि, आपके वातावरण के आधार पर, आपको कस्टम ऐड-ऑन ( संक्षिप्त नाम गाइड टू मोज़िला प्रेफरेंस में XPI टिप्पणियां ) के माध्यम से या फ़ायरफ़ॉक्सएडीएम या इसी तरह के जीपीओ के माध्यम से सेटिंग्स को धकेलना बेहतर लग सकता है ।
browser.search.defaultenginenameका प्रभाव नहीं है। इस उत्तर पर एक अद्यतन अच्छा होगा।
आप उपयोगकर्ता प्रोफ़ाइल फ़ोल्डर में फ़ाइल user.js में निजी ब्राउज़र विकल्प को ओवरराइड कर सकते हैं। उदाहरण पाइपलाइनिंग के लिए कुछ विकल्पों को ओवरराइड करने के लिए मैं अक्सर इसका उपयोग करता हूं। उपयोगकर्ता को अपडेट करने के बाद फ़ायरफ़ॉक्स को पुनः आरंभ करने की आवश्यकता है। यदि फ़ाइल user.js मौजूद नहीं है, तो आपको एक बनाना होगा।
मैं जिस उत्तर की तलाश कर रहा था उसके भाग को कॉपी / पेस्ट करना (env जीतना)।
'C:\Users\User\AppData\Roaming\Mozilla\Firefox\Profiles\#####.default\prefs.js'जोड़ना
user_pref("browser.startup.homepage", "http://www.URL");गेट-कंटेंट / कैट string.txt / "स्ट्रिंग" >> पथ के साथ दूरस्थ मशीनों पर कॉपी करने का मेरा प्रयास prefs.js, स्ट्रिंग में भागने वाले पात्रों के कारण फ़ाइल में डाला गया कचरा समाप्त हो गया ।
cd /D "%APPDATA%\Mozilla\Firefox\Profiles\*.default"
set ffile=%cd%
echo user_pref("browser.startup.homepage", "http://superuser.com");>>"%ffile%\prefs.js"
echo user_pref("browser.search.defaultenginename", "Google");>>"%ffile%\prefs.js"
echo user_pref("app.update.auto", false);>>"%ffile%\prefs.js"
set ffile=
cd %windir%धागा एक लिट्टी पुराना है, लेकिन मैं अपने समाधान वैसे भी साझा करना चाहता हूं। आशा है कि यह किसी की मदद करता है। हमें एक समान समस्या थी और विंडोज़ स्टोर से प्रमाणपत्रों को फ़ायरफ़ॉक्स में जोड़ना चाहते थे। इसलिए मैंने ऐसा करने के लिए एक स्क्रिप्ट बनाई। वैसे भी, आप इसे अपनी आवश्यकताओं में बदल सकते हैं: बस लाइनों को जोड़ें या हटाएं :: cfg_file_name.cfg [...] बनाएं और प्रारंभ मुखपृष्ठ और इसी तरह आपको जो कुछ भी आवश्यक है उसे डालें । याद रखें ^ अंतिम से पहले ^ सेट करें, अन्यथा यह काम नहीं करेगा! echo pref("browser.startup.homepage", "http://superuser.com"^);
संस्करण 49 के बाद से आप इसे इस तरह कर सकते हैं:
@echo off
setlocal enabledelayedexpansion
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: MAIN INFORMATION
:: Title: Change about:config entries in Mozilla Firefox
:: Author: I-GaLaXy-I
:: Version: 1.1
:: Last Modified: 10.01.2018
:: Last Modified by: I-GaLaXy-I
::------------------------------------------------------------------------------
:: This script will add two files, which will change about:config parameters of
:: Mozilla Firefox. You can change the name of these two files and remove or add
:: parameters according to your needs. Renaming the files could be essential, if
:: a user creates own files and you don't want to overwrite them.
::
:: If the two files already exist and the script is run, the complete content
:: of both files will be overwritten!
::
:: Note: You may have to run it with administrative privileges!
::
:: More information: https://developer.mozilla.org/en-US/Firefox/Enterprise_deployment
:: http://kb.mozillazine.org/Locking_preferences
::------------------------------------------------------------------------------
:: Subtitle: Import CAs from Windows certificate store
:: More information: https://serverfault.com/questions/722563/how-to-make-firefox-trust-system-ca-certificates
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Set the name of the .cfg file
set cfg_file_name=add_win_certstore_cas
:: Set the name of the .js file
set js_file_name=add_win_certstore_cas
:: Registry keys to check for the installation path of Mozilla Firefox
set regkey1="HKEY_LOCAL_MACHINE\SOFTWARE\MICROSOFT\Windows\CurrentVersion\App Paths\firefox.exe" /v "Path"
set regkey2="HKEY_LOCAL_MACHINE\SOFTWARE\Clients\StartMenuInternet\FIREFOX.EXE\shell\open\command" /ve
:: Get installation path of Mozilla Firefox (if not found exit script):
reg query %regkey1%
if %errorlevel%==0 (
:: First key found, getting path
for /f "tokens=2* delims= " %%a in ('reg query %regkey1%') do set path_firefox=%%b
) else (
:: If first key not found, try another one:
reg query %regkey2%
if !errorlevel!==0 (
for /f "tokens=2* delims= " %%a in ('reg query %regkey2%') do set path_firefox=%%b
set path_firefox=!path_firefox:\firefox.exe=!
for /f "useback tokens=*" %%a in ('!path_firefox!') do set path_firefox=%%~a
) else (
:: No key found, exit script
exit
))
:: Create cfg_file_name.cfg if it doesn't exist and input the following lines.
:: Caution! If cfg_file_name.cfg already exists, all lines will be overwritten!
:: Add more lines as needed with the following syntax:
::echo pref("<name_of_config_entry>", <value>^);
(
echo //Firefox Settings rolled out via KACE from Systec
echo //Do not manually edit this file because it will be overwritten!
echo //Import CAs that have been added to the Windows certificate store by an user or administrator.
echo pref("security.enterprise_roots.enabled", true^);
) > "%path_firefox%\%cfg_file_name%.cfg"
:: Create js_file_name.js if it doesn't exist and input the following lines.
:: Caution! If js_file_name.js already exists, all lines will be overwritten!
(
echo /* Firefox Settings rolled out via KACE from Systec
echo Do not manually edit this file because it will be overwritten! */
echo pref("general.config.obscure_value", 0^);
echo pref("general.config.filename", "%cfg_file_name%.cfg"^);
) > "%path_firefox%\defaults\pref\%js_file_name%.js"
:: Files created, exit
exit