Send to मेनू में SendTo फोल्डर की सभी प्रविष्टियाँ नहीं दिखती हैं

मेनू पर भेजने का स्क्रीनशॉट

जैसा कि ऊपर दिए गए स्क्रीनशॉट में है, मैं सभी डिफ़ॉल्ट प्रविष्टियों के साथ-साथ स्वयं द्वारा जोड़े गए मेनू फ़ोल्डर में भेज रहा हूं जिसे मैंने उपयोग किया था shell:SendTo।

लेकिन सभी प्रविष्टियाँ सेंड टू मेन्यू में दिखाई नहीं दे रही हैं।

इसे कैसे ठीक करें?

windows-10 send-to

— achintha
स्रोत

Winhelponline.com/xp/sendtofix.htm के अनुसार , यह कुछ रजिस्ट्री प्रविष्टियों के साथ एक समस्या हो सकती है जो SendTo कार्यक्षमता का प्रबंधन करती हैं। उनके पास एक स्क्रिप्ट है जो इसे ठीक कर सकती है। (यह विंडोज़ एक्सपी के लिए है, लेकिन यह अभी भी लागू हो सकता है।)

— डग डेडेन

मैंने वह चेक किया है, लेकिन यह एक संदेश दिखाता है जब मैंने स्क्रिप्ट निष्पादित की थी कि यह केवल 7 और नीचे की खिड़कियों में काम करता है: /

— achintha

वह कोड जो आपको वह संदेश देता है, यदि OS XP, Vista, या 7 है, और तदनुसार एक निर्देशिका संरचना का चयन कर रहा है। (मुझे संदेह है कि जब उन्होंने इसे लिखा था, तो विंडो 8 और 10 अभी तक मौजूद नहीं थे।) आप स्क्रिप्ट को संशोधित कर सकते हैं कि यह विंडोज 10 को विंडोज 7 के समान माना जाए - प्रश्न में निर्देशिका 10 के लिए समान है जैसा कि इसके लिए है 7.

— डग डेडेन

आह, यह तय है, मैं स्क्रिप्ट को बदल दिया है और निष्पादित किया गया है। सबकुछ वापस पटरी पर। डौग धन्यवाद :)

— achintha

यह तो बहुत अच्छी खबर है। मैं इसे उत्तर के रूप में लिखूंगा।

— डग डेडेन

Https://winhelponline.com/xp/sendtofix.htm के अनुसार , यह कुछ रजिस्ट्री प्रविष्टियों के साथ एक समस्या हो सकती है जो SendTo कार्यक्षमता का प्रबंधन करती हैं। उनके पास एक स्क्रिप्ट है जिसे उसे ठीक करना चाहिए।

यह मूल रूप से विंडोज एक्सपी, विस्टा और 7 के लिए था, इसलिए मैंने इसे विंडोज 10 के लिए काम करने के लिए थोड़ा बदलाव किया है।

निम्न स्क्रिप्ट को एक फ़ाइल fixsendto.vbs पर सहेजें , और कमांड प्रॉम्प्ट का उपयोग करके इसे निष्पादित करें wscript.exe "C:\Scripts\fixsendto.vbs"। तदनुसार फ़ाइल पथ बदलें।

'-----------------------------------------------------------------
'Compatibility : Windows XP, Windows Vista and Windows 7 (added 8 and 10)
'Author        : Ramesh Srinivasan - Microsoft MVP (Windows Shell)
'Created on    : February 19, 2005
'Revised on    : November 01, 2010
'Description   : Fixes the Send To menu (missing all the shortcuts)
'Homepage      : http://windowsxp.mvps.org
'More Info     : http://windowsxp.mvps.org/sendtofix.htm
'Requirement   : Needs Administrative privileges
'-----------------------------------------------------------------

Set WshShell = CreateObject("WScript.Shell")
strComputer = "."
Set objWMIService = GetObject _
    ("winmgmts:\\" & strComputer & "\root\cimv2")

'Determine OS version
Set colOperatingSystems = objWMIService.ExecQuery _
    ("Select * from Win32_OperatingSystem")
For Each objOperatingSystem in colOperatingSystems
    if instr(objOperatingSystem.Caption,"Vista") Or instr(objOperatingSystem.Caption,"Windows 7") Or instr(objOperatingSystem.Caption,"Windows 8") Or instr(objOperatingSystem.Caption,"Windows 10") then
        strSendTo = "%USERPROFILE%\AppData\Roaming\Microsoft\Windows\SendTo"
    elseif instr(objOperatingSystem.Caption,"XP") Then  
        strSendTo = "%USERPROFILE%\SendTo"
    else
        MsgBox "This script runs in Windows 10/8/7/Vista/XP systems only"
        wscript.Quit
    end if
Next

USFolderPath = "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders"
On Error Resume Next
WshShell.RegWrite "HKCR\exefile\shellex\DropHandler\", "{86C86720-42A0-1069-A2E8-08002B30309D}", "REG_SZ"
WshShell.RegWrite "HKCR\lnkfile\shellex\DropHandler\", "{00021401-0000-0000-C000-000000000046}", "REG_SZ"
WshShell.RegWrite USFolderPath & "\SendTo", strSendTo, "REG_EXPAND_SZ"
Wshshell.RUN ("regsvr32.exe shell32.dll /i /s")

'Get curr. user name
Set colItems = objWMIService.ExecQuery("Select * From Win32_ComputerSystem")
For Each objItem in colItems
    strCurrentUserName = objItem.UserName
Next

'Restart user shell
Set colProcessList = objWMIService.ExecQuery _
    ("Select * from Win32_Process Where Name = 'Explorer.exe'")
For Each objProcess in colProcessList
    colProperties = objProcess.GetOwner(strNameOfUser,strUserDomain)
    If strUserDomain & "\" & strNameOfUser = strCurrentUserName then
        objProcess.Terminate()
    End If
Next

MsgUser = Msgbox ("Fixed the Send To menu.", 4160, "'Send To' menu fix for Windows 10/8/7/Vista/XP.")
Set WshShell = Nothing

— डग डेडेन
स्रोत

मुझे लगता है कि स्क्रिप्ट को बचाने के लिए (i मतलब विस्तार) और निष्पादित करने के तरीके के बारे में विवरण होना बेहतर है।

— 17

@achintha उन विवरणों को उत्तर में संपादित करने के लिए स्वतंत्र महसूस करें। यह स्टैक एक्सचेंज साइटों पर प्रोत्साहित किया जाता है।

— ट्विस्टी इंपर्सनेटर