कोई स्क्रॉल व्हील ट्रैकबॉल के लिए उपाय?

Question

मैं एक ट्रैकबॉल खरीदने के लिए सोच रहा हूं और मेरा विकल्प लॉजिटेक ट्रैकमैन मार्बल है। लेकिन फिर मैंने पाया कि कोई स्क्रॉल व्हील नहीं है। आप उससे कैसे निपटेंगे? क्या मैं निश्चित रूप से स्क्रॉल व्हील के साथ एक ट्रैकबॉल खरीदना चाहता हूं? मैं facebook का उपयोग करके बहुत स्क्रॉल करता हूं।

मैं अपनी अनुक्रमणिका और मध्य उंगलियों के साथ क्लिक नहीं करना चाहता, इसलिए ट्रैकमैन व्हील की तरह कुछ ट्रैकबॉल चूहे मेरे लिए काम नहीं करेंगे।

Comments

Logitech द्वारा ट्रैकमैन व्हील का प्रयास करें। एक वायर्ड या वायरलेस मॉडल प्रदान करते हैं।

— Moab

मैं अपनी अनुक्रमणिका और मध्य उंगलियों के साथ क्लिक नहीं करना चाहता, इसलिए मैं केंद्र में गेंद के साथ ट्रैकबॉल चाहता हूं। धन्यवाद।

— lamwaiman1988

आप आमतौर पर अपने माउस सॉफ्टवेयर के साथ चीजों को इस तरह सेट कर सकते हैं। वहां से आप कई तरह की चीजें कर सकते हैं (ट्रैकबॉल वगैरह चलते समय राइट-क्लिक बटन दबाएं ...)। मैं मान रहा हूँ कि आपने शायद अपनी समस्या अब तक ठीक कर ली है, क्योंकि आपने इसे एक साल पहले पोस्ट किया था । यदि नहीं, तो फिर सौभाग्य।

— हेल्पिंगहैंड

@ हेल्पिंगहैंड नोप मैं अभी भी एक व्यवहार्य समाधान नहीं ढूंढ सका। अब मैं स्क्रॉलिंग के लिए पेजअप और पेजडाउन का उपयोग कर रहा हूं।

— lamwaiman1988

Answer 1

यदि आप Windows पर हैं तो मैं सुझाव दूंगा कि AutoHotKey, अन्य उपयोगकर्ता पहले ही मार्बल माउस के साथ स्क्रॉल कर चुके हैं (मैंने स्क्रिप्ट का नीचे उपयोग किया है):

http://www.autohotkey.com/board/topic/4677-wheel-button-emulation-script/

लॉजिटेक का समाधान जो उनके ड्राइवरों के साथ आता है, अजीब है: आप एक बार क्लिक करके 4 तरीके स्क्रॉल करने में सक्षम होते हैं और इसे अक्षम करने के लिए फिर से क्लिक करते हैं। आप पकड़ नहीं सकते हैं और स्क्रॉल कर सकते हैं कि मैं क्या था। मैं उनके सॉफ़्टवेयर की स्थापना रद्द कर रहा हूं।

Comments

यह समाधान काम करता है लेकिन केवल ट्रैकबॉल पर छोटे बाएं बटन का समर्थन करता है इसलिए यह वेब पेज के लिए डिफ़ॉल्ट 'बैक' फ़ंक्शन को अक्षम करता है। वैसे भी, मैं कुछ दिनों के लिए इसे आज़माने के बाद इस उत्तर को स्वीकार कर सकता हूं।

— lamwaiman1988

नोट: एएचके स्क्रिप्ट केवल एक्स-बटन या 4+ बटन ट्रैकबॉल के साथ ट्रैकबॉल के लिए काम करती है।

— माइकल पॉलुकोनिस

एक अलग बटन का उपयोग करने के लिए स्क्रिप्ट को अपडेट करना बहुत सरल है। शीर्ष के पास एक चर असाइनमेंट के ऊपर एक टिप्पणी है - "XButton1" को बदले में उस बटन का उपयोग करने के लिए एक और मान। AHK हेल्प फ़ाइल (स्टार्ट मेन्यू से AHK को रन करें), "कीज़, माउस बटन, और जॉयस्टिक कंट्रोल्स" के अंतर्गत विशेष कुंजी की एक सूची है, जहाँ आप संशोधक के रूप में कार्य करने के लिए कोई भी कुंजी / बटन चुन सकते हैं।

— जेम्स बी

Answer 2

मेरे पास एक ही ट्रैकबॉल है और समाधान बहुत ही सुरुचिपूर्ण है: जब आप चुने हुए बटन पर क्लिक करते हैं, तो गेंद खुद एक स्क्रॉल व्हील बन जाती है। मैंने बड़ा दाहिना बटन चुना है जिसे मैं छोटी उंगली से दबाता हूं।

यह बहुत सुविधाजनक है और इसका उपयोग करने के लिए केवल कुछ दिन लगते हैं।

आप जल्दी से विचार करेंगे कि कोई भी स्क्रॉलव्हील (माउस या ट्रैकबॉल पर) कुछ बेकार है। मेरा विश्वास करो, यह इसके लायक है ;-)

लाभ:

• 1 डी के बजाय 2 डी स्क्रॉल
• एक पहिया की तुलना में तेज और अधिक सटीक स्क्रॉलिंग
• लंबी स्क्रॉल के लिए अधिक आरामदायक (गेंद की जड़ता के लिए धन्यवाद)। अपने फेसबुक उदाहरण के लिए बिल्कुल सही।

मैं इसके बिना नहीं रह सकता।

किसी भी Linux OS के अंतर्गत कॉन्फ़िगर करना कठिन नहीं है। इसके लिए आपको केवल एक /etc/X11/xorg.conf फ़ाइल बनानी होगी (मेरा कॉन्‍फ़िगर यहां देखें: Xorg.conf को संपादित किए बिना लिनक्स के अंतर्गत एक ट्रैकबॉल कॉन्फ़िगर करें )

अधिक विवरण यहां पाया जा सकता है: https://help.ubuntu.com/community/Logitech_Marblemouse_USB

विंडोज पर, मुझे कोई अनुभव नहीं है लेकिन मुझे लगता है कि एक कॉन्फ़िगरेशन टूल ट्रैकबॉल के साथ दिया गया है।

Comments

मेरे काम करने का माहौल ज्यादातर खिड़कियां हैं इसलिए यह मेरे लिए व्यवहार्य विकल्प नहीं है और मुझे नहीं पता कि इसे खिड़कियों में कैसे पोर्ट किया जाए।

— lamwaiman1988

Answer 3

आप मार्बल माउस स्क्रॉल व्हील की कोशिश कर सकते हैं, विशेष रूप से उस माउस के लिए विकसित:

मार्बल माउस स्क्रॉल व्हील, या सिर्फ मार्बल स्क्रॉल, एक छोटा प्रोग्राम है जिसे बिना किसी ट्रैकबॉल या माउस के स्क्रॉल व्हील को अनुकरण करने के लिए डिज़ाइन किया गया है। यह विशेष रूप से लॉजिटेक मार्बल माउस के लिए डिज़ाइन किया गया था, लेकिन यह किसी भी मानक माउस या ट्रैकबॉल के साथ काम कर सकता है। यह विंडोज 2000 और इसके बाद के संस्करण के लिए डिज़ाइन किया गया है।

मार्बल स्क्रॉल लॉजिटेक के ऑटोस्कॉल और यूनिवर्सल स्क्रॉल कार्यों के लिए एक प्रतिस्थापन है; न तो एक वास्तविक स्क्रॉल व्हील का ठीक से अनुकरण करें और दोनों की सीमाएं और दोष हैं।

मार्बल स्क्रॉल किसी भी माउस या ट्रैकबॉल के साथ काम करता है और इसे Logitech के सेटपॉइंट या माउसवेयर ड्राइवरों को स्थापित करने की आवश्यकता नहीं होती है।

विशेषताएं

• दो से अधिक बटन वाले किसी भी माउस में एक स्क्रॉल व्हील जोड़ें
• अधिकांश अनुप्रयोगों के साथ संगतता जो स्क्रॉल व्हील का समर्थन करते हैं (किसी भी प्रकार के इनपुट के लिए)
• समायोज्य त्वरण
• एडजस्टेबल स्क्रॉलिंग दूरी (प्रति "स्टेप" - नीचे देखें)
• असली माउस व्हील का अनुकरण करने के लिए स्क्रॉलिंग स्टेप
• क्विक लेफ्ट / राइट हैंड मोड स्विचर
• ट्रे आइकन पर क्लिक करके त्वरित सक्षम / अक्षम करें
• सिस्टम संसाधनों पर छोटा और हल्का

उत्पाद की वेबसाइट वर्तमान में नीचे की ओर लगती है, लेकिन यहां आर्काइव.ऑर्ग पर साइट के पाठ की एक प्रति है ।

एक डाउनलोड लिंक यहाँ है ।

Comments

विंडोज़ 8 पर यह अच्छी तरह से काम करता है।

— जस्टिनस डोडनास

यह अभी भी Win7 पर बहुत अच्छा काम करता है। 8. मेरे माउस पर बैक बटन रखने से मुझे ट्रैकबॉल का उपयोग करने में आसानी होती है। फिर भी मैं बैक बटन को बैक बटन के रूप में उपयोग कर सकता हूं। मूल रूप से यह कुछ भी दूर ले बिना कार्यक्षमता जोड़ा। सबसे अच्छा प्रकार का समाधान।

— जपजोन

विंडोज 10 पर मज़बूती से काम करना प्रतीत नहीं होता है :(

— askvictor

लिंक किए गए डाउनलोड मिरर मालवेयर के रूप में दिखाई देते हैं - सुनिश्चित नहीं है कि यह एक गलत सकारात्मक है, लेकिन अभी के लिए इसे जप नहीं कर रहा है।

— जेम्स बी

मैंने इसे वर्षों तक उपयोग किया है, और यह विंडोज 8 तक ठीक काम करता है, जिसमें यह अविश्वसनीय हो गया। Win 10 में इसे आजमाया नहीं गया। मैंने ओरिजिनल लेखक को ईमेल किया जिसने जवाब दिया (और!) हालांकि उसने स्रोत कोड खो दिया था, मुझे बताया कि इसे कैसे करना है। उन्होंने मुझे जो गिफ्ट दिया, वह यह है कि इस अन्य उत्तर ने क्या किया: सुपरयुसर.

— जोहान

Answer 4

एक सरल 100 लाइन C ++ विकल्प है, जो AutoHotKey समाधानों के समान है, अर्थात्

• एक्स-बटन और में से किसी एक को पकड़ते हुए ट्रैकबॉल को ले जाकर वर्टिकल / हॉरिजॉन्टल स्क्रॉल व्हील इवेंट भेजना
• ट्रैकबॉल को स्थानांतरित किए बिना एक्स-बटन दबाते और छोड़ते समय मध्य क्लिक करें।

https://github.com/Seelge/TrackballScroll

संपादित करें: नए संस्करण एक सिस्टरे-आइकन प्रदान करते हैं, विंडोज 10 पर काम करते हैं और सी # पर आधारित होते हैं।

Comments

यह समाधान मेरे द्वारा आजमाई गई किसी भी ऑटोहॉट स्क्रिप्ट से बेहतर है, जिसमें से सभी एक कष्टप्रद "कर्सर जिगल" से पीड़ित होते हैं, एक समय-संचालित घटना के कारण जो "माउस को उसकी मूल स्थिति में वापस ले जाता है" जबकि हर इतने मिलीसेकंड स्क्रॉल। यह सरल TrackballScroll निष्पादन योग्य ऐसी कोई सीमा नहीं है और बहुत अच्छी तरह से काम करता है। एकमात्र चेतावनी यह है कि यह विंडोज 10 क्रिएटर के अपडेट पर मज़बूती से काम नहीं करता है, इस लेखन के रूप में: github.com/Seelge/TrackballScroll/issues/14

— बेन जॉनसन

मैं वर्षों से इसका उपयोग कर रहा था और इसे प्यार करता था (मैंने एक साल पहले भी इसका जवाब दिया था) लेकिन पिछले हफ्ते विंडोज 10 पर स्विच करने के बाद मैं यह बताना चाहूंगा कि बग का उल्लेख अन्य टिप्पणी में अभी भी नहीं है ' टी निश्चित, और अविश्वसनीयता ने इसे व्यवहार में मेरे लिए पूरी तरह से अनुपयोगी बना दिया है।

— mtraceur

Answer 5

यहाँ AutoHotKey स्क्रिप्ट का उपयोग किया गया है। आप बाएं छोटे बटन को दबाकर रखें और गेंद को ऊपर / नीचे घुमाएं। हालाँकि बायाँ छोटा बटन क्लिक करने पर भी BACK होता है। यह बाएँ / दाएँ स्क्रॉल भी कर सकता है, लेकिन यह मेरे लिए बहुत संवेदनशील था इसलिए इसे यहाँ टिप्पणी की गई है (जो ब्लॉक शुरू होता है ;timesX := Abs(movedx) / 4)।

मुझे http://www.autohotkey.com/board/topic/30816-simulate-scroll-wheel-use-right-mouse-button/ पर मूल संस्करण मिला । मैंने अपना संस्करण वहां एक और पोस्टर्सनॉ 2323 के रूप में पोस्ट किया।

$*XButton1::
Hotkey, $*XButton1 Up, XButton1up, off
;KeyWait, XButton1, T0.4
;If ErrorLevel = 1
;{
   Hotkey, $*XButton1 Up, XButton1up, on
   MouseGetPos, ox, oy
   SetTimer, WatchTheMouse, 5
   movedx := 0
   movedy := 0
   pixelsMoved := 0
;   TrayTip, Scrolling started, Emulating scroll wheel
;}
;Else
;   Send {XButton1}
return

XButton1up:
Hotkey, $*XButton1 Up, XButton1up, off
SetTimer, WatchTheMouse, off
;TrayTip
If (pixelsMoved = 0)
{
    ;The mouse was not moved, send the click event
    ; (May want to make it PGUP or something)
    Send {XButton1}
    Send {XButton1Up}
}
return

WatchTheMouse:
MouseGetPos, nx, ny
movedx := movedx+nx-ox
movedy := movedy+ny-oy

pixelsMoved := pixelsMoved + Abs(nx-ox) + Abs(ny-oy)

;timesX := Abs(movedx) / 4
;ControlGetFocus, control, A
;Loop, %timesX%
;{
;    If (movedx > 0)
;    {
;        SendMessage, 0x114, 1, 0, %control%, A ; 0x114 is WM_HSCROLL
;        movedx := movedx - 4
;    }
;    Else
;    {
;        SendMessage, 0x114, 0, 0, %control%, A ; 0x114 is WM_HSCROLL
;        movedx := movedx + 4
;    }
;}

timesY := Abs(movedy) / 4
Loop, %timesY%
{
    If (movedy > 0)
    {
        Click WheelDown
        movedy := movedy - 4
    }
    Else
    {
        Click WheelUp
        movedy := movedy + 4
    }
}   

MouseMove ox, oy
return

Comments

यदि आप राइट-क्लिक का उपयोग करते हैं, तो "XButton1" को "RButton" से बदलें।

— मैट वोल्क

यह मेरे लिए पूरी तरह से काम कर रहा है, लेकिन क्या स्क्रॉलिंग एक्शन को आसान बनाने का कोई तरीका है? मैंने लंबवत स्क्रॉलिंग के लिए SendMessage और WheelUp / Down दोनों तरीकों को आज़माया है, और वे दोनों एक 'जंप' करते हैं

— Askvictor

Answer 6

यह एक ऐसी शर्म की बात है कि Logitech ने स्क्रॉल व्हील सिमुलेशन लागू नहीं किया। उनका ड्राइवर ऐसा करने के लिए एक सुविधा का वादा करता है, लेकिन यह सभी अनुप्रयोगों के लिए काम नहीं करता है, जिससे यह काफी बेकार हो जाता है। वे एकदम सही माउस बनाने के करीब थे! : रों

मुझे जो एकमात्र समाधान मिला है , वह है इसके लिए एक ऑटोहॉट्की स्क्रिप्ट का उपयोग करना। इसके साथ आप छोटे बाएँ / दाएँ बटन को ऊपर और नीचे स्क्रॉल कर सकते हैं। यह पूरी तरह से काम करता है, लेकिन इसे कॉन्फ़िगर करने के लिए यह एक वास्तविक परेशानी है: आपको पहले ऑटोटेक मूल बातें सीखने की आवश्यकता होगी। यदि आप ऐसा करने का निर्णय लेते हैं, तो यहां मेरी ऑटोहॉटकी स्क्रिप्ट है। यह जेरो की मूल पटकथा का रूपांतरण है । एक सिंगल क्लिक सामान्य गति से स्क्रॉल करना शुरू कर देगा, लेकिन एक डबल या ट्रिपल क्लिक तेजी से स्क्रॉल करना शुरू कर देगा।

; This script remaps the two small buttons on a Logitech Trackman® Marble® Mouse
; to act as scroll up and scroll down

global lastXButton1ClickTime := 0
global nrSubsequentXButton1Clicks := 0

ScrollTheWheel(direction, scrollKey)
{
    now := A_TickCount
    timeSinceLastClick := now - lastXButton1ClickTime 
    lastXButton1ClickTime := now
    if (timeSinceLastClick < 300)
    {
        nrSubsequentXButton1Clicks := nrSubsequentXButton1Clicks + 1
    }
    else
    {
        nrSubsequentXButton1Clicks := 1
    }        

    sleepingFraction := 5

    if (nrSubsequentXButton1Clicks <= 1)
        scrollSpeed := 30
    if (nrSubsequentXButton1Clicks == 2)
        scrollSpeed := 15
    if (nrSubsequentXButton1Clicks >= 3)
        scrollSpeed := 5

    timeSlept := scrollSpeed

    loop 
    {
        if (direction == 1) ; Scroll down
        {
            static downKeyState
            if (scrollKey == 0) 
                GetKeyState, downKeyState, XButton1, P
            else
                GetKeyState, downKeyState, PgDn, P

            if downKeyState = U ; The key has been released, so break out of the loop
               break

            if (timeSlept >= scrollSpeed)
            {
                Send {WheelDown}
                timeSlept = 0                
            }
        }
        else ; Scroll up
        {
            static upKeyState
            if (scrollKey == 0)
                GetKeyState, upKeyState, XButton2, P
            else
                GetKeyState, upKeyState, PgUp, P

            if upKeyState = U ; The key has been released, so break out of the loop
               break            

            if (timeSlept >= scrollSpeed)
            {
                Send {WheelUp}
                timeSlept = 0                
            }
        }   

        Sleep, sleepingFraction
        timeSlept := timeSlept + sleepingFraction
    }    
}

XButton2::
    ScrollTheWheel(0, 0)
    return
XButton1::
    ScrollTheWheel(1, 0)
    return
!PgUp::
    ScrollTheWheel(0, 1)
    return
!PgDn::
    ScrollTheWheel(1, 1)
    return

Comments

मैं सीधे PageUp / PageUp कुंजी को दबा सकता हूँ ....

— lamwaiman1988

Answer 7

मुझे बस एक लॉजिटेक मार्बल माउस मिला और इसमें स्क्रॉलिंग की समस्या भी थी। इसलिए मैंने AutoHotKey पर यह स्क्रिप्ट बनाई है। बाएँ Xbutton स्क्रॉल करने में सक्षम करता है, जिसका अर्थ है कि नीचे की ओर आप गेंद के साथ लंबवत और क्षैतिज रूप से स्क्रॉल कर सकते हैं, और बाएँ और दाएँ बटन के साथ ब्राउज़र में आगे और पीछे जा सकते हैं। दाईं ओर एक्सबटन में मध्य बटन के समान कार्रवाई है।

विंडोज 7 पर Im।

#SINGLEINSTANCE FORCE  
GLOBAL status := "basic"
GLOBAL cnt_x
GLOBAL cnt_y

XButton2::MButton

$*XButton1::
    status := "scroll"
    cnt_x := 0
    cnt_y := 0
    MOUSEGETPOS, st_x, st_y
    SETTIMER, _scroll, 30
RETURN

$*XButton1 UP::
    status := "basic"
    SETTIMER, _scroll, OFF
RETURN

_scroll:
    MOUSEGETPOS, cur_x, cur_y
    MOUSEMOVE, st_x, st_y

IF(abs(cur_x-st_x) > abs(cur_y-st_y)) {
    cnt_x := cnt_x + (cur_x-st_x)
    ControlGetFocus, control, A 
    IF (cnt_x > 7) {
        cnt := floor(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 0, 0, %control%, A
        }
        cnt_x := cnt_x - 8*floor(cnt_x / 8)
    } ELSE IF (cnt_x < -7) {
        cnt := -ceil(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 1, 0, %control%, A
        }
        cnt_x := cnt_x - 8*ceil(cnt_x / 8)
    }
} ELSE {
    IF (cur_y >= st_y) {
        cnt_y := cnt_y + (cur_y-st_y)**1.2
    } ELSE {
        cnt_y := cnt_y -(st_y-cur_y)**1.2
    }   
    IF (cnt_y > 7) {
        cnt := floor(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelUp
        }
        cnt_y := cnt_y - 8*floor(cnt_y / 8)
    } ELSE IF (cnt_y < -7) {
        cnt := -ceil(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelDown
        }
        cnt_y := cnt_y - 8*ceil(cnt_y / 8)
    }
}   
RETURN

$*LButton::
    IF (status = "basic") {
        CLICK DOWN Left
    } ELSE IF (status = "scroll") {
        SEND {Browser_Back}
    }
RETURN

$*LButton UP::
    IF (status = "basic") {
        CLICK UP Left
    }
RETURN

$*RButton::
    IF (status = "basic") {
        CLICK DOWN Right
    } ELSE IF (status = "scroll") {
        SEND {Browser_Forward}
    }
RETURN

$*RButton UP::
    IF (status = "basic") {
        CLICK UP Right
    }
RETURN

Comments

मैंने कीबोर्ड पर कुंजी को छोड़ दिया था और उपयोग किया था। इसके अलावा, मैं पेज को ऊपर और नीचे ले जाने के लिए स्क्रॉल बार पर खाली जगह पर प्रेस करूँगा।

— lamwaiman1988

Answer 8

अपने OS के आधार पर, आप पॉइंटर को मूविंग के माध्यम से स्क्रॉल करने में सक्षम करने के लिए किसी एक बटन को कॉन्फ़िगर करने में सक्षम हो सकते हैं। उदाहरण के लिए निम्नलिखित स्क्रिप्ट मेरे माउस के बटन 10 (लॉजिटेक एमएक्स 310 का "शीर्ष मध्य" बटन) को सक्षम करता है:

#!/bin/sh
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 290 10
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 286 1
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 287 6 7 4 5

Answer 9

ऐसे मार्बल माउस (चूहे) होते हैं जिनमें स्क्रॉल व्हील शामिल होता है। अन्यथा, यह एक ऐप की तरह दिखता है या एक स्क्रॉल किए गए फ़ंक्शन को संलग्न करने के लिए एक बटन के उपयोग के साथ-साथ एक गैर-पहिए वाले माउस के लिए कुछ स्क्रिप्ट की आवश्यकता होगी (जो कि आप किसी अन्य उत्तर में टिप्पणी में उल्लेख किया गया है, स्वीकार्य समाधान के रूप में नहीं)।

तो "पहिया को क्यों मजबूत करें?" इस मामले में एक अच्छा कहावत है।

इन उदाहरणों में, तत्व शारीरिक रूप से स्थापित है और चुनने के लिए कई प्रकार हैं। नीचे दो उदाहरण और शैलियाँ दी गई हैं।

या कुछ इस तरह: Adesso

Answer 10

दो गैर पारंपरिक विकल्प

• ट्रैकबॉल के अलावा एक Apple मैजिक ट्रैकपैड का उपयोग करें। (यह मेरा वर्तमान समाधान है) http://www.apple.com/magictrackpad/

• एक leapmotion नियंत्रक खरीद और ट्रैकबॉल के अलावा इसका इस्तेमाल करते हैं। ऊपर और नीचे स्क्रॉल करने के लिए डिवाइस के सामने अपना हाथ लहरें। https://www.leapmotion.com/product

छवि क्रेडिट http://www5.pcmag.com/media/images/393268-leap-motion-controller.jpg

Answer 11

एक सरल (और एर्गोनोमिक हिम्मत मैं कहता हूं) समाधान अपने बाएं तरफ स्क्रॉल करने का कार्य करना है।

यह अपने बाएं हाथ से माउस का उपयोग करके / अपने बाएं किनारे पर एक अंतर्निहित स्क्रॉल व्हील के साथ कीबोर्ड का उपयोग करके प्राप्त किया जा सकता है / एक प्रोग्राम के साथ प्रोग्राम कीपैड की कुंजी पर स्क्रॉलिंग फ़ंक्शन असाइन करके Mkey ( http: //) www.seriosoft.org/en/index.php )।

मुझे क्यों लगता है कि यह अधिक एर्गोनोमिक है - क्योंकि यह दृष्टिकोण दोनों हाथों पर समान रूप से तनाव को वितरित करता है। (इसके बारे में अधिक जानकारी: http://capsoff.org/checklist )।

Answer 12

मैं विंडोज 7 पर हूं और बिना स्क्रॉल किए केंसिंग्टन ऑर्बिट ऑप्टिकल ट्रैकबॉल का उपयोग कर रहा हूं - यह दो-बटन ट्रैकबॉल है, बिना एएचके लिपियों और अधिकांश अन्य द्वारा बताए गए अनुप्रयोगों द्वारा आवश्यक एक्स-बटन के बिना।

हालाँकि, MouseImp मेरे लिए Windows7 पर काम कर रहा है। आईटी का विन्यास, लेकिन मैंने इसे right-click + rollस्क्रॉल करने की स्क्रीन प्राप्त करने के लिए स्थापित किया है । यह एक ड्रैग की तरह अधिक है, इसलिए पॉइंटर चलता है, और आपको एक समय में केवल एक ही स्क्रीन मिली है [अपडेट: स्क्रॉल दर कॉन्फ़िगर करने योग्य है, इसलिए यह "एक पृष्ठ" से अधिक हो सकता है]।

उसी समय, केंसिंग्टन के ट्रैकबॉलवर्क्स को मुझे पृष्ठ-डाउन स्क्रॉल पर देने के लिए कॉन्फ़िगर किया गया है left-click + right-click। दुर्भाग्य से यह एक समय में एक पृष्ठ (एक या दूसरे) को वापस स्क्रॉल नहीं कर सकता है।

यह एक उत्पाद प्लग नहीं है - यह सिर्फ मैंने इस मॉडल / ट्रैकबॉल के प्रकार के साथ काम करने के लिए पाया है ।

कैविएट: आप लगातार दाएं और बाएं क्लिक कर रहे हैं, और इससे भ्रम पैदा हो सकता है, और जब आप केवल स्क्रॉल करना बंद करना चाहते हैं तो लिंक / js-सक्रिय हो सकते हैं । ::: विलाप :::

Answer 13

मुझे बस केंसिंग्टन से एक वायरलेस वायरलेस ट्रैकबॉल मिला, यह बहुत अद्भुत है। आपके पास गेंद है, आपके पास प्रत्येक तरफ दोनों बटन हैं और आपके पास ट्रैकबॉल के बाहर एक तरह का सर्कल है जो पृष्ठ को ऊपर या नीचे स्क्रॉल करना संभव बनाता है। यह वास्तव में काम करता है, और मैं विंडोज और मैक ओएसएक्स पर उपयोग कर रहा हूं।

Answer 14

मैं वास्तव में कुछ समय पहले AutoHotkey का उपयोग करके इसके लिए कुछ बना था और लगा कि मैं इसे यहाँ भी साझा करूँगा: माउस व्हील एमुलेटर

यह माउस व्हील स्क्रॉलिंग का अनुकरण करता है ताकि बाईं और दाईं माउस बटन दबाए रखें।

आप एक ही समय में बाएँ और दाएँ माउस बटन पर क्लिक करके एक मध्य क्लिक का अनुकरण भी कर सकते हैं।

Answer 15

विंडोज 7 के लिए एक और समाधान जो इंटरनेट एक्सप्लोरर सहित सभी अनुप्रयोगों में स्क्रॉल करने की अनुमति देता है:

1. AutoHotKey स्थापित करें ।
2. इस स्क्रिप्ट को scroll.ahkडेस्कटॉप पर सहेजें ।
3. राइट-क्लिक करें scroll.ahk।
4. रन स्क्रिप्ट का चयन करें ।
5. यदि पुष्ट हो तो पुष्टि करें।

यह ट्रैकबॉल को स्थानांतरित करते समय छोटे दाएं बटन को लंबवत स्क्रॉल करेगा। छोटा लेफ्ट बटन बैक बटन है।

---

यदि एरिक एलमोर के कोड का लिंक गायब हो जाता है, तो यह है:

;;
;; Emulate_Scrolling_Middle_Button.ahk
;; Author: Erik Elmore <[e-mail]>
;; Version: 1.1 (Aug 16, 2005)
;;
;; Enables you to use any key with cursor movement
;; to emulate a scrolling middle button.  While
;; the TriggerKey is held down, you may move the
;; mouse cursor up and down to send scroll wheel
;; events.  If the cursor does not move by the
;; time the TriggerKey is released, then a middle
;; button click is generated.  I wrote this for my
;; 4-button Logitech Marble Mouse (trackball),  
;; which has no middle button or scroll wheel.
;;

;; Configuration

;#NoTrayIcon

;; Higher numbers mean less sensitivity
esmb_Threshold = 7

;; This key/Button activates scrolling
esmb_TriggerKey = XButton2

;; End of configuration

#Persistent
CoordMode, Mouse, Screen
Hotkey, %esmb_TriggerKey%, esmb_TriggerKeyDown
HotKey, %esmb_TriggerKey% Up, esmb_TriggerKeyUp
esmb_KeyDown = n
SetTimer, esmb_CheckForScrollEventAndExecute, 10
return

esmb_TriggerKeyDown:
  esmb_Moved = n
  esmb_FirstIteration = y
  esmb_KeyDown = y
  MouseGetPos, esmb_OrigX, esmb_OrigY
  esmb_AccumulatedDistance = 0
return

esmb_TriggerKeyUp:
  esmb_KeyDown = n
  ;; Send a middle-click if we did not scroll
  if esmb_Moved = n
    MouseClick, Middle
return

esmb_CheckForScrollEventAndExecute:
  if esmb_KeyDown = n
    return

  MouseGetPos,, esmb_NewY
  esmb_Distance := esmb_NewY - esmb_OrigY
  if esmb_Distance
    esmb_Moved = y

  esmb_AccumulatedDistance := (esmb_AccumulatedDistance + esmb_Distance)
  esmb_Ticks := (esmb_AccumulatedDistance // esmb_Threshold) ; floor divide
  esmb_AccumulatedDistance := (esmb_AccumulatedDistance - (esmb_Ticks * esmb_Threshold))
  esmb_WheelDirection := "WheelDown"
  if (esmb_Ticks < 0) {
    esmb_WheelDirection := "WheelUp"
    esmb_Ticks := (-1 * esmb_Ticks)
  }

  ;; Do not send clicks on the first iteration
  if esmb_FirstIteration = y
    esmb_FirstIteration = n
  else {
    Loop % esmb_Ticks {
      MouseClick, %esmb_WheelDirection%
    }
  }

  MouseMove,esmb_OrigX,esmb_OrigY,0
return

Comments

इसके लिए शुक्रिया! मैं इस स्क्रिप्ट के लिए दो छोटे संशोधनों बनाया: बदल XButton2करने के लिए XButton1के रूप में मैं बाएं बटन को पसंद करते हैं, और एक जोड़ा *से पहले %esmb_TriggerKey%में दो पंक्तियों पर #Persistentतो वे शुरू करते हैं, खंड Hotkey, *%esmb_TriggerKey%। उत्तरार्द्ध यह संशोधक कुंजियों के साथ निर्दोष रूप से काम करता है, इसलिए जैसे Ctrl + स्क्रॉल काम करता है।

— सिनकोडेनाडा

Answer 16

एक और Trackman संगमरमर उपयोगकर्ता यहाँ।

मैं स्क्रॉल एमुलेशन के लिए एक्स-माउस बटन कंट्रोल का उपयोग कर रहा हूं । यह सुविधा कार्यान्वयन वहाँ (अभी तक?) सही नहीं है, लेकिन यह अपने स्वयं के SetPoint ™ सॉफ़्टवेयर में Logitech के कार्यान्वयन की तुलना में बहुत अधिक प्रयोग करने योग्य है।

मैं किसी को भी XMBC की सलाह देता हूं, जो AutoHotKey के साथ खिलवाड़ नहीं करना चाहता है और वह कुछ खोज रहा है जो सिर्फ काम करता है।