मुझे बैटरी स्तर परिवर्तन के आधार पर टास्क शेड्यूलर में एक कार्य बनाने की आवश्यकता है
विंडोज घटनाओं के रूप में इस तरह के विवरण को लॉग नहीं करता है हालाँकि आप नीचे दी गई बैच फ़ाइल जैसी किसी चीज़ का उपयोग कर सकते हैं और एक कस्टम ईवेंट बना सकते हैं।
Battery.cmd
यह बैच फ़ाइल वर्तमान बैटरी प्रतिशत चार्ज पर नज़र रखती है और उपयोगकर्ता परिभाषित घटना बनाता है यदि चार्ज उपयोगकर्ता परिभाषित सीमा मूल्य से नीचे चला जाता है।
@echo off
setlocal EnableDelayedExpansion
rem set threshold value
set _threshold=82
:start
rem get the battery charge
rem use findstr to strip blank lines from wmic output
for /f "usebackq skip=1 tokens=1" %%i in (`wmic Path Win32_Battery Get EstimatedChargeRemaining ^| findstr /r /v "^$"`) do (
set _charge=%%i
echo !_charge!
if !_charge! lss !_threshold! (
echo threshold reached
rem create a custom event in the application event log
rem requires administrator privileges
eventcreate /l APPLICATION /t WARNING /ID 999 /D "Battery charge has dropped"
goto :done
) else (
rem wait for 10 minutes then try again
timeout /t 600 /nobreak
goto :start
)
)
:done
endlocal
टिप्पणियाँ:
Eventcreateकरने के लिए और सहित Windows 10 अप Windows XP पर आदेश काम करता है, यह काम करने के लिए व्यवस्थापक विशेषाधिकारों की आवश्यकता है_thresholdआवश्यकतानुसार सेट करें- यदि बैटरी इस मान से नीचे आती है
999तो विवरण के साथ APPLICATION ईवेंट लॉग में ID के साथ कोई ईवेंट उत्पन्न हो जाएगाBattery charge has dropped
eventcreateअपनी स्थिति के लिए आवश्यकतानुसार कमांड को संशोधित करें ।timeoutअपनी स्थिति के लिए आवश्यकतानुसार देरी को संशोधित करें ।
उदाहरण आउटपुट:
मेरी बैटरी का वर्तमान में 81% चार्ज है। मैंने थ्रेशोल्ड सेट किया 82। जब मैं दौड़ता हूं तो यहां क्या होता है Battery.cmd:
> battery
81
threshold reached
SUCCESS: An event of type 'WARNING' was created in the 'APPLICATION' log with 'EventCreate' as the source.
और यहां इवेंट लॉग में नई प्रविष्टि है:
घटना सिंटैक्स
EVENTCREATE [/S system [/U username [/P [password]]]] /ID eventid
[/L logname] [/SO srcname] /T type /D description
Description:
This command line tool enables an administrator to create
a custom event ID and message in a specified event log.
Parameter List:
/S system Specifies the remote system to connect to.
/U [domain\]user Specifies the user context under which
the command should execute.
/P [password] Specifies the password for the given
user context. Prompts for input if omitted.
/L logname Specifies the event log to create
an event in.
/T type Specifies the type of event to create.
Valid types: SUCCESS, ERROR, WARNING, INFORMATION.
/SO source Specifies the source to use for the
event (if not specified, source will default
to 'eventcreate'). A valid source can be any
string and should represent the application
or component that is generating the event.
/ID id Specifies the event ID for the event. A
valid custom message ID is in the range
of 1 - 1000.
/D description Specifies the description text for the new event.
/? Displays this help message.
Examples:
EVENTCREATE /T ERROR /ID 1000
/L APPLICATION /D "My custom error event for the application log"
EVENTCREATE /T ERROR /ID 999 /L APPLICATION
/SO WinWord /D "Winword event 999 happened due to low diskspace"
EVENTCREATE /S system /T ERROR /ID 100
/L APPLICATION /D "Custom job failed to install"
EVENTCREATE /S system /U user /P password /ID 1 /T ERROR
/L APPLICATION /D "User access failed due to invalid user credentials"
आगे की पढाई
- विंडोज सीएमडी कमांड लाइन का एक ऐज़ इंडेक्स - संबंधित सभी चीज़ों के लिए एक उत्कृष्ट संदर्भ विंडोज सीएमडी लाइन।
- Eventcreate - विंडोज इवेंट व्यूअर में एक कस्टम ईवेंट बनाएं।
- schtasks - अनुसूचित नौकरी / कार्य बनाएँ / संपादित करें। नौकरी स्थानीय या दूरस्थ कंप्यूटर पर बनाई जा सकती है।
- wmic - विंडोज मैनेजमेंट इंस्ट्रूमेंटेशन कमांड।
