प्रत्येक दिन .vbs के लिए लॉग जनरेट करें

Question

मैं इस स्क्रिप्ट के साथ दिन के लिए एक लॉग फ़ाइल बनाने की कोशिश कर रहा हूं

hostIp      = wscript.arguments(0)
logfilename = wscript.arguments(1)
Set fso     = CreateObject("Scripting.FileSystemObject")
Set Shell   = CreateObject("Wscript.Shell")
' OpenTextFile Method requires a Const value
' (Over)Write = 2  Append = 8  
    d = Day(Now) 
    m = Month(Now)  
    y = Year(Now)
    myDateFormat= d & "-" & m & "-" & y 
Set logfile = fso.OpenTextFile(logfilename & " " & myDateFormat & ".log", 8, True)
shellstring = "%comspec% /c ping -t -f -l 32 -w 1000 " & hostIP
Set oExec   = Shell.Exec(shellstring)
wscript.echo "Ping Error log With Timestamp - Ctrl + C to halt"
Do While oExec.StdOut.AtEndOfStream <> True
      pingline = Date & " " & Time & " " & oExec.StdOut.ReadLine
'      If InStr(pingline, "TTL=") = 0 Then
         logfile.WriteLine(pingline)
'      End If
Loop

मुझे लगा कि यह ठीक है, लेकिन मैंने इसे 3 दिनों के लिए चलाया है और इसके बजाय केवल एक फ़ाइल है। 3 स्क्रिप्ट के बारे में गलत क्या है? btw मैं इस लाइन के साथ cmd पर इस स्क्रिप्ट को चलाता हूं

FileName ip logname.log

Comments

अपने तर्क को सत्यापित करने के लिए d, "m", "y", 'logfile' के मान को प्रिंट करने के लिए लॉग फाइल में स्टेटमेंट जोड़ें। प्रासंगिक जानकारी के साथ प्रश्न अद्यतन करें।

— Ramhound

Answer 1

क्या यह मदद करता है:

dim objShell : set ObjShell  = CreateObject("Wscript.Shell")
dim objFso   : set objFso    = CreateObject("Scripting.FileSystemObject")

dim shellstring : shellstring = "%comspec% /c ping -t -f -l 32 -w 1000 " & wscript.arguments(0)

dim oExec : set oExec = ObjShell.Exec(shellstring)

do while oExec.StdOut.AtEndOfStream <> true
  log( oExec.StdOut.ReadLine )
loop

function log(strLineIn)

  myDateFormat= Day(Now) & "-" & Month(Now) & "-" & Year(Now)

  dim logfile : set logfile = objFso.OpenTextFile(wscript.arguments(1) & " " & myDateFormat & ".log", 8, True)

  if instr(strLineIn, "TTL") > 0 then
    logfile.writeline date() & "-" & time() & ": " & strLineIn
  end if

  logfile.close

end function