मैं विंडोज 10 के तहत लिब्रे ऑफिस में डिफ़ॉल्ट के रूप में यूनिकोड -8 कैसे सेट करूं?

जब मैं लिब्रे ऑफिस Calc का उपयोग करता हूं और अपनी फ़ाइल को एक .csv लिब्रे ऑफिस के रूप में सहेजता हूं तो पश्चिमी यूरोप को डिफ़ॉल्ट एन्कोडिंग के रूप में सुझाता हूं। लेकिन मैं यूनिकोड -8 एन्कोडिंग चाहता हूं।

windows-10 libreoffice

— Christian
स्रोत

LibreOffice v5.0.x की मेरी प्रति को देखते हुए, यह एक डिफ़ॉल्ट सेटिंग नहीं है। हालांकि आसपास देखते हुए, मुझे एक मैक्रो का उदाहरण मिला जिसे आप यूटीएफ 8 में बचाने के लिए यहां उपयोग कर सकते हैं,

https://forum.openoffice.org/en/forum/viewtopic.php?f=45&t=19695

और दूसरा मैक्रो आपको बताने के लिए फ़ाइल पिकर संवाद का उपयोग करता है

https://forum.openoffice.org/en/forum/viewtopic.php?f=25&t=36441

यहाँ पूरा कोड है ...

Function fOpenFile() as String

   Dim oFileDialog as Object
   Dim iAccept as Integer
   Dim sPath as String
   Dim InitPath as String
   Dim oUcb as object
   Dim filterNames(3) as String

   filterNames(0) = "*.csv"
   'filterNames(1) = "*.png"
   'filterNames(2) = "*.jpg"

   GlobalScope.BasicLibraries.LoadLibrary("Tools")
   'Note: The following services must be called in the following order,
   ' otherwise the FileDialog Service is not removed.
   oFileDialog = CreateUnoService("com.sun.star.ui.dialogs.FilePicker")
   oUcb = createUnoService("com.sun.star.ucb.SimpleFileAccess")

   AddFiltersToDialog(FilterNames(), oFileDialog)
   'Set your initial path here!
   InitPath = ConvertToUrl("C:\")

   If oUcb.Exists(InitPath) Then
      oFileDialog.SetDisplayDirectory(InitPath)
   End If

   iAccept = oFileDialog.Execute()
   If iAccept = 1 Then
      sPath = oFileDialog.Files(0)
      fOpenFile = sPath
   End If
   oFileDialog.Dispose()

End Function
Sub SaveAsCsvUTF8
    Dim Propval(1) as New com.sun.star.beans.PropertyValue
    Propval(0).Name = "FilterName"
    Propval(0).Value = "Text - txt - csv (StarCalc)"
    Propval(1).Name = "FilterOptions"
    ' field sep(44 - comma), txt delim (34 - dblquo), charset (0 = system, 76 - utf8), first line (1 or 2) 
    Propval(1).Value = "44,34,76,1" 
    Doc = ThisComponent
    Filename = fOpenFile()
    FileURL = convertToURL(FileName)
    Doc.StoreAsURL(FileURL, Propval())
End Sub

इसे एक शॉर्टकट में असाइन करें और आप जाने के लिए अच्छे हैं।

पुनश्च: यदि फ़ाइल पहले से ही UTF8 में है, तो इसे केवल उसका सम्मान करना चाहिए।

HTH

— Dude named Ben
स्रोत