एक मैक्रो की जरूरत है जो एक्सेल स्प्रेडशीट में शीट को फिर से चालू कर सकता है [बंद]

Question

मेरे पास कई कार्यपुस्तिकाएँ हैं जिनके पत्रक क्रम में नहीं हैं (जैसे शीट A, C, B)

मुझे एक मैक्रो की आवश्यकता है जो शीट को फिर से व्यवस्थित कर सके ताकि वे क्रम में हों (जैसे शीट ए, बी, सी)।

क्या कोई मेरी सहायता कर सकता है?

Comments

कृपया बताएं कि आपने पहले से क्या प्रयास किया है, क्योंकि यह साइट सहायता प्रदान करने के लिए है न कि कस्टम स्क्रिप्ट।

— Jonno

मुझे यकीन नहीं है कि इस परियोजना के साथ कहां शुरू करना है। मुझे पता है कि शीट कैसे बनाई जाती है लेकिन कोड जो फ्लॉप का उपयोग नहीं करता है वह जानता है कि टैब को कैसे रीऑर्डर करना है। मूल रूप से "अंतिम" टैब के बाद शीट का निर्माण करना, लेकिन यह तय हो गया है। इसलिए जब मैं अपनी चादरें बनाता हूं, तो ऑर्डर पीछे की तरफ होता है। किसी भी मदद की सराहना की है।

— DanM

न केवल जूनो सही है, आपको अपने आप को बेहतर तरीके से समझाने की भी आवश्यकता होगी कि आप क्या कहते हैं चादरें जो क्रम में नहीं हैं "क्या आपका मतलब" ए, सी, बी "लेबल वाले कॉलम में है, या ये शीट्स के टैब पर वास्तविक नाम हैं। स्क्रीन शॉट देने के लिए यह आपके लिए मददगार हो सकता है। कृपया एक नज़र डालें। कैसे पूछें अपने प्रश्न को बेहतर बनाने के लिए कैसे सीखें।

— CharlieRB

आप मैक्रो रिकॉर्ड सुविधा का उपयोग मैन्युअल रूप से वही करने के लिए कर सकते हैं जो आप करना चाहते थे, और आउटपुट को कम से कम आपको सही ट्रैक पर देखने के लिए।

— Jonno

कोई im स्तंभों के बारे में बात नहीं कर रहा है। ये स्वयं चादरों के नाम हैं। इसलिए मेरे पास एक रूटीन है जो पेज बनाता है (A, B, C नाम दिया गया है) लेकिन जब मैं रूटीन चलाता हूं, तो पेज C, B, A के रूप में सामने आते हैं, इसलिए मुझे उन्हें पुनः व्यवस्थित करने की आवश्यकता है ताकि वे A, B, C । पृष्ठ ZZZZZ तक जाते हैं, इसलिए Z के बाद, तो यह AA, BB, आदि चला जाता है क्योंकि मैं VBA में नया हूं, यह सुनिश्चित नहीं है कि इसके साथ कहां से शुरू करें। किसी भी मदद की सराहना करते हैं।

— DanM

Answer 1

यह लघु मैक्रो ऐसा करेगा

हाँ आरोही के लिए

अवरोही के लिए नहीं

Sub Sort_Active_Book()
Dim i As Integer
Dim j As Integer
Dim iAnswer As VbMsgBoxResult
'
' Prompt the user as which direction they wish to
' sort the worksheets.
'
   iAnswer = MsgBox("Sort Sheets in Ascending Order?" & Chr(10) _
     & "Clicking No will sort in Descending Order", _
     vbYesNoCancel + vbQuestion + vbDefaultButton1, "Sort Worksheets")
   For i = 1 To Sheets.Count
      For j = 1 To Sheets.Count - 1
'
' If the answer is Yes, then sort in ascending order.
'
         If iAnswer = vbYes Then
            If UCase$(Sheets(j).Name) > UCase$(Sheets(j + 1).Name) Then
               Sheets(j).Move After:=Sheets(j + 1)
            End If
'
' If the answer is No, then sort in descending order.
'
         ElseIf iAnswer = vbNo Then
            If UCase$(Sheets(j).Name) < UCase$(Sheets(j + 1).Name) Then
               Sheets(j).Move After:=Sheets(j + 1)
            End If
         End If
      Next j
   Next i
End Sub

https://support.microsoft.com/en-us/kb/812386

Comments

धन्यवाद पोत, मैं उस कोड के साथ काम कर सकता हूं। ठीक वही जो मेरे द्वारा खोजा जा रहा था। और माइक्रोसॉफ्ट के लिए लिंक के लिए धन्यवाद, एक तय करने के लिए अपनी साइट की जांच करने के लिए नहीं सोचा था।

— DanM