विम: टैबलाइन में टैब का इंडेक्स दिखाएं

Question

चलो कहते हैं कि मैं खोला file1.txt, file2.txt, file3a.txtऔर file3b.txtऐसा है कि tabline (शीर्ष पर बात) इस प्रकार है:

file1.txt  file2.txt  2 file3a.txt

(ध्यान दें कि कैसे file3b.txt.गायब है क्योंकि यह एक विभाजन में, उसी टैब में दिखाया गया है file3a.txt)

टैब (के साथ <Number>gt) के बीच और अधिक तेज़ी से स्थानांतरित करने के लिए , मैं प्रत्येक टैब को फ़ाइलनाम के साथ इसके सूचकांक को प्रदर्शित करना चाहूंगा। इस तरह:

1:<file1.txt>  2:<file2.txt>  3:<2 file3a.txt>

स्वरूपण (विशेष रूप से कोण ब्रेसिज़) वैकल्पिक हैं; मैं सिर्फ सूचकांक (वहां दिखाना चाहते हैं 1:, 2:और इसी तरह)।

:h tab-page-commandsगूगल या गूगल पर कोई सुराग नहीं।

Comments

अपडेट: यह प्लगइन मददगार हो सकता है। मुझे लगता है कि इस प्रश्न का उत्तर दिए जाने के बाद इसे बनाया गया था इसलिए यह किसी भी उत्तर में दिखाई नहीं देता है।

— crayzeewulf

Answer 1

आपको देखने की जरूरत है:

:help 'tabline'
:help setting-tabline

और यदि आपके पास अपनी 'guioptions' सेटिंग में "e" है:

:help 'guitablabel'

Comments

जो मुझे सही रास्ते पर ले गया। आपका बहुत बहुत धन्यवाद!

— बिटमैप

@bitmask शायद आपका समाधान प्रदान कर सकता है? हेपेटाइट, क्या आप अपने उत्तर में संशोधन कर सकते हैं?

— wmarbut

@wmarbut इस प्लगइन का उपयोग करें , यह अद्भुत है।

— .'18

माना। अत्यंत निराशाजनक है जब समाधान स्पष्ट रूप से "पाया गया" है, लेकिन प्रदान नहीं किया गया है और सभी को डॉक्स के माध्यम से खुदाई करने और समान कॉन्फ़िगरेशन लिखने में उसी समय को खर्च करना है।

— एलेक्स एच।

Answer 2

इसे अपने vimrc में रखें

" Rename tabs to show tab number.
" (Based on http://stackoverflow.com/questions/5927952/whats-implementation-of-vims-default-tabline-function)
if exists("+showtabline")
    function! MyTabLine()
        let s = ''
        let wn = ''
        let t = tabpagenr()
        let i = 1
        while i <= tabpagenr('$')
            let buflist = tabpagebuflist(i)
            let winnr = tabpagewinnr(i)
            let s .= '%' . i . 'T'
            let s .= (i == t ? '%1*' : '%2*')
            let s .= ' '
            let wn = tabpagewinnr(i,'$')

            let s .= '%#TabNum#'
            let s .= i
            " let s .= '%*'
            let s .= (i == t ? '%#TabLineSel#' : '%#TabLine#')
            let bufnr = buflist[winnr - 1]
            let file = bufname(bufnr)
            let buftype = getbufvar(bufnr, 'buftype')
            if buftype == 'nofile'
                if file =~ '\/.'
                    let file = substitute(file, '.*\/\ze.', '', '')
                endif
            else
                let file = fnamemodify(file, ':p:t')
            endif
            if file == ''
                let file = '[No Name]'
            endif
            let s .= ' ' . file . ' '
            let i = i + 1
        endwhile
        let s .= '%T%#TabLineFill#%='
        let s .= (tabpagenr('$') > 1 ? '%999XX' : 'X')
        return s
    endfunction
    set stal=2
    set tabline=%!MyTabLine()
    set showtabline=1
    highlight link TabNum Special
endif

Comments

क्या आप जानते हैं कि '%999XX'यहाँ क्या मतलब है?

— बच्चू

चूंकि यह टर्मिनल और जीवीएम दोनों के लिए काम करता है, मुझे लगता है कि इसका सबसे अच्छा समाधान है। मेरा उत्थान करो, श्रीमान।

— imolit

Answer 3

पर विकिया पेज आप कम से कम दो (मेरे द्वारा परीक्षण किया है), जो आप टैब सूचकांक प्राप्त सकते हैं, और उनमें से एक-एक बफर संपादन है जो अंदर खिड़कियों की संख्या पैदा करता है।

यहाँ मेरे द्वारा संशोधित बफ़र्स की गिनती का उत्पादन करने वाले संशोधनों का परिणाम है, मैंने जो बदलाव किया वह बाकी टैब के अनुरूप गणना का हाइलाइट मान बनाने के लिए था:

set tabline=%!MyTabLine()  " custom tab pages line
function MyTabLine()
        let s = '' " complete tabline goes here
        " loop through each tab page
        for t in range(tabpagenr('$'))
                " set highlight
                if t + 1 == tabpagenr()
                        let s .= '%#TabLineSel#'
                else
                        let s .= '%#TabLine#'
                endif
                " set the tab page number (for mouse clicks)
                let s .= '%' . (t + 1) . 'T'
                let s .= ' '
                " set page number string
                let s .= t + 1 . ' '
                " get buffer names and statuses
                let n = ''      "temp string for buffer names while we loop and check buftype
                let m = 0       " &modified counter
                let bc = len(tabpagebuflist(t + 1))     "counter to avoid last ' '
                " loop through each buffer in a tab
                for b in tabpagebuflist(t + 1)
                        " buffer types: quickfix gets a [Q], help gets [H]{base fname}
                        " others get 1dir/2dir/3dir/fname shortened to 1/2/3/fname
                        if getbufvar( b, "&buftype" ) == 'help'
                                let n .= '[H]' . fnamemodify( bufname(b), ':t:s/.txt$//' )
                        elseif getbufvar( b, "&buftype" ) == 'quickfix'
                                let n .= '[Q]'
                        else
                                let n .= pathshorten(bufname(b))
                        endif
                        " check and ++ tab's &modified count
                        if getbufvar( b, "&modified" )
                                let m += 1
                        endif
                        " no final ' ' added...formatting looks better done later
                        if bc > 1
                                let n .= ' '
                        endif
                        let bc -= 1
                endfor
                " add modified label [n+] where n pages in tab are modified
                if m > 0
                        let s .= '[' . m . '+]'
                endif
                " select the highlighting for the buffer names
                " my default highlighting only underlines the active tab
                " buffer names.
                if t + 1 == tabpagenr()
                        let s .= '%#TabLineSel#'
                else
                        let s .= '%#TabLine#'
                endif
                " add buffer names
                if n == ''
                        let s.= '[New]'
                else
                        let s .= n
                endif
                " switch to no underlining and add final space to buffer list
                let s .= ' '
        endfor
        " after the last tab fill with TabLineFill and reset tab page nr
        let s .= '%#TabLineFill#%T'
        " right-align the label to close the current tab page
        if tabpagenr('$') > 1
                let s .= '%=%#TabLineFill#%999Xclose'
        endif
        return s
endfunction

Comments

आपकी स्क्रिप्ट अन्य की तुलना में बेहतर है क्योंकि यह उस हिस्से को बरकरार रखता है जहां टैब दिखाता है कि फ़ाइल संपादित की गई है या नहीं। धन्यवाद!

— प्लास्टर ग्रोव

हाँ, मैं airlineप्लगइन से टैबलाइन का उपयोग कर रहा हूं , लेकिन ईमानदार होने के लिए, यह पुरानी टैबलाइन जो मेरे साथ आई है, वह बहुत अधिक कार्यात्मक है ...

— स्टीवन लू

Answer 4

Tabline प्लगइन एक vim प्लगइन है कि लागू कार्यक्षमता का अनुरोध किया और अपने vimrc बुझाना नहीं होंगे। बस स्थापित करें, और विम को पुनरारंभ करें।

स्थापित करने के लिए:

cd /usr/share/vim/vimfiles/plugin/
wget https://raw.githubusercontent.com/mkitt/tabline.vim/master/plugin/tabline.vim

या एक प्लगइन प्रबंधक का उपयोग करें।

Comments

सुपर उपयोगकर्ता में आपका स्वागत है! कृपया पढ़ें कैसे सॉफ्टवेयर की सिफारिश करने के लिए न्यूनतम आवश्यक जानकारी कैसे सूपर उपयोगकर्ता पर सॉफ्टवेयर की सिफारिश करने पर और सुझावों। आपके उत्तर को उपयोगी रखने के लिए, भले ही प्रदान की गई कड़ी इन विवरणों को आपके उत्तर में संपादित कर दे।

— मैं कहता हूं कि मोनिका

Answer 5

GUI- आधारित विम (लिनक्स पर Gvim, Mac पर MacVim, आदि) के लिए, इसे अपने में डालें .gvimrc:

set guitablabel=%N:%M%t " Show tab numbers

वास्तव में प्रदर्शित संख्या का उपयोग करने पर कुछ सुझाव:

• Ngtटैब में स्विच जाएगा N। उदाहरण के लिए, 3gtटैब 3 पर जाता है।
• :tabm2टैब 2 के बाद प्रदर्शित होने के लिए वर्तमान टैब चलता है ।
  • इस टैब को पहली स्थिति में ले जाने के लिए, उपयोग करें :tabm0
  • इस टैब को अंतिम स्थिति में ले जाने के लिए, बस उपयोग करें :tabm