Internet Explorer को कमांड लाइन से डिफ़ॉल्ट ब्राउज़र के रूप में सेट करें

Question

क्या कमांड लाइन से लॉन्च करने के लिए डिफ़ॉल्ट ब्राउज़र के रूप में इंटरनेट एक्सप्लोरर को सेट करना संभव है?

मेरे पास एक वेब एप्लिकेशन है जो केवल इंटरनेट एक्सप्लोरर के तहत चलता है, लेकिन अगर ऐसा होता है कि फ़ायरफ़ॉक्स डिफ़ॉल्ट ब्राउज़र है, तो यह काम नहीं करता है। उपयोगकर्ता एक डोमेन वातावरण में हैं और भले ही मैं इस तरह से हमारे एप्लिकेशन को बैच से लॉन्च करने का प्रयास करता हूं:

start "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

जब तक मैं ब्राउज़र को मैन्युअल रूप से नहीं बदलूंगा, तब तक एप्लिकेशन शुरू नहीं होता है।

Comments

मुझे लगता है कि "एप्लिकेशन को ठीक करें ताकि यह वास्तव में हर सभ्य ब्राउज़र के तहत तोड़ने के बजाय उचित HTML का सम्मान करे" एक विकल्प नहीं है?

— 19

@ बहादुर कुछ ऐसे क्षेत्र हैं जहाँ समस्याओं को सुविधाओं के रूप में देखा जाता है ..

— जोसेफ हैनसन

किसी एक ब्राउज़र के लिए टूटे हुए व्यवहार पर निर्भर होना, या कम से कम कभी नहीं होना चाहिए, एक विशेषता।

— शादुर

@ techie007 मैंने इसे स्वयं परीक्षण नहीं किया लेकिन आप यहां और यहां देख सकते हैं ।

— एविर्क

IE डिफ़ॉल्ट ब्राउज़र बनाना एक बुरा विचार है।

— जेट

Answer 1

यह कमांड IE को डिफ़ॉल्ट ब्राउजर के रूप में सेट करेगा:

shmgrate.exe OcinstallreinstallIE

इस नीति को डिफ़ॉल्ट ब्राउज़र का निर्धारण करने वाले लोगों को रोकना चाहिए।

Comments

समस्या नहीं। इसे आपके लिए तैयार करने में खुशी हुई।

— 22

+1 पॉलिसी के लिए भी।

— एमडीटी गाय

Windows Vista में पंजीकरण योजना को ओवरहाल किया गया था। यह shmgrateटूल केवल Windows 2000 / XP और Windows Server 2003 में उपलब्ध है। साथ ही, यह नीति इंटरनेट एक्सप्लोरर को यह जाँचने से रोकेगी कि क्या यह डिफ़ॉल्ट ब्राउज़र के रूप में सेट है।

— and31415

Answer 2

आप यह कोशिश कर सकते हैं, यह काम करेगा

start "" "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

आपके आदेश में त्रुटि यह थी कि startपहले उद्धृत स्ट्रिंग को आवेदन का शीर्षक होने की उम्मीद है, जो इस मामले में आप खाली छोड़ सकते हैं।

iexplorer.exeसिस्टम के डिफ़ॉल्ट वेब ब्राउज़र के रूप में स्थापित करने के लिए , आप उपयोग कर सकते हैं assocऔर ftypeकमांड कर सकते हैं , जो एक्सटेंशन को फाइल प्रकारों के साथ जोड़ते हैं, और निष्पादन योग्य फाइलों के साथ फाइल प्रकारों की तरह, जैसे:

assoc .html=htmlfile
ftype htmlfile="C:\Program Files\Internet Explorer\iexplore.exe" %1

%1 यहाँ तर्क है - वह URL या फ़ाइल है जिसे आप प्रोग्राम में इनपुट के रूप में भेज सकते हैं

Comments

(बस) IE द्वारा खोले जाने वाले HTML फ़ाइल प्रकार को संबद्ध करना OS के डिफ़ॉल्ट ब्राउज़र के रूप में इसे सेट करने के समान नहीं है।

— Ƭᴇc atιᴇ007

iexplore.exe, नहीं iexplorer.exe

— InterLinked

Answer 3

विंडोज विस्टा और बाद में, IE 7+

निम्न बैच स्क्रिप्ट डिफ़ॉल्ट प्रोग्राम कंट्रोल पैनल एप्लेट से इस प्रोग्राम को डिफ़ॉल्ट के रूप में सेट करने पर क्लिक करती है। विस्टा / 7 और IE 7 / IE 11 के साथ परीक्षण किया गया।

@echo off
setlocal enabledelayedexpansion

REM -- check XHTML support (IE 9+)
set xhtml=0
for /f %%G in ('"reg query "HKCR\IE.AssocFile.XHT" /ve 2>&1 | findstr /c:".XHT" "') do set xhtml=1

REM -- reset file extensions
set exts=HTM,HTML
if %xhtml% == 1 (set exts=%exts%,XHT,XHTML)

for %%G in (%exts%) do (
set ext=%%G
set ext=!ext:~0,3!
reg add "HKCU\Software\Classes\.%%G" /ve /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)

set exts=%exts%,MHT,MHTML,URL
set acl=%temp%\acl_%random%%random%.txt

for %%G in (%exts%) do (
set key=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%G\UserChoice
echo !key! [1 7 17]>"%acl%"
regini "%acl%" >nul
set ext=%%G
set ext=!ext:~0,3!
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)
del "%acl%" 2>nul

REM -- reset MIME associations
for %%G in (message/rfc822,text/html) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\MIMEAssociations\%%G\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%G" /f >nul
)

REM -- reset URL protocols
for %%A in (FTP,HTTP,HTTPS) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\%%A\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%A" /f >nul
for %%B in (DefaultIcon,shell) do (
set key=HKCU\Software\Classes\%%A
reg delete "!key!\%%B" /f >nul 2>&1
reg copy "HKCR\IE.%%A\%%B" "!key!\%%B" /s /f >nul
reg add "!key!" /v "EditFlags" /t REG_DWORD /d 2 /f >nul
reg add "!key!" /v "URL Protocol" /t REG_SZ /d "" /f >nul
))

REM -- reset the start menu Internet link (Vista and earlier)
reg add "HKCU\Software\Clients\StartMenuInternet" /ve /t REG_SZ /d "IEXPLORE.EXE" /f

REM -- reset cached icons
if %xhtml% == 1 (
ie4uinit -cleariconcache
) else (
taskkill /im explorer.exe /f >nul
start explorer
)

pause
exit /b

टिप्पणियों

कोई भी वेब ब्राउज़र एप्लिकेशन स्टार्ट मेन्यू पर इंटरनेट क्लाइंट के रूप में प्रदर्शित होने के लिए रजिस्टर कर सकता है। यह दृश्यता, किसी एप्लिकेशन की फ़ाइल और प्रोटोकॉल प्रकारों के लिए उचित पंजीकरण के साथ मिलकर , एप्लिकेशन डिफ़ॉल्ट ब्राउज़र का दर्जा देती है। डिफ़ॉल्ट वेब ब्राउज़र का उपयोग सिस्टम में कहीं से भी मनमाना URL लॉन्च करने के लिए किया जाता है।

नोट मौजूदा [प्रारंभ मेनू लिंक] पंजीकरण को विंडोज 7 और बाद में अनदेखा किया गया है। इस पंजीकरण को विंडोज 7 के रूप में चित्रित किया गया है।

_{स्रोत: विंडोज स्टार्ट मेनू के साथ इंटरनेट ब्राउज़र या ईमेल क्लाइंट को कैसे पंजीकृत करें}

­­

फ़ाइल और प्रोटोकॉल संघों के लिए पदानुक्रमित रजिस्ट्री संरचना मशीन-स्तर की चूक पर प्रति-उपयोगकर्ता डिफॉल्ट को पूर्वता देती है।

_{स्रोत: डिफ़ॉल्ट कार्यक्रम}

Comments

विंडोज 8.1 पर मेरे लिए IE को डिफ़ॉल्ट के रूप में रीसेट नहीं करता है। :(

— cʜιᴇ007

@ Techie007 कंट्रोल पैनल में डिफ़ॉल्ट प्रोग्राम सेटिंग्स के बारे में क्या? क्या वहां कुछ बदला? क्या आपको बैच स्क्रिप्ट निष्पादित करते समय कोई त्रुटि मिली?

— and31415

विंडोज 7 (प्रो, 64-बिट) के तहत काम करने लगता है, लेकिन विंडोज 8 (प्रो 32-बिट) के तहत यह सिर्फ (एक ही / सामान्य) आउटपुट दिखाता है "ऑपरेशन सफलतापूर्वक पूरा हुआ।" -- "जारी रखने के लिए कोई भी कुंजी दबाएँ । । ।" लेकिन वास्तव में IE को डिफ़ॉल्ट के रूप में सेट नहीं करता है।

— 14c atιᴇ007

मेरी अन्य विंडोज 8 मशीन के तहत, इसने थोड़ा बेहतर काम किया। मैं इसे चलाता हूं, और फिर अगली बार जब मैं एक http लिंक खोलता हूं, तो यह मुझसे पूछता है कि मैं किस ब्राउज़र का उपयोग करना चाहता हूं। यह मेरे द्वारा काफी अच्छा है, क्योंकि अन्य बिट्स और टुकड़े सभी (AFAICT) लगता है कि IE को ऐसा करने के बाद डिफ़ॉल्ट के रूप में पंजीकृत किया गया है। तो मेरा इनाम है। :)

— ᴇc --ιᴇ007

@ Techie007 मैं पूरी तरह से भूल गया कि Microsoft ने नियमों को बदल दिया है और अब उन रजिस्ट्री कुंजियों में से अधिकांश के लिए एक विरोधी छेड़छाड़ संरक्षण है। यदि आप इसका परीक्षण करने के लिए तैयार हैं, तो मैं आपको स्क्रिप्ट का एक अद्यतन संस्करण भेज सकता हूं, जो विंडोज़ 8 में एसोसिएशन को बाद में क्लियर कर देगा ताकि अगली बार जब आप एक लिंक या एक html फ़ाइल खोलें, तो विंडोज़ आपको यह चुनने देगा ब्राउज़र का उपयोग करने के लिए। यह संभवत: सबसे अच्छा है जिसे आप स्वचालित तरीके से प्राप्त कर सकते हैं क्योंकि (कुछ) उपयोगकर्ता इंटरैक्शन को वैसे भी आवश्यक होगा।

— ३१४१५

Answer 4

आप एक बैट फ़ाइल में दो लाइनों के नीचे जोड़ सकते हैं

reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /f /v "Check_Associations" /d "yes" /t REG_SZ

reg add "HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\http\UserChoice" /f /v "ProgId" /d "IE.HTTP" /t REG_SZ

बैट चलाने के बाद, रिबूट / लॉग ऑफ करें और लॉग ऑन करें क्योंकि दो कमांड लाइन रजिस्ट्री मान बदलने के लिए हैं।

आदित्य विवरण यहाँ पाया जा सकता है

(फिक्स्ड) - इंटरनेट एक्सप्लोरर को डिफ़ॉल्ट ब्राउज़र के रूप में सेट करें! http://www.windowstechinfo.com/2016/03/fixed-cant-set-internet-explorer-as-the-default-browser.html

Answer 5

मुझे कमांड लाइन से डिफ़ॉल्ट ब्राउज़र को सेट करने के बारे में नहीं पता है, लेकिन आप इसे ग्रुप पॉलिसी के माध्यम से डोमेन के लिए सेट और लागू कर सकते हैं।

यहाँ कुछ आरंभ करने के लिए है:

http://technet.microsoft.com/en-us/library/hh147307%28WS.10%29.aspx

Answer 6

बस startकाम करने के लिए कमांड या बैच फ़ाइल प्राप्त करने के लिए ड्रॉप करें ।

"C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

Comments

हम (अच्छी तरह से मैं वैसे भी हूं ) कमांड लाइन से डिफ़ॉल्ट ब्राउज़र सेट करने के समाधान की तलाश कर रहे हैं, न कि केवल ओपी में उदाहरण समस्या / कारण को हल करने के लिए।

— 14c atιᴇ007

Answer 7

विंडोज 8 (IE 10+) के लिए यह आसान VBS स्क्रिप्ट है:

Dim URL 
Dim IE 
Set IE = CreateObject("internetexplorer.application")
URL = "res://ieframe.dll/defaultbrowser.htm" 
IE.Visible = True
IE.Navigate URL


 Do While IE.Busy
    WScript.Sleep 100
 Loop

IE.Document.getElementById("changeDefaultButton").Click

यह IE को डिफ़ॉल्ट के रूप में बदलने के लिए IE पेज शुरू करेगा और स्वीकार करने के लिए बटन पर क्लिक अनुकरण करेगा।