एक नए विंडोज इंस्टाल के बाद - एक्सपी या 7 - मैं विंडोज अपडेट को "फोर्स" कैसे कर सकता हूं?
मैं एक सप्ताह के बाद "पुराने" विंडोज अपडेट नहीं करना चाहता, तो क्या यह "एक कदम" में किया जा सकता है? क्या कोई "जादुई" कमांड हैं जो विंडोज को अपडेट के लिए जांच करने के लिए मजबूर करते हैं, और यदि कोई हैं, तो उन्हें स्थापित करें?
जवाबों:
आप स्क्रिप्ट का उपयोग करके अपडेट को स्वचालित रूप से जांच सकते हैं और इंस्टॉल कर सकते हैं। यह XP या विंडोज 7 में काम करेगा।
डाउनलोड के लिए कई लिपियाँ उपलब्ध हैं, यहाँ मेरा है :
' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.
' This code has been placed in the public domain. It may be freely
' used, modified, and distributed. However it is provided with no
' warranty, either express or implied.
'
' Exit Codes:
' 0 = scripting failure
' 1 = error obtaining or installing updates
' 2 = installation successful, no further updates to install
' 3 = reboot needed; rerun script after reboot
'
' Note that exit code 0 has to indicate failure because that is what
' is returned if a scripting error is raised.
'
Set updateSession = CreateObject("Microsoft.Update.Session")
Set updateSearcher = updateSession.CreateUpdateSearcher()
Set updateDownloader = updateSession.CreateUpdateDownloader()
Set updateInstaller = updateSession.CreateUpdateInstaller()
Do
WScript.Echo
WScript.Echo "Searching for approved updates ..."
WScript.Echo
Set updateSearch = updateSearcher.Search("IsInstalled=0")
If updateSearch.ResultCode <> 2 Then
WScript.Echo "Search failed with result code", updateSearch.ResultCode
WScript.Quit 1
End If
If updateSearch.Updates.Count = 0 Then
WScript.Echo "There are no updates to install."
WScript.Quit 2
End If
Set updateList = updateSearch.Updates
For I = 0 to updateSearch.Updates.Count - 1
Set update = updateList.Item(I)
WScript.Echo "Update found:", update.Title
Next
WScript.Echo
updateDownloader.Updates = updateList
updateDownloader.Priority = 3
Set downloadResult = updateDownloader.Download()
If downloadResult.ResultCode <> 2 Then
WScript.Echo "Download failed with result code", downloadResult.ResultCode
WScript.Echo
WScript.Quit 1
End If
WScript.Echo "Download complete. Installing updates ..."
WScript.Echo
updateInstaller.Updates = updateList
Set installationResult = updateInstaller.Install()
If installationResult.ResultCode <> 2 Then
WScript.Echo "Installation failed with result code", installationResult.ResultCode
For I = 0 to updateList.Count - 1
Set updateInstallationResult = installationResult.GetUpdateResult(I)
WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode
Next
WScript.Quit 1
End If
If installationResult.RebootRequired Then
WScript.Echo "The system must be rebooted to complete installation."
WScript.Quit 3
End If
WScript.Echo "Installation complete."
Loop
आप इसे कमांड लाइन से इस तरह चलाते हैं:
cscript wsusupdate.vbs
मेरी स्क्रिप्ट केवल न्यूनतम रूप से कार्यात्मक है लेकिन फिर भी उपयोगी हो सकती है। कई अन्य सुविधाओं के साथ ऐसी अन्य स्क्रिप्ट उपलब्ध हैं, Google खोज का प्रयास करें।
<59, 3> <null>: 0x80240044। किसी भी विचार क्यों यह विफल रहता है? मैंने उन तरीकों को देखने की कोशिश की है जो इस संदर्भ में हैं, लेकिन मैं यह पता नहीं लगा सका कि क्या हो रहा है। क्या मुझे आपसे सही दिशा निर्देशन मिलेगा?
विंडोज अपडेट का उपयोग करने के सामान्य तरीके से परे, आप एक कमांड-लाइन से एक चेक को बाध्य कर सकते हैं।
व्यवस्थापक कमांड प्रॉम्प्ट खोलें और चलाएँ:
C:\> %windir%\system32\wuauclt.exe /detectnow
Wuauclt.exe Windows अद्यतन का स्वतः अद्यतन क्लाइंट है और इसका उपयोग Microsoft अद्यतन से उपलब्ध अद्यतनों (MS Windows प्लेटफ़ॉर्म के विभिन्न संस्करणों के लिए) की जाँच करने के लिए किया जाता है।
यह एक स्थापित करने के लिए मजबूर नहीं करेगा।
अपडेट की जांच करने के लिए, कंट्रोल पैनल, सिक्योरिटी, विंडोज अपडेट पर जाएं, फिर "अपडेट की जांच करें" पर क्लिक करें।
अद्यतनों के लिए सच्चे रेस्क्यू को बाध्य करने का एक और तरीका है, स्लेट क्लीन को पोंछना, % विंडिर% \ Windows \ SoftwareDistribution \ Download में संग्रहीत सभी अपडेट को हटाकर :
NET STOP wuauserv
RD /S /Q %windir%\SoftwareDistribution\Download
NET START wuauserv
फिर विंडोज अपडेट पर जाएं, और "अपडेट की जांच करें"। इसमें एक घंटे का समय लग सकता है, क्योंकि आपके सिस्टम वॉल्यूम पर प्रत्येक अपडेट करने योग्य फ़ाइल की जाँच की जाती है (बाद में "अपडेट के लिए चेक" तेज़ होगा)। यह दृष्टिकोण त्रुटियों को समाप्त करता है, अपडेट किया गया है, और एक साफ-सुथरी, अप-टू-डेट प्रणाली देता है, जैसा कि एमएस इसे देखता है।
मैं एक दूसरे पार्टी उपकरण का उपयोग कर रहा हूं जिसे ताजा विंडोज़ इंस्टॉलेशन को अपडेट करने के लिए वूइस्टिट कहा जाता है । इसके साथ आप स्वचालित रिबूट सहित पूरी अद्यतन प्रक्रिया को स्वचालित कर सकते हैं। मुझे लगता है कि यह उपयोगकर्ता की उपस्थिति के बिना एक नई खिड़कियों को अप-टू-डेट प्राप्त करने के सबसे तेज़ तरीकों में से एक है।
मैंने पाया है कि अगर, विंडोज 7 पर आपके नए इंस्टाल के हिस्से के रूप में, आपने IE को अपग्रेड किया है या आपने IE अभी तक नहीं चलाया है और परिचयात्मक सवालों के जवाब दिए हैं, तो यह कि विंडोज अपडेट आपको एक त्रुटि देगा। मुझे GUI के माध्यम से Microsoft अद्यतन के बिना Windows अद्यतन स्विच करने का एक तरीका भी नहीं मिला है, इसलिए मैं मैन्युअल रूप से IE को आग लगाता हूं, इसे प्रारंभ कर देता हूं और फिर GUI के माध्यम से Windows अद्यतन सेटअप करता हूं, इसलिए मैं Microsoft अद्यतन पर स्विच कर सकता हूं और इससे बच सकता हूं प्रारंभिक त्रुटि। आपकी माइलेज भिन्न हो सकती है।