मैं मैक ओएस पर एक पीसी कीबोर्ड का उपयोग कर रहा हूं। मैं वॉल्यूम को नियंत्रित करने के लिए मेनूबार का उपयोग कर सकता हूं, लेकिन क्या कोई कीबोर्ड शॉर्टकट हैं जो मैं सिस्टम वॉल्यूम को बदलने के लिए उपयोग कर सकता हूं?
या शायद एक साधारण स्क्रिप्ट या समाधान मैं कीबोर्ड का उपयोग करके वॉल्यूम सेट करने में सक्षम होने के लिए स्थापित कर सकता हूं।
जवाबों:
आप Sizzling Keys का प्रो संस्करण खरीद सकते हैं । यह वह है preference paneजो आपको सिस्टम वॉल्यूम को संशोधित करने के लिए कई अन्य चीजों के बीच एक कस्टम कीबोर्ड शॉर्टकट को परिभाषित करने की अनुमति देता है।
वैकल्पिक रूप से, आप AppleScript का उपयोग करके सिस्टम वॉल्यूम को संशोधित कर सकते हैं।
AppleScript संपादक खोलें और दर्ज करें
set volume output volume 100
वॉल्यूम 0 से 100 के पैमाने पर है। आप या तो एक निरपेक्ष मान सेट कर सकते हैं (उदाहरण के लिए पूर्ण मात्रा के लिए 100), या स्क्रिप्ट बढ़ाएँ / घटाएँ, जैसे कि निम्नलिखित:
set vol to output volume of (get volume settings)
if vol > 90 then # 100 max
set volume output volume 100
else
set volume output volume (vol + 10)
end if
वॉल्यूम डाउन के लिए:
set vol to output volume of (get volume settings)
if vol < 10 then # 0 is min
set volume output volume 0
else
set volume output volume (vol - 10)
end if
यदि आप उस प्रतिक्रिया ध्वनि को दोहराना चाहते हैं जो आम तौर पर तब होती है जब आप वॉल्यूम बदलते हैं, तो आप स्क्रिप्ट में निम्नलिखित जोड़ सकते हैं:
do shell script "afplay /System/Library/Sounds/Pop.aiff"
आप स्क्रिप्ट को इन अनुप्रयोगों के रूप में सहेज सकते हैं, या उन्हें स्वचालित-सेवा के रूप में ऑटोमेटर का उपयोग करके सेवा मेनू में एकीकृत कर सकते हैं । आप में सेवाओं के लिए कीबोर्ड शॉर्टकट को परिभाषित कर सकते सिस्टम प्राथमिकताएं »कीबोर्ड» कीबोर्ड शॉर्टकट »सेवाएं
Full Keyboard Accessकरते हैंAll controls
मैंने AppleScript सेवाओं और निर्देशों का एक सेट तैयार किया है जो आपको सिस्टम और आईट्यून्स की मात्रा को नियंत्रित करने देता है, साथ ही साथ शेर में किसी भी कीबोर्ड पर प्ले / पॉज़ और अगला / प्रचलित करता है।
http://gskinner.com/blog/archives/2011/10/media-keys-in-osx-for-any-keyboard.html
पुराना धागा लेकिन जिस तरह से मैंने इसे हल किया वह अन्य उत्तरों के आधार पर एकल पंक्ति एप्सस्क्रिप्ट के माध्यम से है
मात्रा में 10% की वृद्धि
osascript -e 'set volume output volume ((output volume of (get volume settings)) + 10)'
मात्रा में 10% की कमी
osascript -e 'set volume output volume ((output volume of (get volume settings)) - 10)'
वास्तव में अल्फ्रेड एप्लिकेशन के साथ इसका उपयोग करने के बारे में एक ब्लॉग पोस्ट लिखना समाप्त हो गया: http://arif.im/system-volume-control-use-alfred/
पीसी कीबोर्ड पर एफ 1 से एफ 12 कीज को एक ही काम करना चाहिए। मुझे लगता है आप के लिए "विंडोज" कुंजी प्रतिस्थापन के साथ कोई मुद्दों पड़ा है ⌘ कुंजी। यदि F1 से F12 कुंजियाँ काम नहीं करती हैं, तो सिस्टम प्राथमिकताएँ, कीबोर्ड और माउस, कीबोर्ड पर जाएँ और वहाँ से चुनाव करें, चाहे F कुंजियों का उपयोग सीधे या fn कुंजी क्वालीफायर के साथ करें। सादर पॉल
यहाँ वॉल्यूम अप, डाउन और म्यूट के लिए शॉर्टकट के लिए मेरा पूरा समाधान है। मैं इन लिपियों ( http://www.macupdate.com/app/mac/14352/spark ) के लिए मुख्य संयोजनों को बांधने के लिए स्पार्क एप्लिकेशन का उपयोग करता हूं । स्क्रिप्ट वर्तमान म्यूट स्थिति की जांच करते हैं और इसे संभालते हैं, ताकि अजीब समस्याओं से बचा जा सके, अगर आप इसे ठीक से नियंत्रित नहीं करते हैं।
ध्वनि तेज:
set vol to output muted of (get volume settings)
if (vol = true) then
set volume without output muted
end if
set vol to output volume of (get volume settings)
if vol > 95 then
set volume output volume 100
else
set volume output volume (vol + 5)
end if
do shell script "afplay /System/Library/Sounds/Pop.aiff"
आवाज निचे:
set vol to output muted of (get volume settings)
if (vol = true) then
error number -128
else
set vol to output volume of (get volume settings)
if vol < 5 then # 0 is min
set volume with output muted
else
set volume output volume (vol - 5)
end if
do shell script "afplay /System/Library/Sounds/Pop.aiff"
end if
म्यूट / अनम्यूट:
set vol to output muted of (get volume settings)
if (vol = true) then
set volume without output muted
else
set volume with output muted
end if