मैं box.com भंडारण में फ़ाइलों को अपलोड करने के लिए सफलतापूर्वक cURL का उपयोग कर रहा हूं:
:: send file to Box.com
::
:: Syntax: sb.bat <username> <password> <filename> [<destination filename>]
@setlocal enabledelayedexpansion
@set OutFile=https://dav.box.com/dav/%~4
@if "%~4" equ "" set OutFile=https://dav.box.com/dav/%~nx3
@echo Sending file: "%~dpnx3"
@echo Destination : "%OutFile%"
@set replace=%%20
@set OutFile=%OutFile: =!replace!%
curl --insecure -u %1:%2 -T "%~3" "%OutFile%"
@if %ErrorLevel% neq 0 echo CURL returned error code of %ErrorLevel%
@exit /b %ErrorLevel%
यदि गंतव्य फ़ोल्डर पहले से मौजूद नहीं है, तो यह आदेश विफल हो जाता है, और मुझे कोई भी उदाहरण या दस्तावेज़ नहीं मिल सकता है कि आप बॉक्स.कॉम स्टोरेज में फ़ोल्डर बनाने के लिए cURL का उपयोग कैसे कर सकते हैं।
** अपडेट करें **
यहाँ परिणामी बैच रूटीन है, Anaksunaman से स्वीकृत उत्तर के आधार पर।
:: create a folder at Box.com
::
:: Syntax: cf.bat <username> <password> <pathname>
@setlocal enabledelayedexpansion
@set NewPath=https://dav.box.com/dav/%~3
@echo Creating folder: "%NewPath%"
@set replace=%%20
@set NewPath=%NewPath: =!replace!%
@set replace=/
@set NewPath=%NewPath:\=!replace!%
curl --insecure -u %1:%2 -X MKCOL "%NewPath%"
@if %ErrorLevel% neq 0 @echo cURL returned error code of %ErrorLevel%
@exit /b %ErrorLevel%