Cmd का उपयोग कर वायरलेस नेटवर्क से कनेक्ट नहीं किया जा सकता

Question

Im अपने फ़ोन को FTP के माध्यम से अपने PC से कनेक्ट करने की कोशिश कर रहा हूँ और cmd का उपयोग करके Windows Explorer के साथ FTP को खोल सकता हूँ।

नीचे दिए गए कोड हैं:

@echo off 
echo Setup connection to ftp 192.168.43.1 
ipconfig | findstr /I "192.168.43.1"
:: Opens ipconfig and searches for string "192.168.43.1" in the output of ipconfig to check if 192.168.43.1 is connected 
if %errorlevel% == 0 ( 
echo Connection set
%windir%\explorer.exe ftp://192.168.43.1:8888/ 
) else ( 
echo Connection not set 
echo Setting up connection... 
netsh wlan connect name="sdc-yayjg"
:: "sdc-yayjg" is the host name of 192.168.43.1
timeout 3 > NUL 
echo Opening ftp 192.168.43.1
ipconfig | findstr /I "192.168.43.1" 
if %errorlevel% == 0 ( 
echo Connection set
%windir%\explorer.exe ftp://192.168.43.1:8888/ 
) else ( 
echo FAIL: Connection not set. 
echo Press any key to exit. 
pause > NUL

मैं एक बैच फ़ाइल में उन कोड को संग्रहीत करता हूं और जब मैं बैच फ़ाइल चलाता हूं, तो cmd एक मिलीसेकंड या तो के लिए खुलता है और फिर बाहर निकलता है, मेरा मतलब है कि cmd विंडो बस कुछ मिलीसेकंड के लिए चमकती है और कुछ नहीं होता है। कोई संबंध स्थापित नहीं किया गया है या जो भी हो।
"खोज" आदेश के बिना कोड ठीक काम करते हैं। मैं उस आदेश को नहीं हटा सकता क्योंकि यह नेटवर्क स्थिति की जांच करने के लिए बहुत आवश्यक है।

Comments

आपके बैच फ़ाइल के अंत में "ठहराव" होने पर सीएमडी का क्या होता है? ("विराम दें & gt; एनयूएल" आपके लिए काम नहीं करता है।)

— Ultrasonic54321

@ Ultrasonic54321 मैंने जोड़ा '; ठहराव', अंत में, वही हो रहा है यानी खिड़की चमकती हुई। किसी भी बदलाव पर ध्यान नहीं दिया।

— Xlam

तब स्पष्ट रूप से पता लगाने के लिए ipconfig आउटपुट में स्ट्रिंग नहीं मिल रही है। साथ ही आपके विषय में कहा गया है कि आप अपने फोन से अपने डेस्कटॉप पर एफ़टीपी करने की कोशिश कर रहे हैं, लेकिन यह दूसरे तरीके से हो रहा होगा (आपने अपने फोन पर एफ़टीपी सर्वर स्थापित किया है?)

— psusi

@psusi जब मैं सीधे ipconfig टाइप करता हूं और एक cmd विंडो में एंट्री मारता हूं, जब मेरा पीसी मेरे फोन से जुड़ा होता है, तो मैं आउटपुट में आईपी एड्रेस देखता हूं। अन्य कोड के साथ बैच फ़ाइल से इसे चलाने के दौरान ही समस्या हुई। वैसे भी, समस्या 'नेस्टेड इफ-और' के साथ लगती है, मैंने अपने कोड में उपयोग किया था। यदि नेस्टेड-और को 'गोटो' से बदल दिया जाए तो कोड ठीक काम करते हैं। Ultrasonic54321 का जवाब देखें

— Xlam

Answer 1

इस कोड को आज़माएं (भावी उपयोगकर्ताओं के लिए प्रतिरूपकता में सुधार करने के लिए संपादित, और बेहतर उपयोगकर्ता अनुभव के लिए थोड़ा बेहतर कोड):

@echo off
goto setup
:setup
title FTP Connection w/ network support 

SET "FTP=192.168.43.1"
:: Location of the FTP server

SET "FTPPORT=8888"
:: The FTP server's port

SET "WIRELESS=sdc-yayjg"
:: The network where the FTP server resides

SET "TRIES=0"
:: Please do not tamper with.

SET "MAXTRIES=3"
:: How many tries before failure

SET "TIMETOCONNECT=3"
:: How much time to give to connect to the network

echo Setting up connection to FTP %FTP%...
goto check1
:check1
if %TRIES% LSS %MAXTRIES% (
SET /A "TRIES=TRIES+1"
goto check2
) else (
goto Fail
)
:check2
echo Checking for FTP Server presence...
ipconfig | findstr /I "%FTP%"
:: Opens ipconfig and searches for %FTP%. (in this case it's "192.168.43.1") in the output of ipconfig to check if 192.168.43.1 is connected 
if %errorlevel% EQU 0 ( 
goto 0
) else ( 
echo Presence not found. Assuming connection not set...
goto 1
)
:1
echo Connection not set after %TRIES% times.
echo Setting up connection... 
netsh wlan connect name="%WIRELESS%"
:: This script assumes that WIRELESS (sdc-yayjg) houses the IP (192.168.43.1)
timeout %TIMETOCONNECT% > NUL 
goto check1
:Fail
echo FAIL: Connection not set after %MAXTRIES% tries. 
echo Press any key to exit. 
pause > NUL
exit
)
:0
echo Internet Connection set - Connecting to FTP via Windows Explorer...
%windir%\explorer.exe ftp://%FTP%:%FTPPORT%/ 
echo Connection Sucessful. Windows Explorer should now open...
echo Press any key to close this window.
pause > NUL
exit

इस घटना में कि उपरोक्त कोड काम नहीं कर रहा है, मूल कोड (जो कुछ कॉस्मेटिक परिवर्तनों के साथ ओपी के अनुसार काम करता है) नीचे है।

@echo off 
echo Setting up connection to FTP 192.168.43.1...
goto Check
:check
ipconfig | findstr /I "192.168.43.1"
:: Opens ipconfig and searches for 192.168.43.1 in the output of ipconfig to check if 192.168.43.1 is connected 
if %errorlevel% == 0 ( 
goto 0
) else ( 
goto 1

)
:: Close your if statements!
:1
echo Connection not set 
echo Setting up connection... 
netsh wlan connect name="sdc-yayjg"
:: "sdc-yayjg" is the host name of 192.168.43.1
timeout 3 > NUL 
echo Opening ftp 192.168.43.1
ipconfig | findstr /I "192.168.43.1" 
if %errorlevel% == 0 ( 
goto 0
) else ( 
echo FAIL: Connection not set after three tries. 
echo Press any key to exit. 
pause > NUL
:: Close your if statements!
exit
)
:0
echo Internet Connection set - Connecting to FTP via Windows Explorer...
%windir%\explorer.exe ftp://192.168.43.1:8888/ 
exit

Comments

मैं इसे अधिक मॉड्यूलर बनाने के लिए आपके कोड को संपादित करूंगा, लेकिन मैं अभी अपने कंप्यूटर पर नहीं हूं।

— Ultrasonic54321

आपके कोड का उपयोग करते हुए, डिवाइस सफलतापूर्वक जुड़ा हुआ है लेकिन विंडोज एक्सप्लोरर को नहीं खोलता है क्योंकि यह आपके कोड के साथ होना चाहिए। Im यह पता लगाने में सक्षम नहीं है कि क्यों नहीं खुल रहा है

— Xlam

ओह रुको अब इसके खुलने का। पता नहीं उस समय क्या गलत हुआ था। धन्यवाद

— Xlam