17

बैच फ़ाइल में मुझे दिनांक कमांड से एक महीने, दिन, वर्ष निकालने की आवश्यकता होती है। इसलिए मैंने निम्नलिखित का उपयोग किया, जो अनिवार्य रूप से एक उप चर में एक उप स्ट्रिंग निकालने के लिए दिनांक कमांड को पार करता है:

set Day=%Date:~3,2%
set Mth=%Date:~0,2%
set Yr=%Date:~6,4%

यह सब बहुत अच्छा है, लेकिन अगर मैं इस बैच फ़ाइल को एक अलग क्षेत्रीय / देश सेटिंग्स के साथ मशीन पर तैनात करता हूं, तो यह विफल हो जाता है क्योंकि महीने, दिन और वर्ष अलग-अलग स्थानों में होते हैं।

दिनांक प्रारूप की परवाह किए बिना मैं महीने, दिन और वर्ष कैसे निकाल सकता हूं?

— AngryHacker
स्रोत

1

क्या आप बैच के लिए बिल्कुल प्रतिबंधित हैं? VBScript / WSH और / या पॉवरशेल में ऐसी बात बहुत सरल है ...

— Adrien

@ एड्रिएन, हाँ बैच तक सीमित - यह VS2008 पोस्ट-बिल्ड कदम का हिस्सा है।

— एंग्रीहैकर

% तारीख से%% की जगह: ~ 6,4% -% तारीख: ~ 3,2% -% तारीख: ~ 0,2% ने काम किया

— MagTun

14

स्रोत: http://ss64.com/nt/syntax-getdate.html

विधि 2 (एकल सेमी)

_GetDate.cmd

@Echo off
:: Check WMIC is available
WMIC.EXE Alias /? >NUL 2>&1 || GOTO s_error

:: Use WMIC to retrieve date and time
FOR /F "skip=1 tokens=1-6" %%G IN ('WMIC Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
   IF "%%~L"=="" goto s_done
      Set _yyyy=%%L
      Set _mm=00%%J
      Set _dd=00%%G
      Set _hour=00%%H
      SET _minute=00%%I
)
:s_done

:: Pad digits with leading zeros
      Set _mm=%_mm:~-2%
      Set _dd=%_dd:~-2%
      Set _hour=%_hour:~-2%
      Set _minute=%_minute:~-2%

:: Display the date/time in ISO 8601 format:
Set _isodate=%_yyyy%-%_mm%-%_dd% %_hour%:%_minute%
Echo %_isodate%
pause

विधि 1 (cmd + vb)

_GetDate.cmd

@Echo off
For /f %%G in ('cscript /nologo getdate.vbs') do set _dtm=%%G
Set _yyyy=%_dtm:~0,4%
Set _mm=%_dtm:~4,2%
Set _dd=%_dtm:~6,2%
Set _hh=%_dtm:~8,2%
Set _nn=%_dtm:~10,2%
Echo %_yyyy%-%_mm%-%_dd%T%_hh%:%_nn%

_getdate.vbs

Dim dt
dt=now
'output format: yyyymmddHHnn
wscript.echo ((year(dt)*100 + month(dt))*100 + day(dt))*10000 + hour(dt)*100 + minute(dt)

— टेक्स हेक्स
स्रोत

1

आह हा, लोकेल की डेट ऑर्डर करने का बहुत साफ तरीका। ss64 में cmd.exe उपयोगकर्ताओं का एक निफ्टी समुदाय है।

— निकोली

मैंने आपके स्रोत लिंक से दोनों लिपियों को शामिल किया। आशा है कि यह आपके लिए ठीक है

— nixda

@ निक्सडा कोई समस्या नहीं है, जो भी उपयोगकर्ता मदद करता है।

— टेक्स हेक्स

यदि आपको उपरोक्त "विधि 2" में सेकंड को बनाए रखने की आवश्यकता है , तो दूसरों की तरह अग्रणी शून्य Set _second=00%%Kसे wmicपैड और निकालने पर जोड़ें ।

— टिम पैरेंटी

13

Windows XP और बाद में

_getDate.cmd

@echo off
for /f "tokens=2 delims==" %%G in ('wmic os get localdatetime /value') do set datetime=%%G

set year=%datetime:~0,4%
set month=%datetime:~4,2%
set day=%datetime:~6,2%

echo %year%/%month%/%day%

_{उत्पादन}

— and31415
स्रोत

सबसे संक्षिप्त उत्तर के लिए +1। मैं यह भी सुझाव देना चाहता हूं कि ECHO %year%-%month%-%day%आईएसओ और फाइलसिस्टम संगत प्रारूप के साथ समाप्त हो रहा है (वर्ष-महीने-दिन तक स्वचालित रूप से उल्लेख नहीं करने के लिए)। :-)।

— जेफान श्रोएडर 23

3

मुझे पता है कि यह वास्तव में आपके द्वारा पूछा गया नहीं है, लेकिन मैं dateबैच फ़ाइल के अंदर एक कमांड से लिनक्स एप्लिकेशन के विंडोज पोर्ट का उपयोग करता हूं और फिर एक चर के परिणाम को असाइन करता हूं ।

मुझे अभी तक केवल बैच कमांड का उपयोग करके तारीख प्राप्त करने का एक तरीका खोजना है।

— Hydaral
स्रोत

2

YYYY-MM-DD प्रारूप के लिए इस बैच फ़ाइल का उपयोग करें। यह विंडो इंस्ट्रूमेंटेशन टूल का उपयोग करता है जो एक हाल ही में विंडोज संस्करणों में मौजूद होना चाहिए ताकि एक डेटाइम स्ट्रिंग प्राप्त हो जो क्षेत्रीय सेटिंग्स से स्वतंत्र हो।

पथ में एक बैच फ़ाइल को सहेजें (जैसे) c: \ windows \ rdate.bat तब चर (सेट) को सेट करने के लिए एक कॉल RDATE.BAT के साथ एक्सेस करें। वैकल्पिक रूप से, कोड को अपने बैच फ़ाइल में कॉपी करें।

यह तिथि प्रारूप फ़ाइल नाम और लॉगिंग के लिए उपयुक्त है। यह सही ढंग से हल करता है। दूसरी सटीकता पर लॉगिंग बैच फ़ाइल गतिविधि में उपयोग के लिए उपयुक्त YYYY-MM-DD-HHMMSS के रूप में लॉगटाइम चर एक दिनांक + समय चर जोड़ता है।

अपनी इच्छानुसार दिनांक (और समय) स्वरूपों को समायोजित करें। उत्पादन में स्क्रीन echos REM करें। प्रत्येक पाठ चयन में दो संख्याएँ शून्य-आधारित प्रारंभ वर्ण सूचकांक और कॉपी करने के लिए वर्णों की संख्या, उदाहरण के लिए,% डेटाइम: ~ 0,4% स्थिति 4 पर शुरू होने वाले 4 वर्ण प्रतिस्थापन को लेती है।

echo off
rem First, get the locality-invariant datetime
for /f "tokens=2 delims==" %%I in ('wmic os get localdatetime /format:list') do set datetime=%%I
rem echo %datetime%

rem Build the reverse date string YYYY-MM-DD
set rdate=%datetime:~0,4%-%datetime:~4,2%-%datetime:~6,2%
echo rdate=%rdate%

rem Built a datetime string YYYY-MM-DD-hhmmss
set logtime=%rdate%-%datetime:~8,6% 
echo logtime=%logtime%

— जिम् बर्च
स्रोत

1

लगभग and31415 के उत्तर के समान है । दोनों स्क्रिप्ट का उपयोगwmic os get localdatetime

— nixda

1

जब आप सही होते हैं कि वीएस 2008 एक बैचफाइल का उत्पादन करता है, तो आप बहुत अधिक किसी भी प्रोग्राम को चला सकते हैं, जिसमें पॉवरशेल स्क्रिप्ट और अन्य प्रोग्राम शामिल हैं।

संपादित करें:

यहाँ कुछ ऐसे ही प्रश्न हैं:

/programming/1051845/visual-studio-2008-professional-build-process /programming/3049369/embed-application-compilation-time-camp

मूल रूप से, मुझे लगता है कि यह एसओ में चला गया था। । ।

— surfasb
स्रोत

0

क्या आपने NET TIME \\%ComputerName%इसके बजाय उपयोग करने की कोशिश की है DATE? मुझे लगता है कि NET TIMEस्थानीय लोगों की परवाह किए बिना एक सुसंगत प्रारूप में डेटा प्रदान करना है।

— किर्क
स्रोत

नहीं, यह नहीं है।

— एंग्रीहैकर

दिलचस्प है, मैंने इसे केवल कोशिश की, एयू और यूएस प्रारूपों के बीच स्विच करना, और net timeहमेशा एम / डी / yyyy प्रारूप में आउटपुट। @AngryHacker, किस सेटिंग के साथ यह आपके लिए काम नहीं आया?

— हाइडल जूल

1

मैंने फ्रेंच (बेल्जियम) स्विच किया और इसने मुझे 2011-07-27 दिया। अमेरिका

— 07/27/2011

0

शेखर के पोस्ट की बदौलत यह समय की जरूरत और शून्य पैडिंग का काम करता है।

@Echo Off

for /f "tokens=1-5 delims=:" %%d in ("%time%") do set var=%date:~10,4%%date:~4,2%%date:~7,2%-%%d%%e

set datetimestr=%var: =0%

set logfile=LogFile-%datetimestr%.txt

echo %logfile%

आउटपुट: LogFile-20151113-0901.txt

— Trifused
स्रोत

-1

यह कुछ हद तक विषय हो सकता है लेकिन यहाँ एक .bat फ़ाइल है जो मैंने अपने स्वयं के निर्धारित बैकअप के लिए लिखी है और विजुअल स्टूडियो में पोस्टबिल्डिंग एक्शन से भी कॉल करता है। मुझे उम्मीद है कि कुछ इसे उपयोगी पाएंगे।

निम्नलिखित को .bat फ़ाइल में सहेजें

--------------------------------------------------
**:: The following is Copyright &copy; 2012 ShopNetNuke Corp.  All rights reserved.
::  and released under the GNU General Public License (GPLv3)**

:: The following section retrieves the current date and time and formats it into the '%var%' variable
:: This format always ensures that the Date and Time are fixed length to avoid the situation of
:: having a value of '12/ 1/2012 rather than '12/01/2012'
echo off
for /f "tokens=1-5 delims=:" %%d in ("%time%") do set var=%date:~10,4%-%date:~4,2%-%date:~7,2%-%%d-%%e
set var=%var: =0%
echo Beginning my valuable Backup Set:  Backup--%var%

:: If you wanted to request the user input a filename prefix, 
:: then we would use something similar to this
:: set /p nameprefix= Enter the file name prefix?
:: Get the Current Date and Time
::for /f "tokens=1-5 delims=:" %%d in ("%time%") do set var=%date:~10,4%-%date:~4,2%-%date:~7,2%-%%d-%%e
:: set var=%var: =0%
:: echo Beginning my valuable Backup Set:  Backup--%var%_%nameprefix%

Pause

echo Starting SQL Server Database Backup Job...
:: The following line initiates the Backup job within SqlServer Agent.
:: Change 'MyBackupNameInSqlAgent' to the name of the job you want executed
:: Change the directory paths to those relevant to your current system installation directories
:: SqlAgent will not return a value if the backup action succeed, 
:: however, in the event an error is encountered, it will be echoed onto the screen
"C:\Program Files\Microsoft SQL Server\100\Tools\Binn\sqlcmd.exe" -S SQLSERVERNAME\INSTANCENAME -Q "execute msdb.dbo.sp_start_job @job_name = 'MyBackupNameInSqlAgent'"
:: An error will be returned if the Backup job is not found or has already been triggered by another process

echo Starting My Valuable Source Code Directory Backup...

echo ...backing up files and folders in "C:\Source\MyPreciousProjectDirectory\"...
:: The following line will execute the 7zip command to create a .7z file of the directory named in 'MyPreciousProjectDirectory'
:: and tells it to put the archive in the 'MyPreciousBackupDirectory'.  The compression level will be defined by the 7zip default settings
:: The -p flag tells 7zip to password protect the archive, in this case, I've used the Date/Time portion of the filename as the password
:: remove the '-p%var%' section to remove password protection from the archive
"C:\Program Files\7-Zip\7z.exe" a -t7z C:\MyPreciousBackupDirectory\%var%\MyPreciousProject--%var%.7z -p%var% -mhe C:\Source\MyPreciousProjectDirectory\* 

echo Source Code Directory Backups complete.

echo Archiving Database Backups now...
:: The following line will execute the 7zip command to archive the Database backup.
:: The '*' could be replaced by the actual backup name.
:: The '*' indicates all files of type '.bak'
:: The -p flag tells 7zip to password protect the archive, in this case, again, I've used the Date/Time portion of the filename as the password
:: remove the '-p%var%' section to remove password protection from the archive
"C:\Program Files\7-Zip\7z.exe" a -t7z  C:\MyPreciousBackupDirectory\%var%\MyPreciousProject-Database-%var%.7z -p%var% -mhe "C:\Program Files\Microsoft SQL Server\MSSQL10.SQLDEV08\MSSQL\Backup\*.bak"

echo Database Backup Archival process complete.

:: If you wanted to place both the previous backups into one single combination archive,
:: you could do something like the following
"C:\Program Files\7-Zip\7z.exe" a -t7z C:\MyPreciousBackupDirectoryForSourceAndDatabase\%var%\MyPreciousProjectBackupSourceAndDatabase--%var%.7z -p%var% -mhe C:\Source\MyPreciousProjectDirectory\* 


echo Now attempting to copy archives to Network Server...
:: The following line will use xcopy to copy the arechives to the server backup directory and place them in a directory named by the DateTime variable %var%
xcopy /S /I /J /Y C:\MyPreciousBackupDirectory\%var% \\MyPreciousBackupServerName\SourceCode\MyPreciousServerBackupDirectory\%var%
:: Or if the combination above was used then copy that...
xcopy /S /I /J /Y C:\MyPreciousBackupDirectoryForSourceAndDatabase\%var% \\MyPreciousBackupServerName\SourceCode\MyPreciousServerBackupDirectory\%var%


echo 7z Archive files transferred to MyPreciousBackupServerName successfully
echo  ||
echo \||/
echo  \/
echo ---------------------------------------------------
echo ----- BACKUP SET "%var%" COMPLETE ------
echo ---------------------------------------------------
pause

— जे.सी.
स्रोत

1

tl; dr, आप एक व्याख्या जोड़ सकते हैं कि स्क्रिप्ट क्या करती है। क्योंकि यह तुरंत समाधान के रूप में नहीं आता है। यह अधिक उपयोगी भी हो सकता है, यदि आप गैर-प्रासंगिक बिट्स कोड को हटा सकते हैं

— शेखर

1

पूरे बैच की स्क्रिप्ट %date%और %time%चर पर निर्भर करती है , जो स्थानीय-जागरूक हैं, और ओपी के पूछे जाने पर वास्तव में अनुमान नहीं लगाया जा सकता है।

— 31415

एक पूर्वानुमानित प्रारूप में बैच फ़ाइल में दिनांक कैसे प्राप्त करें?

स्रोत: http://ss64.com/nt/syntax-getdate.html

विधि 2 (एकल सेमी)

विधि 1 (cmd + vb)

Windows XP और बाद में