मैं दूर से लोगों के एक बड़े समूह को प्रशिक्षण दे रहा हूं और कई एप्लिकेशन शॉर्टकट कुंजियों को कवर कर रहा हूं।
मैंने कीस्ट्रोक्स के माउस -स्क्रीन डिस्प्ले को देखा है; क्या विंडोज के लिए एक समान उत्पाद है?
माउसपोज़ की अन्य विशेषताएं (फैंसी माउस पॉइंटर्स, आदि) मेरे लिए वास्तव में उपयोगी नहीं हैं, बस प्रमुख प्रेस के ओएसडी।
जवाबों:
KeyPosé , विंडोज के लिए MousePosé का एक मुफ्त विकल्प है। आप में कार्रवाई में इसे देख सकते हैं स्क्रीनकास्ट ।
यहाँ एक नमूना स्क्रीनशॉट है:
मैं कार्नेक को बहुत सलाह देता हूं । यह GitHub पर होस्ट किया गया एक मुफ्त प्रोजेक्ट है।
एक कीबोर्ड लॉगिंग और प्रेजेंटेशन यूटिलिटीज़ फॉर प्रेजेंटेशन, स्क्रेंस्ट, और आपको एक बेहतर कीबोर्ड यूज़र बनने में मदद करने के लिए।
यह अच्छी तरह से निष्पादित है, अच्छी तरह से डिजाइन किया गया है और गिटहब पर भी खुला है ।
यहां फिक्स और माउस इनपुट के विज़ुअलाइज़ेशन के साथ कांटा रिलीज़ करें: https://github.com/bfritscher/carnac/releases/tag/v3-beta
carnac.applicationफ़ाइल प्रदान करता है , youtube वीडियो youtube.com/watch?v=qSUDfzUkwnc एक दिखाता है Carnac.exe। बस बाद में मुझे एहसास हुआ कि मैं carnac.applicationविंडोज में लॉन्च कर सकता हूं और यह प्रोग्राम को डाउनलोड और इंस्टॉल करता है। मुझे यहाँ zip / exe भी मिला: github.com/downloads/Code52/carnac/Carnac.zip
मैं अपने टूल - कीकास्ट को शेयर करना चाहूंगा।
https://brookhong.github.io/2014/04/28/keycast-on-windows.html
मैंने इस उद्देश्य के लिए एक AutoHotkey_L स्क्रिप्ट लिखी है।
इसे चलाने के लिए, AutoHotkey_L ( डायरेक्ट dl ) का उपयोग करें , यह FOSS है। इसके अलावा, AutoHotkey से आप स्क्रिप्ट को EXE (बस ) में संकलित कर सकते हैं ।Ahk2Exe.exe /inDisplayPressedKeyOnScreen.ahk/outDisplayPressedKeyOnScreen.exe
यह माउस कर्सर के पास दबाए गए कुंजी ओएसडी-जैसे या मानक टूल-टिप प्रदर्शित कर सकता है। इसके अलावा, यह माउस बटन क्लिक और व्हील स्क्रॉलिंग प्रदर्शित करता है।
(ध्यान दें कि फ्रेम और धुंधला चित्रण प्रयोजनों के लिए किया जाता है, स्क्रिप्ट ही पाठ w / o किसी भी गड़बड़ी को प्रदर्शित करता है)
Heres की स्क्रिप्ट (कॉपी करें और नोटपैड पर पेस्ट करें, DisplayPressedKeysOnScreen.ahk के रूप में सहेजें):
#NoEnv
#SingleInstance force
#InstallKeybdHook
Global KeyStates, MouseState, ClickCount, IdleDelay, LargeDisplay
IdleDelay=3000
LargeDisplay=1
; 0 = Tooltip near mouse pointer
; 1 = Big pane at screen bottom
If LargeDisplay
{
;Initializing GUI
;modded func originated from http://www.autohotkey.com/board/topic/8190-osd-function/
SysGet Monitor, Monitor
GUIx := MonitorLeft
GUIw := MonitorRight - MonitorLeft
GUIh := (MonitorBottom - MonitorTop) * GUIw * 0.00003
If (GUIh > ((MonitorBottom - MonitorTop) * 0.3))
GUIh := (MonitorBottom - MonitorTop) * 0.3
opacity=230
fname="Tahoma"
fsize:=GUIh * 0.65 ; really, pixel = 0.75 point, but with 0.75 lowercase letter with lower part (like "g") get cut
fcolor=cccccc
bcolor=222222
fformat="600"
Gui +LastFound +AlwaysOnTop +ToolWindow -Caption
Gui Margin, 0, 0 ;pixels of space to leave at the left/right and top/bottom sides of the window when auto-positioning.
Gui Color, ffffff ;changes background color
Gui Font, s%fsize% w%fformat%, %fname%
; 0x80 = SS_NOPREFIX -> Ampersand (&) is shown instead of underline one letter for Alt+letter navigation
Gui Add, Text, c%bcolor% Center +0x80 w%GUIw% h%GUIh% BackgroundTrans VblkOsdCtrlName, tesT test test
Gui Add, Text, c%fcolor% Center +0x80 w%GUIw% h%GUIh% BackgroundTrans VblkOsdCtrlName2 xp-3 yp-3 , tesT test test
WinSet ExStyle, +0x20 ; WS_EX_TRANSPARENT -> mouse klickthrough
WinSet TransColor, ffffff %opacity%
}
TrayTip %A_ScriptName%, To Exit`, press the Right Windows logo key.
Loop
{
Input SingleKey, L1 V M I B, {LControl}{RControl}{LAlt}{RAlt}{LShift}{RShift}{LWin}{AppsKey}{F1}{F2}{F3}{F4}{F5}{F6}{F7}{F8}{F9}{F10}{F11}{F12}{Left}{Right}{Up}{Down}{Home}{End}{PgUp}{PgDn}{Del}{Ins}{BS}{Capslock}{Numlock}{PrintScreen}{Pause}
GetKeyStates()
; IfInString ErrorLevel, EndKey
; CollectedText .= (CollectedText =="" ? "" : " + " ) . SubStr(ErrorLevel, 8)
If SingleKey
{
SingleKeyText=
If (SingleKey==Chr(27))
SingleKeyText=Esc
Else If (SingleKey==Chr(32))
SingleKeyText=Space
If (GetKeyState("LControl", "P") || GetKeyState("RControl", "P"))
{
If (SingleKey==Chr(10) && EnterPressed)
SingleKeyText=Enter
Else If (SingleKey >= Chr(1) && SingleKey <= Chr(26)) ; With "M" in Input, Ctrl-A through Ctrl-Z correspond to Chr(1) through Chr(26)
SingleKeyText := Chr(Asc("A")-1+Asc(SingleKey))
} Else {
If (SingleKey==Chr(10))
SingleKeyText=Enter
}
If Not SingleKeyText
SingleKeyText:=SingleKey
ShowKeys(KeyStates . SingleKeyText)
; . (MouseState ? "`n" . MouseState : "")
EnterPressed=0
GoSub ClearMouseState
} Else {
ShowKeys(SubStr(KeyStates, 1, -3) . (MouseState ? " + " . MouseState : ""))
}
SetTimer TooltipOff, % -IdleDelay
}
RWin::
ExitApp
~*Enter::
EnterPressed=1
return
~*LButton::
~*RButton::
~*MButton::
~*XButton1::
~*XButton2::
MouseState := "Mouse " . SubStr(A_ThisHotkey, 3) . " Pressed"
MouseTooltip()
return
~*WheelDown::
~*WheelUp::
~*WheelLeft::
~*WheelRight::
MouseState := "Mouse " . SubStr(A_ThisHotkey, 3)
MouseTooltip()
return
~*LButton Up::
~*RButton Up::
~*MButton Up::
~*XButton1 Up::
~*XButton2 Up::
; MsgBox %A_PriorHotkey%`n%A_ThisHotkey%
If (A_PriorHotkey == SubStr(A_ThisHotkey, 1, -3) && A_TimeSincePriorHotkey < 200)
{
ClickCount++
Suffix := " Clicked " . ClickCount . "x"
} Else {
ClickCount:=0
Suffix := " Released"
}
MouseState := "Mouse " . SubStr(A_ThisHotkey, 3, -3) . Suffix
MouseTooltip()
return
MouseTooltip(){
GetKeyStates()
ShowKeys(KeyStates . MouseState)
SetTimer ClearMouseState, % -IdleDelay
SetTimer TooltipOff, % -IdleDelay
}
ClearMouseState:
MouseState=
ClickCount=0
return
TooltipOff:
If LargeDisplay
Gui Hide
Else
Tooltip
return
GetKeyStates() {
KeyStates := ""
. ( GetKeyState("LControl", "P") ? "LControl + " : "" )
. ( GetKeyState("RControl", "P") ? "RControl + " : "" )
. ( GetKeyState("LAlt", "P") ? "LAlt + " : "" )
. ( GetKeyState("RAlt", "P") ? "RAlt + " : "" )
. ( GetKeyState("LShift", "P") ? "LShift + " : "" )
. ( GetKeyState("RShift", "P") ? "RShift + " : "" )
. ( GetKeyState("LWin", "P") ? "LWin + " : "" )
. ( GetKeyState("AppsKey", "P") ? "AppsKey + " : "" )
. ( GetKeyState("F1", "P") ? "F1 + " : "" )
. ( GetKeyState("F2", "P") ? "F2 + " : "" )
. ( GetKeyState("F3", "P") ? "F3 + " : "" )
. ( GetKeyState("F4", "P") ? "F4 + " : "" )
. ( GetKeyState("F5", "P") ? "F5 + " : "" )
. ( GetKeyState("F6", "P") ? "F6 + " : "" )
. ( GetKeyState("F7", "P") ? "F7 + " : "" )
. ( GetKeyState("F8", "P") ? "F8 + " : "" )
. ( GetKeyState("F9", "P") ? "F9 + " : "" )
. ( GetKeyState("F10", "P") ? "F10 + " : "" )
. ( GetKeyState("F11", "P") ? "F11 + " : "" )
. ( GetKeyState("F12", "P") ? "F12 + " : "" )
. ( GetKeyState("Left", "P") ? "Left + " : "" )
. ( GetKeyState("Right", "P") ? "Right + " : "" )
. ( GetKeyState("Up", "P") ? "Up + " : "" )
. ( GetKeyState("Down", "P") ? "Down + " : "" )
. ( GetKeyState("Home", "P") ? "Home + " : "" )
. ( GetKeyState("End", "P") ? "End + " : "" )x
. ( GetKeyState("PgUp", "P") ? "PgUp + " : "" )
. ( GetKeyState("PgDn", "P") ? "PgDn + " : "" )
. ( GetKeyState("Del", "P") ? "Del + " : "" )
. ( GetKeyState("Ins", "P") ? "Ins + " : "" )
. ( GetKeyState("BS", "P") ? "BS + " : "" )
. ( GetKeyState("Capslock", "P") ? "Capslock + " : "" )
. ( GetKeyState("Numlock", "P") ? "Numlock + " : "" )
. ( GetKeyState("PrintScreen", "P") ? "PrintScreen + " : "" )
. ( GetKeyState("Pause", "P") ? "Pause + " : "" )
}
ShowKeys(text) {
If LargeDisplay
{
Global blkOsdCtrlName, blkOsdCtrlName2, MonitorLeft, MonitorRight, MonitorBottom, MonitorTop, GUIx, GUIy, GUIh
CoordMode Mouse, Screen
MouseGetPos MouseX, MouseY
If ((!GUIy) || (MouseX >= MonitorLeft && MouseX <= MonitorRight && MouseY >= GUIy && MouseY <= (GUIy+GUIh)) ) {
If (MouseY < (MonitorTop + (MonitorBottom - MonitorTop) / 2) )
GUIy := MonitorBottom - (MonitorBottom - MonitorTop) * 0.2
Else
GUIy := MonitorTop + (MonitorBottom - MonitorTop) * 0.2
}
GuiControl Text, blkOsdCtrlName, %text%
GuiControl Text, blkOsdCtrlName2, %text%
Gui, Show, x%GUIx% y%GUIy% NoActivate
} Else {
Tooltip % text
}
}
Windows cannot access the specified device, path, or file. You may not have the appropriate permissions to access the item.क्या एक्स-फाइल एक स्टैंडअलोन है? या मुझे पहले से AutoHotkey इंस्टॉल करना है?
आप विंडोज़ के साथ आने वाले प्रमुख प्रेस को दिखाने के लिए स्क्रीन कीबोर्ड का उपयोग कर सकते हैं। जब आप अपने भौतिक कीबोर्ड को स्क्रीन पर टाइप करते हैं तो एक हाइलाइट कुंजी कहा जाता है।
प्रस्तुति सूचक विंडोज के लिए माउसपोस का सबसे अच्छा विकल्प है। यह पॉइंटर इफ़ेक्ट, माउस क्लिक इफ़ेक्ट, कीस्ट्रोक्स प्रदान करता है और यहां तक कि आपको स्क्रीन पर स्वतंत्र रूप से आकर्षित करने की अनुमति देता है, लेकिन स्क्रीन को लॉक नहीं करता है। यह वास्तव में कार्यक्रम का एक फायदा है।
PointerFocus आपके कीस्ट्रोक्स प्रदर्शित कर सकता है।
मैंने एक छोटा सा विंडोज ऐप लिखा है जिसका नाम है किप्स । इसमें कुछ प्रमुख समूहों को लुक-एन-फील, डिस्प्ले या अनदेखा करने के लिए नियंत्रण है, यहां तक कि स्थिर पाठ (उदाहरण के लिए अपना खुद का नाम या कंपनी का नाम) भी जोड़ें। क्लिक-थ्रू को अक्षम करने और पॉप-अप को क्लिक-ड्रैग करने से पोजिशनिंग संभव है। ऐसी अन्य विशेषताएँ हैं जिनकी आपको शायद आवश्यकता नहीं है, लेकिन यह ज्यादातर वही है जो आप चाहते हैं।
आप PassMark KeyboardTest (निशुल्क 30 दिन के मूल्यांकन, तब US $ 24.00 की खरीद कर सकते हैं) का उपयोग कर सकते हैं ।
जानकारी के लिए: