विंडोज विस्टा: cmd में "। प्रशासक के रूप में .exe प्रोग्राम निष्पादित करने के लिए कैसे"

11

हाँ बस यही। मुझे dos cmd लाइन में एक प्रोग्राम .exe चलाने की आवश्यकता है और इसे तब चलाने की आवश्यकता होती है जब आप दाहिने बटन पर क्लिक करते हैं और "एक व्यवस्थापक के रूप में चलाते हैं" का चयन करते हैं

windows-vista  shell  command-line 
— BinaryMisfit
स्रोत
मैं उसके बारे में भी सोचता था। मेरा समाधान या तो कमांड के साथ एक बैच फ़ाइल बनाने और इसे हमेशा व्यवस्थापक के रूप में चलाने के लिए, या cmd को व्यवस्थापक के रूप में खोलने के लिए था। लेकिन ऐसा लगता है कि कुछ सुरुचिपूर्ण समाधान होना चाहिए।
— ओरेगनगॉस्ट

जवाबों:

15

विंडोज में एक "रनस" कमांड होता है जो यूनिक्स-वाई सिस्टम में सुडो की तरह एक सा कार्य करता है। टाइपिंग "रनस /?" अपने कमांड प्रॉम्प्ट में।

— Neall
स्रोत
या इसे यहाँ देखें: Technet.microsoft.com/en-us/library/cc771525.aspx
— Asaf R
यह एक सही उत्तर नहीं है, जब तक कि आपके पास प्रशासक उपयोगकर्ता एक गैर-खाली पासवर्ड के साथ सक्षम नहीं है।
— जिगगंजर
7

यदि आप स्वयं cmd ​​को व्यवस्थापक के रूप में चलाते हैं, तो आप वहां से जो कुछ भी चलाते हैं, वह भी होगा। मैं सिर्फ कमांड प्रॉम्प्ट पर एक शॉर्टकट सेटअप करता हूं जो प्रशासक के रूप में खुलता है। वहां से सब कुछ जाना अच्छा है।

— Kilhoffer
स्रोत
5

मैंने .cmd & .vbs स्क्रिप्ट की एक जोड़ी का उपयोग किया है, जिसे एलिवेट कहा जाता है, यह मेरी जरूरतों के लिए ठीक काम करती है। आपको बस टाइप करना है

तरक्की [कमान]
स्टार्ट> रन से या कमांड लाइन से, और यह एडमिनिस्ट्रेटर विशेषाधिकारों के साथ कमांड चलाएगा। आशा करता हूँ की ये काम करेगा!

यहाँ पर उन्नत है। cmd:

:: //***************************************************************************
:: // ***** Script Header *****
:: //
:: // File:      Elevate.cmd
:: //
:: // Additional files required:  Elevate.vbs
:: //
:: // Purpose:   To provide a command line method of launching applications that
:: //            prompt for elevation (Run as Administrator) on Windows Vista.
:: //
:: // Usage:     elevate.cmd application <application arguments>
:: //
:: // Version:   1.0.0
:: // Date :     01/02/2007
:: //
:: // History:
:: // 1.0.0   01/02/2007  Created initial version.
:: //
:: // ***** End Header *****
:: //***************************************************************************


@echo off

:: Pass raw command line agruments and first argument to Elevate.vbs
:: through environment variables.
set ELEVATE_CMDLINE=%*
set ELEVATE_APP=%1

start wscript //nologo "%~dpn0.vbs" %*

और ऊंचाई:

' //***************************************************************************
' // ***** Script Header *****
' //
' // File:      Elevate.vbs
' //
' // Additional files required:  Elevate.cmd
' //
' // Purpose:   To provide a command line method of launching applications that
' //            prompt for elevation (Run as Administrator) on Windows Vista.
' //
' // Usage:     (Not used directly.  Launched from Elevate.cmd.)
' //
' // Version:   1.0.1
' // Date :     01/03/2007
' //
' // History:
' // 1.0.0   01/02/2007  Created initial version.
' // 1.0.1   01/03/2007  Added detailed usage output.
' //
' // ***** End Header *****
' //***************************************************************************


Set objShell = CreateObject("Shell.Application")
Set objWshShell = WScript.CreateObject("WScript.Shell")
Set objWshProcessEnv = objWshShell.Environment("PROCESS")

' Get raw command line agruments and first argument from Elevate.cmd passed
' in through environment variables.
strCommandLine = objWshProcessEnv("ELEVATE_CMDLINE")
strApplication = objWshProcessEnv("ELEVATE_APP")
strArguments = Right(strCommandLine, (Len(strCommandLine) - Len(strApplication)))

If (WScript.Arguments.Count >= 1) Then
    strFlag = WScript.Arguments(0)
    If (strFlag = "") OR (strFlag="help") OR (strFlag="/h") OR (strFlag="\h") OR (strFlag="-h") _
        OR (strFlag = "\?") OR (strFlag = "/?") OR (strFlag = "-?") OR (strFlag="h") _
        OR (strFlag = "?") Then
        DisplayUsage
        WScript.Quit
    Else
        objShell.ShellExecute strApplication, strArguments, "", "runas"
    End If
Else
    DisplayUsage
    WScript.Quit
End If


Sub DisplayUsage

    WScript.Echo "Elevate - Elevation Command Line Tool for Windows Vista" & vbCrLf & _
                 "" & vbCrLf & _
                 "Purpose:" & vbCrLf & _
                 "--------" & vbCrLf & _
                 "To launch applications that prompt for elevation (i.e. Run as Administrator)" & vbCrLf & _
                 "from the command line, a script, or the Run box." & vbCrLf & _
                 "" & vbCrLf & _
                 "Usage:   " & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate application <arguments>" & vbCrLf & _
                 "" & vbCrLf & _
                 "" & vbCrLf & _
                 "Sample usage:" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate notepad ""C:\Windows\win.ini""" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate cmd /k cd ""C:\Program Files""" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate powershell -NoExit -Command Set-Location 'C:\Windows'" & vbCrLf & _
                 "" & vbCrLf & _
                 "" & vbCrLf & _
                 "Usage with scripts: When using the elevate command with scripts such as" & vbCrLf & _
                 "Windows Script Host or Windows PowerShell scripts, you should specify" & vbCrLf & _
                 "the script host executable (i.e., wscript, cscript, powershell) as the " & vbCrLf & _
                 "application." & vbCrLf & _
                 "" & vbCrLf & _
                 "Sample usage with scripts:" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate wscript ""C:\windows\system32\slmgr.vbs"" –dli" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate powershell -NoExit -Command & 'C:\Temp\Test.ps1'" & vbCrLf & _
                 "" & vbCrLf & _
                 "" & vbCrLf & _
                 "The elevate command consists of the following files:" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate.cmd" & vbCrLf & _
                 "    elevate.vbs" & vbCrLf

End Sub
— kolrie
स्रोत
बस जिज्ञासु, इस अति रनों का क्या फायदा है?
— 22
ओह! आप समझ गए! :) मैं रनों से अधिक लाभ नहीं जानता, लेकिन जब आप रनास को नहीं जानते, तो यह एकमात्र विकल्प है। मैं निश्चित रूप से शर्मिंदा हूं :)
मुझे लगता है कि अगर हम एक बार एक स्क्रिप्ट के रूप में उपयोग कर रहे हैं तो हम इसे पढ़ेंगे तो यह मदद करेगा!
1
इस जोड़ी को Technet.microsoft.com/en-us/magazine/…
2
एलिवेट स्क्रिप्ट का स्पष्ट लाभ यह है कि वे आपको यूएएसी के तहत अपने उपयोगकर्ता को व्यवस्थापक उपयोगकर्ता और पासवर्ड प्रदान करने की आवश्यकता के बिना प्रशासक को उन्नत करने में सक्षम बनाते हैं (यह प्रदान करते हुए कि आप एक व्यवस्थापक उपयोगकर्ता के रूप में लॉग इन हैं)। Runas.exe कर सकते हैं?
2

आप Windows कुंजी भी दबा सकते हैं, CMD टाइप करें, यह प्रोग्राम्स में cmd ​​को सूचीबद्ध करेगा, राइट क्लिक करें -> गुण -> संगतता -> इस प्रोग्राम को व्यवस्थापक के रूप में चलाएं

यह हमेशा एडमिन के रूप में चलेगा।

— डाकिया
स्रोत
आप Ctrl + Shift + Enter का भी उपयोग कर सकते हैं।
— जॉय
1

चूंकि किसी ने VBS के समकक्ष पोस्ट किया था, यहाँ PowerShell के लिए एक इनवोक-एडमिन फ़ंक्शन है

function Invoke-Admin() {
param ( [string]$program = $(throw "Please specify a program" ),
        [string]$argumentString = "",
        [switch]$waitForExit )

$psi = new-object "Diagnostics.ProcessStartInfo"
$psi.FileName = $program 
$psi.Arguments = $argumentString
$psi.Verb = "runas"
$proc = [Diagnostics.Process]::Start($psi)
if ( $waitForExit ) {
    $proc.WaitForExit();
}

}

— JaredPar
स्रोत
0

संक्षेप में:

  • प्रारंभ / क्लिक करें, फिर CTRL + SHIFT और ENTER दबाएँ। पुष्टि करें।

विस्तार से:

  1. प्रारंभ बटन दबाएं "cmd" (बिना उद्धरण के) तुरंत (1)
  2. CTRL और SHIFT दबाए रखें
  3. एंटर दबाए
  4. Windows Vista UAC संवाद बॉक्स की पुष्टि करें

(1) तत्काल का अर्थ है इसे सर्च बॉक्स में टाइप करना, रन बॉक्स में नहीं।

— Mackaaij
स्रोत
0

आप एक VBScript का उपयोग कर सकते हैं। एक .vbsफ़ाइल बनाएँ , जैसे ambika.vbs:

Set objShell = CreateObject(“Shell.Application”)
Set objWshShell = WScript.CreateObject(“WScript.Shell”)
Set objWshProcessEnv = objWshShell.Environment(“PROCESS”)

objShell.ShellExecute “C:\Windows\system32\cmd.exe”, “/k”, “”, “runas”
— अंबिका सिंह
स्रोत
हमारी साइट का प्रयोग करके, आप स्वीकार करते हैं कि आपने हमारी Cookie Policy और निजता नीति को पढ़ और समझा लिया है।
Licensed under cc by-sa 3.0 with attribution required.