विंडोज़ कमांड लाइन से डिस्प्ले रिज़ॉल्यूशन प्राप्त करें

19

मैंने कमांड लाइन से रिज़ॉल्यूशन बदलने के लिए कार्यक्रमों के बारे में कई सुझाव देखे हैं। हालांकि मैं सिर्फ इसे प्रदर्शित करना चाहता हूं, इसे बदलना नहीं।

लिनक्स पर मैं इस जानकारी का उपयोग कर सकता हूं xrandrया कर सकता हूं xdpyinfo, इसलिए मैं ऐसा कुछ खोज रहा हूं।

मुझे एक साइबर शेल के भीतर काम करने के लिए भी इसकी आवश्यकता है।

— Zitrax
स्रोत

2

नोट: अगर कोई दिलचस्पी रखता है तो एक PowerShell संस्करण भी उपलब्ध है।

— स्टैकऑवरफ्लो में उन्होंने मल्टीमिंटन की

20

इसे इस्तेमाल करे:

wmic desktopmonitor get screenheight, screenwidth

साइगविन के भीतर से:

cmd /c wmic desktopmonitor get screenheight, screenwidth

मुझे यकीन नहीं है कि आउटपुट का उपयोग करने के लिए किन चालों का उपयोग करना है। शायद एक अस्थायी पाठ फ़ाइल?

— paradroid
स्रोत

हाँ धन्यवाद यह cmd.exe से काम करता है। हालाँकि मैं यह उल्लेख करना भूल गया कि मुझे एक साइबर शेल के अंदर काम करने के लिए इसकी आवश्यकता है और विकी वहाँ काम नहीं करता है।

— Zitrax

1

@Zitrax: अब आप मुझे बताएं।

— विरोधाभास

एक बार फिर धन्यवाद। हालांकि यह रद्दीकोटॉप (या sggv में ssh) के साथ जुड़ने पर काम नहीं करता था। उन सभी स्थितियों में भी इसे करने के लिए बहुत अच्छा होगा।

— Zitrax

2

Win8.1 या win10 पर काम नहीं करता है। यह स्क्रीनशीट और पटकथा दोनों के लिए खाली परिणाम देता है।

— डेविड बालूसिक

1

@paradroid यह काम नहीं करता है, जैसा कि अन्य उत्तर

— डेविड बालैसिक

10

Dxdiag के साथ हालांकि यह सबसे तेज़ तरीका नहीं है:

@echo off

del ~.txt /q /f >nul 2>nul
start "" /w dxdiag /t ~
setlocal enableDelayedExpansion
set currmon=1 
for /f "tokens=2 delims=:" %%a in ('find "Current Mode:" ~.txt') do (
    echo Monitor !currmon! : %%a
    set /a currmon=currmon+1

)
endlocal
del ~.txt /q /f >nul 2>nul

यह सभी मॉनिटरों के प्रस्तावों को प्रिंट करेगा।

संपादित करें । स्वीकृत उत्तर WMIC का उपयोग करता है। ( wmic desktopmonitor get screenheight, screenwidth /format:value) .यह विंडोज 8 / 8.1 / 10 पर काम नहीं करेगा। नए विंडोज़ संस्करणों के लिए इसका उपयोग किया जा सकता है:

wmic path Win32_VideoController get VideoModeDescription,CurrentVerticalResolution,CurrentHorizontalResolution /format:value

एक स्क्रिप्ट जो विंडोज़ संस्करण की जांच करती है और फिर विकी के साथ रिज़ॉल्यूशन प्राप्त करती है:

@echo off

setlocal
for /f "tokens=4,5 delims=. " %%a in ('ver') do set "version=%%a%%b"


if version lss 62 (
    ::set "wmic_query=wmic desktopmonitor get screenheight, screenwidth /format:value"
    for /f "tokens=* delims=" %%@ in ('wmic desktopmonitor get screenwidth /format:value') do (
        for /f "tokens=2 delims==" %%# in ("%%@") do set "x=%%#"
    )
    for /f "tokens=* delims=" %%@ in ('wmic desktopmonitor get screenheight /format:value') do (
        for /f "tokens=2 delims==" %%# in ("%%@") do set "y=%%#"
    )

) else (
    ::wmic path Win32_VideoController get VideoModeDescription,CurrentVerticalResolution,CurrentHorizontalResolution /format:value
    for /f "tokens=* delims=" %%@ in ('wmic path Win32_VideoController get CurrentHorizontalResolution  /format:value') do (
        for /f "tokens=2 delims==" %%# in ("%%@") do set "x=%%#"
    )
    for /f "tokens=* delims=" %%@ in ('wmic path Win32_VideoController get CurrentVerticalResolution /format:value') do (
        for /f "tokens=2 delims==" %%# in ("%%@") do set "y=%%#"
    )

)

echo Resolution %x%x%y%

endlocal

— npocmaka
स्रोत

2

आपको धन्यवाद @paradroid :) WMIC के साथ, मैंने बैच स्क्रिप्ट को रिमोट डेस्कटॉप पर लिखा है, न कि पूर्ण स्क्रीन पर, लेकिन फिर भी सुविधाजनक है। ^ _ ^

@echo off
:p00
setlocal
if "%1"=="" goto :q01
set i01=wmic desktopmonitor
set i01=%i01% where availability^=3
set i01=%i01% get screenHeight,screenWidth
set o01=%temp%\ScrRes.txt
%i01%>"%o01%"
for /f "delims= skip=1" %%o in ('type %o01%') do call :p01 %1 %%o
goto :p99

:p01
set srvnm=%1
set /a tl=%2-40
set /a ll=%3-80
start mstsc /admin /w:%ll% /h:%tl% /v:%srvnm%
goto :eof

:q01
echo.
echo ^>^> Syntax: %0 MachineHostname [enter]
echo.

:p99
if exist "%o01%" del "%o01%" /f /q
echo.
echo ^>^> Sincerely Thank You For Using..
endlocal
goto :eof

बेझिझक तलाश करें। बढ़ाने के लिए उत्साहित महसूस करते हैं। (Y)

— रक कहर
स्रोत

1

MultiMonitorTool का उपयोग करें :

MultiMonitorTool.exe /scomma "%TEMP%\MultiMonitorTool.csv"

तब फ़ाइल "% TEMP% \ MultiMonitorTool.csv" पार्स करें (मैं अभी भी इस पर काम कर रहा हूं)

— eadmaster
स्रोत

1

पुराने जवाब में अब काम नहीं लगता (win7 64bit); मैंने उस तरह से हल किया

FOR /f "tokens=1,2" %%a IN ('"wmic desktopmonitor get screenheight, screenwidth"') DO (
    SET /a ScreenHeight=%%a
    SET /a ScreenWidth=%%b
)
echo %ScreenHeight%
echo %ScreenWidth%

— Lesto
स्रोत

1

मल्टी मॉनिटर सेटअप के लिए बस कमांड को विभाजित करें:

setlocal ENABLEDELAYEDEXPANSION
setlocal ENABLEEXTENSIONS
set wmicheight="wmic desktopmonitor get screenheight /format:value"
set wmicwidth="wmic desktopmonitor get screenwidth /format:value"
:height
for /f "tokens=2 delims==" %%a in ('%wmicheight%') do (
    If %%a LEQ 1 (
        rem skip if height is not bigger than 1
    ) Else (
        rem take the first height value larger than 1
        rem then skip to width
        Set /a "height=%%a"
        goto :width
    )
)
:width
for /f "tokens=2 delims==" %%a in ('%wmicwidth%') do (
    If %%a LEQ 1 (
        rem skip if width is not bigger than 1
    ) Else (
        rem add width found to get total width of all screens
        Set /a "width=width+%%a"
    )
)
echo %width% x %height%

— रोब मूर
स्रोत

कृपया कोड ब्लॉक का उपयोग करें। आप यह जानने के लिए लंबे समय से यहां हैं कि मार्कडाउन कैसे काम करता है और इसे कैसे पठनीय बनाया जा सकता है।

— करण

1

सबसे सरल तरीका:

@echo off
::By SachaDee 2018

FOR /F "skip=2 delims=" %%a IN ('wmic path Win32_VideoController get VideoModeDescription^,CurrentHorizontalResolution^,CurrentVerticalResolution /format:Value ^| findstr ":"') do set %%a

echo Width =^> %CurrentHorizontalResolution%
echo Height =^> %CurrentVerticalResolution%
echo Description =^> %VideoModeDescription%

— SachaDee
स्रोत

क्या आप यहाँ पर क्या हो रहा है में थोड़ा और स्पष्टीकरण दे सकते हैं? मैं समझता हूं कि /format:Valueरिटर्न का परिणाम एक var = मान रूप में होता है जो तब setकमांड में उपयोग किया जाता है । यदि आप सिर्फ एक मूल्य चाहते हैं, तो क्या लूप के बिना ऐसा करने का कोई तरीका है?

— काइल डेलानी

यदि आप केवल आवश्यक मान प्रदर्शित करना चाहते हैं, तो आप यह सुनिश्चित कर सकते हैं कि केवल wmicमान प्रदर्शित करने के लिए सही पैरामीटर के साथ एक क्वेरी अकेले चलाएं । forपाश करने के लिए यहाँ प्रयोग किया जाता है setकोड में एक बाद में उपयोग के लिए मान। batबाहरी कमांड ( wmic.exeइस मामले में) का उपयोग करने का एकमात्र तरीका यही है ।

— सच्ची

आप लूप के बिना परिणाम के setसाथ उपयोग नहीं कर सकते हैं wmic?

— काइल डेलाने

नहीं, यह संभव नहीं है!

— सच्ची

0

यह मेरी कोशिश है:

@echo off
Mode 45,3 & color 0A
Title Dislpay Resolution by Hackoo 2018
Set "WMIC_Command=wmic path Win32_VideoController get VideoModeDescription^,CurrentHorizontalResolution^,CurrentVerticalResolution /format:Value"
Set "H=CurrentHorizontalResolution"
Set "V=CurrentVerticalResolution"
Call :GetResolution %H% HorizontalResolution
Call :GetResolution %V% VerticalResolution
echo(
echo     Screen Resolution is : %HorizontalResolution% x %VerticalResolution%
pause>nul & Exit
::****************************************************
:GetResolution 
FOR /F "tokens=2 delims==" %%I IN (
  '%WMIC_Command% ^| find /I "%~1" 2^>^nul'
) DO FOR /F "delims=" %%A IN ("%%I") DO SET "%2=%%A"
Exit /b
::****************************************************

— Hackoo
स्रोत