प्रोग्राम से संबंधित संदर्भ कैसे जोड़ें

Question

मैंने एक प्रोग्राम लिखा है जो स्काइप को चलाता है और जानकारी देता है जब खत्म हो जाता है। Skype4COM.dllSkype के माध्यम से संदेश भेजने के लिए मुझे एक संदर्भ जोड़ना होगा । हमारे पास एक नेटवर्क पर एक दर्जन या तो कंप्यूटर हैं और एक साझा फ़ाइल सर्वर (अन्य चीजों के बीच) है। अन्य सभी कंप्यूटरों को इस प्रोग्राम को चलाने में सक्षम होना चाहिए। मैं हाथ से संदर्भ स्थापित करने से बचने की उम्मीद कर रहा था। मैंने संदर्भ को एक साझा स्थान पर रखने की योजना बनाई थी, और कार्यक्रम चलने पर इसे प्रोग्रामेटिक रूप से जोड़ दिया।

मुझे यह पता नहीं लग सकता है कि VBA का उपयोग करके Excel 2007 में प्रोग्राम के संदर्भ को कैसे जोड़ा जाए। मुझे पता है कि इसे मैन्युअल रूप से कैसे करना है: खोलें VBE --> Tools --> References --> browse --_> File Location and Name। लेकिन यह मेरे उद्देश्यों के लिए बहुत उपयोगी नहीं है। मुझे पता है कि एक्सेस Vb.net में इसे करने के तरीके हैं और इसी तरह के कोड को पॉप-अप किया जाता है, लेकिन मुझे यकीन नहीं है कि मैं इसे समझता हूं, या यदि यह प्रासंगिक है:

ThisWorkbook.VBProject.References.AddFromGuid _
    GUID:="{0002E157-0000-0000-C000-000000000046}", _
    Major:=5, Minor:=3

अब तक प्रस्तुत किए गए समाधानों में, संदर्भ को प्रोग्रामेटिक रूप से जोड़ने के लिए मुझे हाथ से एक संदर्भ जोड़ने और ट्रस्ट सेंटर को बदलने की आवश्यकता होगी - जो केवल संदर्भ जोड़ने से अधिक है। हालांकि मुझे लगता है कि अगर मैं प्रस्तावित समाधानों के साथ गुजरता हूं तो मैं भविष्य के संदर्भों को प्रोग्रामेटिक रूप से जोड़ पाऊंगा। जो शायद इसे प्रयास के लायक बनाता है।

आगे कोई विचार महान होगा।

Comments

आप Excel 2010

— Qbik

पता नहीं क्यों यह फिर से जीवंत हो गया है - लेकिन जल्दी / देर से बंधन पर एक नज़र है। यदि आप एक संदर्भ जोड़ते हैं (या तो हाथ से या प्रोग्रामिक रूप से) तो यह आपके कोड को एक विशिष्ट संस्करण में बाँधता है। उदाहरण के लिए Excel 11 पुस्तकालय Excel 2003 से बंधा हुआ है। यदि आप चाहते हैं तो यह सब अच्छा है, लेकिन अक्सर (विशेष रूप से जहां मैं काम करता हूं) मुझे 2003, 2007 और 2010 को काम करने की आवश्यकता है।

— डैरेन बार्ट्रुप-कुक

Answer 1

ommit

आपकी परियोजनाओं के लिए VBA के माध्यम से संदर्भ जोड़ने के दो तरीके हैं

1) GUID का उपयोग करना

2) सीधे डीएल को संदर्भित करना।

मुझे दोनों को कवर करने दें।

लेकिन पहले ये 3 बातें हैं जिनका आपको ध्यान रखना आवश्यक है

a) मैक्रोज़ को सक्षम किया जाना चाहिए

b) सुरक्षा सेटिंग्स में, सुनिश्चित करें कि "ट्रस्ट बेसिक टू विजुअल बेसिक प्रोजेक्ट" की जाँच की गई है

ग) आपने मैन्युअल रूप से अनुप्रयोग एक्सटेंशन के लिए "Microsoft Visual Basic के लिए संदर्भ" ऑब्जेक्ट सेट किया है

रास्ता 1 (GUID का उपयोग करके)

मैं आमतौर पर इस तरह से बचता हूं क्योंकि मुझे रजिस्ट्री में GUID की खोज करनी है ... जो मुझे LOL से नफरत है। यहाँ GUID पर अधिक ।

विषय: कोड के माध्यम से VBA संदर्भ लाइब्रेरी जोड़ें

लिंक : http://www.vbaexpress.com/kb/getarticle.php?kb_id=267

'Credits: Ken Puls
Sub AddReference()
     'Macro purpose:  To add a reference to the project using the GUID for the
     'reference library

    Dim strGUID As String, theRef As Variant, i As Long

     'Update the GUID you need below.
    strGUID = "{00020905-0000-0000-C000-000000000046}"

     'Set to continue in case of error
    On Error Resume Next

     'Remove any missing references
    For i = ThisWorkbook.VBProject.References.Count To 1 Step -1
        Set theRef = ThisWorkbook.VBProject.References.Item(i)
        If theRef.isbroken = True Then
            ThisWorkbook.VBProject.References.Remove theRef
        End If
    Next i

     'Clear any errors so that error trapping for GUID additions can be evaluated
    Err.Clear

     'Add the reference
    ThisWorkbook.VBProject.References.AddFromGuid _
    GUID:=strGUID, Major:=1, Minor:=0

     'If an error was encountered, inform the user
    Select Case Err.Number
    Case Is = 32813
         'Reference already in use.  No action necessary
    Case Is = vbNullString
         'Reference added without issue
    Case Else
         'An unknown error was encountered, so alert the user
        MsgBox "A problem was encountered trying to" & vbNewLine _
        & "add or remove a reference in this file" & vbNewLine & "Please check the " _
        & "references in your VBA project!", vbCritical + vbOKOnly, "Error!"
    End Select
    On Error GoTo 0
End Sub

---

रास्ता 2 (सीधे dll को संदर्भित करता है)

यह कोड एक संदर्भ जोड़ता है Microsoft VBScript Regular Expressions 5.5

Option Explicit

Sub AddReference()
    Dim VBAEditor As VBIDE.VBE
    Dim vbProj As VBIDE.VBProject
    Dim chkRef As VBIDE.Reference
    Dim BoolExists As Boolean

    Set VBAEditor = Application.VBE
    Set vbProj = ActiveWorkbook.VBProject

    '~~> Check if "Microsoft VBScript Regular Expressions 5.5" is already added
    For Each chkRef In vbProj.References
        If chkRef.Name = "VBScript_RegExp_55" Then
            BoolExists = True
            GoTo CleanUp
        End If
    Next

    vbProj.References.AddFromFile "C:\WINDOWS\system32\vbscript.dll\3"

CleanUp:
    If BoolExists = True Then
        MsgBox "Reference already exists"
    Else
        MsgBox "Reference Added Successfully"
    End If

    Set vbProj = Nothing
    Set VBAEditor = Nothing
End Sub

नोट : मैंने त्रुटि हैंडलिंग नहीं जोड़ी है। यह अनुशंसा की जाती है कि आपके वास्तविक कोड में, इसका उपयोग करें :)

EDIT द्वारा बनाई गई mischab1:)

Comments

तो ऐसा लगता है कि हाथ से संदर्भ जोड़ने के बजाय मुझे हाथ से एक अलग संदर्भ जोड़ने और एक्सेल अनुमतियों को बदलने की आवश्यकता है? दी यह भविष्य में बेहतर होगा, लेकिन यह अब थोड़ा अजीब लगता है।

— ओमित

हाँ, यह मज़ेदार लगता है, लेकिन फिर इस समय यह कैसा है :)

— सिद्धार्थ राउत

बहुत बढ़िया जवाब। FYI करें इसके उपयोगकर्ता, नोटिस करते हैं कि आप अभी भी किसी वर्ड / पॉवरपॉइंट / अन्य ऑब्जेक्ट या Enum को किसी फंक्शन या प्रक्रिया से बाहर का उपयोग नहीं कर सकते हैं क्योंकि कंपाइलर फेल होने से पहले WORKBOOK_OPENईवेंट को निष्पादित करना शुरू कर देगा। इसलिए आप एक सार्वजनिक शब्द ऑब्जेक्ट नहीं बना सकते हैं और आप वर्ड / पीपीटी प्रकार के रूप में एक पैरामीटर के प्रकार को परिभाषित नहीं कर सकते हैं (जैसे आप कुछ ऐसा नहीं कर सकते हैं Sub CopyActiveChartToWord(FormatType as WdPasteDataType))।

— s_a

विंडोज के विभिन्न संस्करणों में कुछ DLL के फ़ोल्डर स्थान अलग-अलग नहीं होंगे? (जैसे विन 8, विन 7, विस्टा, एक्सपी, आदि)। जिस स्थिति में, GUID द्वारा सुरक्षित नहीं किया जाएगा (यदि आपके उपयोगकर्ता विभिन्न Win संस्करणों पर हैं)?

— जॉनी

रिकॉर्ड के लिए, MS स्क्रिप्टिंग रनटाइम के लिए GUID है {420B2830-E718-11CF-893D-00A0C9054228}। आप अन्य GUID को मैन्युअल रूप से जोड़कर पता कर सकते हैं, फिर प्रत्येक के माध्यम से पाशन कर सकते हैं Ref ThisWorkbook.VBProject.Referencesऔर उपयोग कर सकते हैंDebug.Print Ref.Name, Ref.Guid

— हवाई-

Answer 2

VBA का उपयोग करके संदर्भ जोड़ने के दो तरीके हैं। .AddFromGuid(Guid, Major, Minor)और .AddFromFile(Filename)। कौन सा सबसे अच्छा है इस पर निर्भर करता है कि आप किस संदर्भ को जोड़ने की कोशिश कर रहे हैं। मैं लगभग हमेशा उपयोग .AddFromFileकरता हूं क्योंकि मैं जिन चीजों का संदर्भ दे रहा हूं वे अन्य एक्सेल वीबीए प्रोजेक्ट हैं और वे विंडोज रजिस्ट्री में नहीं हैं।

आप जिस उदाहरण कोड को दिखा रहे हैं, वह उस कार्यपुस्तिका का एक संदर्भ जोड़ देगा, जिसमें कोड है। मैं आमतौर पर ऐसा करने में कोई बिंदु नहीं देखता क्योंकि 90% समय, इससे पहले कि आप संदर्भ जोड़ सकें, कोड पहले ही संकलित करने में विफल रहा है क्योंकि संदर्भ गायब है। (और अगर यह विफल-से-संकलन नहीं हुआ, तो आप शायद देर से बाध्यकारी का उपयोग कर रहे हैं और आपको एक संदर्भ जोड़ने की आवश्यकता नहीं है।)

यदि आपको कोड चलाने में समस्या आ रही है, तो दो संभावित मुद्दे हैं।

1. VBE के ऑब्जेक्ट मॉडल को आसानी से उपयोग करने के लिए, आपको एप्लिकेशन एक्स्टेंसिबिलिटी के लिए Microsoft Visual Basic का संदर्भ जोड़ना होगा । (VBIDE)
2. किसी VBProject में कुछ भी बदलने वाले Excel VBA कोड को चलाने के लिए, आपको VBA प्रोजेक्ट ऑब्जेक्ट मॉडल पर पहुंच पर भरोसा करना होगा । (एक्सेल 2010 में, यह ट्रस्ट सेंटर - मैक्रो सेटिंग्स में स्थित है।)

इसके अलावा, यदि आप थोड़ा और अधिक स्पष्ट हो सकते हैं कि आपका प्रश्न क्या है या आप क्या करने की कोशिश कर रहे हैं जो काम नहीं कर रहा है, तो मैं और अधिक विशिष्ट उत्तर दे सकता हूं।

Answer 3

मार्गदर्शक या पथ का उपयोग करने के लिए रजिस्ट्री ब्राउज़ करना, कौन सी विधि सर्वोत्तम है। यदि रजिस्ट्री ब्राउज़ करना अब आवश्यक नहीं है, तो क्या यह गाइड का उपयोग करने का बेहतर तरीका नहीं होगा? कार्यालय हमेशा एक ही निर्देशिका में स्थापित नहीं होता है। स्थापना पथ को मैन्युअल रूप से परिवर्तित किया जा सकता है। इसके अलावा संस्करण संख्या पथ का एक हिस्सा है। मैं कभी भी यह अनुमान नहीं लगा सकता था कि 64 बिट्स प्रोसेसर के आने से पहले Microsoft कभी भी 'प्रोग्राम फाइल्स' में 'x86' जोड़ देगा। यदि संभव हो तो मैं एक मार्ग का उपयोग करने से बचने की कोशिश करूंगा।

नीचे दिए गए कोड को सिद्धार्थ राउत के उत्तर से लिया गया है, जो सक्रिय कार्यपुस्तिका में उपयोग किए जाने वाले सभी संदर्भों को सूचीबद्ध करने के लिए एक अतिरिक्त फ़ंक्शन के साथ है। अगर मैं एक्सेल के बाद के संस्करण में अपनी कार्यपुस्तिका खोलता हूं तो क्या होगा? क्या वर्कबुक अभी भी VBA कोड को अडॉप्ट किए बिना काम करेगा? मैंने पहले ही जाँच कर ली है कि कार्यालय 2003 और 2010 के लिए छापे समान हैं। चलो आशा करते हैं कि Microsoft भविष्य के संस्करणों में छापे नहीं बदले।

तर्क 0,0 (से .AddFromGuid) एक संदर्भ के नवीनतम संस्करण का उपयोग करना चाहिए (जिसे मैं परीक्षण करने में सक्षम नहीं हुआ हूं)।

आपके क्या विचार हैं? बेशक हम भविष्य का अनुमान नहीं लगा सकते लेकिन हम अपने कोड संस्करण को प्रमाण बनाने के लिए क्या कर सकते हैं?

Sub AddReferences(wbk As Workbook)
    ' Run DebugPrintExistingRefs in the immediate pane, to show guids of existing references
    AddRef wbk, "{00025E01-0000-0000-C000-000000000046}", "DAO"
    AddRef wbk, "{00020905-0000-0000-C000-000000000046}", "Word"
    AddRef wbk, "{91493440-5A91-11CF-8700-00AA0060263B}", "PowerPoint"
End Sub

Sub AddRef(wbk As Workbook, sGuid As String, sRefName As String)
    Dim i As Integer
    On Error GoTo EH
    With wbk.VBProject.References
        For i = 1 To .Count
            If .Item(i).Name = sRefName Then
               Exit For
            End If
        Next i
        If i > .Count Then
           .AddFromGuid sGuid, 0, 0 ' 0,0 should pick the latest version installed on the computer
        End If
    End With
EX: Exit Sub
EH: MsgBox "Error in 'AddRef'" & vbCrLf & vbCrLf & err.Description
    Resume EX
    Resume ' debug code
End Sub

Public Sub DebugPrintExistingRefs()
    Dim i As Integer
    With Application.ThisWorkbook.VBProject.References
        For i = 1 To .Count
            Debug.Print "    AddRef wbk, """ & .Item(i).GUID & """, """ & .Item(i).Name & """"
        Next i
    End With
End Sub

ऊपर दिए गए कोड को अब "Microsoft Visual Basic for Applications Extensibility" ऑब्जेक्ट के संदर्भ की आवश्यकता नहीं है।

Comments

ध्यान दें कि आपके पास मैक्रोज़ सक्षम होना चाहिए और ट्रस्ट एक्सेस टू विज़ुअल बेसिक प्रोजेक्ट चेक किया हुआ है ( @Siddharth_Rout से उत्तर में a और b ), लेकिन VBIDE संदर्भ को समाप्त करने के लिए +1! इसके अलावा, मैं सराहना करता हूं कि DebugPrintExistingRefs इसे कोड में पंक्ति को कॉपी और पेस्ट करने के प्रारूप में आउटपुट करता है।

— ग्लेनफ्रॉमियावा

Answer 4

यहाँ कैसे गाइड प्रोग्राम प्राप्त करने के लिए है! फिर आप संदर्भ जोड़ने के लिए उपरोक्त उत्तर के साथ इन guids / filepaths का उपयोग कर सकते हैं!

संदर्भ: http://www.vbaexpress.com/kb/getarticle.php?kb_id=278

Sub ListReferencePaths()
'Lists path and GUID (Globally Unique Identifier) for each referenced library.
'Select a reference in Tools > References, then run this code to get GUID etc.
    Dim rw As Long, ref
    With ThisWorkbook.Sheets(1)
        .Cells.Clear
        rw = 1
        .Range("A" & rw & ":D" & rw) = Array("Reference","Version","GUID","Path")
        For Each ref In ThisWorkbook.VBProject.References
            rw = rw + 1
            .Range("A" & rw & ":D" & rw) = Array(ref.Description, _
                   "v." & ref.Major & "." & ref.Minor, ref.GUID, ref.FullPath)
        Next ref
        .Range("A:D").Columns.AutoFit
    End With
End Sub

यहाँ एक ही कोड है, लेकिन अगर आप किसी कार्यपत्रक को आउटपुट में समर्पित नहीं करना चाहते हैं तो टर्मिनल को प्रिंट करना है।

Sub ListReferencePaths() 
 'Macro purpose:  To determine full path and Globally Unique Identifier (GUID)
 'to each referenced library.  Select the reference in the Tools\References
 'window, then run this code to get the information on the reference's library

On Error Resume Next 
Dim i As Long 

Debug.Print "Reference name" & " | " & "Full path to reference" & " | " & "Reference GUID" 

For i = 1 To ThisWorkbook.VBProject.References.Count 
  With ThisWorkbook.VBProject.References(i) 
    Debug.Print .Name & " | " & .FullPath  & " | " & .GUID 
  End With 
Next i 
On Error GoTo 0 
End Sub