जब ध्यान में न हो तो Excel में सेल चयन दिखाएँ

Question

यह वास्तव में कष्टप्रद है कि एक्सेल (2003 और 2007) यह नहीं दिखाता है कि विंडो के फोकस में न होने पर कौन सी सेल, रो या कॉलम चुना जाता है। मैं आमतौर पर किसी अन्य एप्लिकेशन में काम करते समय वर्तमान सेल या पंक्ति को संदर्भित करना चाहता हूं।

क्या कोई वर्कअराउंड या फिक्स है जो फोकस न होने पर सेल / रो को हाइलाइट करेगा? मुझे पता है कि आप एक सेल (Ctrl + C) की नकल कर सकते हैं लेकिन हर बार ऐसा करना थकाऊ है।

Comments

Cntrl + C कोई अच्छा नहीं है, क्योंकि मैं अपनी क्लिपबोर्ड सामग्री रखना चाहता हूं

— केल्टरी

फोकस खो जाने

— डेव

Microsoft Word / Excel में परिवर्तन को ध्यान में रखते हुए चयनित पाठ को कैसे रखा जाए, इसकी

— साइबरबैंक

Answer 1

मुझे लगता है कि चारों ओर एक काम है लेकिन, यह वास्तव में आपकी स्थिति पर निर्भर करता है!

आप एक मैक्रो बना सकते हैं जो चयन के समय बदल जाता है और यह प्रत्येक सेल की पृष्ठभूमि को बदल देता है। जब आप सेल को 'छोड़' देते हैं तो यह पंक्ति की पृष्ठभूमि मान को सफेद में रीसेट कर देगा और फिर नई पंक्ति का चयन करेगा।

मैंने इसे Visual Basic विंडो में अपने शीट 1 में जोड़ा।

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Cells.Interior.ColorIndex = xlColorIndexNone
    ActiveCell.EntireRow.Interior.ColorIndex = 34
End Sub

यह स्क्रीन शॉट तब लिया गया था जब एप्लिकेशन ने फोकस खो दिया था।

यह कष्टप्रद हो सकता है लेकिन आप आसानी से एक बटन जोड़ सकते हैं जो इस सुविधा को चालू या बंद कर सकता है!

निगेटिव हैं (मेरे सिर के ऊपर से: यह आपके पास मौजूद किसी भी हाइलाइटिंग को हटा देगा। इसलिए यदि आपने अपने पेज पर हाइलाइटिंग की है (रंगीन रंग) तो इसका उपयोग न करें! इसके अलावा, यह संभवतः हाइलाइट की गई पंक्तियों के साथ प्रिंट होगा!

Answer 2

जरूरत पड़ने पर आप ऐसा कुछ कर सकते हैं। हालांकि यह शीट विशिष्ट हो सकता है

Dim wasActive As String

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If wasActive = Empty Then wasActive = "A1"
Range(wasActive).Interior.ColorIndex = "0"
ActiveCell.Interior.ColorIndex = "6"
wasActive = ActiveCell.Address
End Sub

यह वापस सफेद करने के लिए सक्रिय नहीं है, और पीले करने के लिए activecell बदल जाता है। और तब भी दिखाता है जब खिड़की सक्रिय नहीं है। यकीन नहीं होता कि यह सबसे अच्छा तरीका है, लेकिन यह काम करता है

Answer 3

यहाँ @datatoo से कोड का संशोधन है। यह वर्तमान भरण रंग को खोने से रोकने के लिए पिछले मानों को पढ़ता है। यह पाठ के रंग को भी बदल देता है ताकि यह और आगे निकल जाए। मैंने इसे कोड संपादक में एक्सेल शीट में जोड़ा (एक्सेल से Alt-F11)।

वर्कशीट बदलने की घटना के बारे में जानकारी के लिए यहां क्लिक करें ।

'VBA code for Excel to show active cell in worksheet when worksheet is out of focus

Dim wasActive As String
Dim originalFillColor As String
Dim originalTextColor As String

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    'Set up colors on load
    If wasActive = Empty Then
        wasActive = "A1"
        originalFillColor = Range(wasActive).Interior.Color
        originalTextColor = Range(wasActive).Font.Color
    End If

    'Reset previous cell to original color values; If statement prevents removal of grid lines by using "0" for clear fill color when white
    If originalFillColor = 16777215 Then
        Range(wasActive).Interior.ColorIndex = "0"
        Range(wasActive).Font.Color = originalTextColor
    Else
        Range(wasActive).Interior.Color = originalFillColor
        Range(wasActive).Font.Color = originalTextColor
    End If

    'Set new colors and change active cell to highlighted colors (black fill with white text)
    originalFillColor = ActiveCell.Interior.Color
    originalTextColor = ActiveCell.Font.Color
    wasActive = ActiveCell.Address
    ActiveCell.Interior.ColorIndex = "1"
    ActiveCell.Font.ColorIndex = "2"

End Sub

Answer 4

चयन को हाइलाइट करने के लिए किसी आकृति का उपयोग करें।

नोट: यह केवल दूसरी एक्सेल विंडो पर स्विच करने पर काम करता है। वर्कअराउंड के रूप में आप हाइलाइट रखने के लिए किसी अन्य एप्लिकेशन पर स्विच करने से पहले एक खाली एक्सेल विंडो खोल सकते हैं और इस विंडो पर स्विच कर सकते हैं।

बस इसे अपने ThisWorkbookcode में जोड़ें (आपका वर्कबुक, आपका शीट कोड नहीं)। यह आपकी कार्यपुस्तिका में प्रत्येक पत्रक के लिए काम करेगा।

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
    DeleteSelectionHighlight
End Sub
Private Sub Workbook_WindowActivate(ByVal Wn As Window)
    DeleteSelectionHighlight
End Sub
Private Sub Workbook_WindowDeactivate(ByVal Wn As Window)
  On Error Resume Next
    Dim shp As Shape
    Application.ScreenUpdating = False

    Set shp = ActiveSheet.Shapes("SelectionHighlight")
    If Err.Number <> 0 Then
        Set shp = ActiveSheet.Shapes.AddShape(msoShapeRectangle, 1, 1, 1, 1)
        With shp 'Format shape to your preference
            .Name = "SelectionHighlight"
            .Line.ForeColor.RGB = RGB(226, 0, 0) ' Border color
            .Line.Weight = 1.5
            .Line.DashStyle = msoLineSolid
            .Fill.Visible = msoFalse 'No background
            '.Fill.ForeColor.RGB = RGB(0, 153, 0) 'Background color
            '.Fill.Transparency = 0.95 'Background transparency
        End With
    End If

    Dim oldZoom As Integer
    oldZoom = Wn.Zoom
    Wn.Zoom = 100 'Set zoom at 100% to avoid positioning errors
    With shp
        .Top = Wn.Selection.Top   'Tweak the offset to fit your desired line weight
        .Left = Wn.Selection.Left 'Tweak the offset to fit your desired line weight
        .Height = Wn.Selection.Height
        .Width = Wn.Selection.Width
    End With
    Wn.Zoom = oldZoom 'Restore previous zoom
    Application.ScreenUpdating = True
End Sub

Private Sub DeleteSelectionHighlight()
  On Error Resume Next
  Dim shp As Shape
    Set shp = ActiveSheet.Shapes("SelectionHighlight")
    shp.Delete
End Sub

आप कोड को ट्विक करके अपनी पसंद को आकार भी दे सकते हैं।

लाभ हैं:

• जब आपके पास बिजली की विफलता होती है, तो आप अपनी मूल स्वरूपण को नहीं खोते हैं
• सक्रिय पत्रक को बदलने वाली किसी अन्य कार्यपुस्तिका से CTRL + [का उपयोग करते समय आप अपने मूल स्वरूपण को नहीं खोते हैं
• CTRL + C समाधान की तुलना में अन्य एक्सेल विंडो में परिवर्तन करते समय आप हाइलाइट नहीं खोते हैं

Answer 5

Excel 2003 में वर्तमान में चयनित सेल पता ऊपरी बाएँ में दिखाया गया है। हालाँकि सेल को हाइलाइट नहीं किया गया है, लेकिन यह आपको वहाँ भाग देता है।

Answer 6

इस समस्या का कोई स्थायी समाधान नहीं है।

एक वर्कअराउंड (थोड़ी देर में परेशान हो सकता है) चयनित कोशिकाओं के हाइलाइटिंग को बदलने के लिए होगा, जबकि वे चुने गए हैं और फिर से रंग छोड़ने के लिए उन्हें फिर से चुनें।

इस कोड को शीट 1 कोड में पीछे रखें और आप स्प्रैडशीट पर जाएं और कुछ सेल चुनें, अन्य का चयन करें फिर रंग छोड़ने के लिए पहले वाले को फिर से चुनें।

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim cell As Range

    For Each cell In Target.Cells
        If cell.Interior.Color = RGB(60, 150, 230) Then
            cell.Interior.Pattern = xlNone
        Else
            cell.Interior.Color = RGB(60, 150, 230)
        End If
    Next
End Sub

Answer 7

एक साधारण समाधान ^{_{जो चयन में परिवर्तन होने पर सेल रंग देता है}}

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Selection.Interior.ColorIndex = xlColorIndexNone
    Selection.Interior.Color = RGB(204, 204, 204)
End Sub

---

एक जटिल समाधान ^{_{जो केवल फोकस खो जाने पर सेल रंग को बदल देता है}}

एक मानक मॉड्यूल में:

Option Explicit    
Public s As Range

शीट में आप चाहते हैं कि वह इसमें काम करे:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Set s = Selection
End Sub

इन ThisWorkbook:

Private Sub Workbook_Deactivate()
    If s Is Nothing Then
        Set s = Selection
        Exit Sub
    End If
    s.Interior.ColorIndex = xlColorIndexNone
    s.Interior.Color = RGB(204, 204, 204)

    ' This is optional formatting to make the cells look more like they're actually selected
    s.Borders.Color = RGB(130, 130, 130)
    s.BorderAround _
    Color:=RGB(30, 130, 37), Weight:=xlThick
End Sub

Private Sub Workbook_Activate()
    If s Is Nothing Then
        Set s = Selection
        Exit Sub
    End If
    s.Interior.ColorIndex = xlColorIndexNone
    s.Borders.ColorIndex = xlColorIndexNone
End Sub

---

_{उद्धरण: सरल समाधान @Dave द्वारा पिछले उत्तर पर आधारित है ; जटिल समाधान कई स्रोतों से एक साथ लाया गया था, विशेष रूप से इस पोस्ट में @JohnColeman की मदद से ।}