क्या एक विंडोज़ बैच फ़ाइल अपना खुद का फ़ाइल नाम निर्धारित कर सकती है?

Question

क्या एक विंडोज़ बैच फ़ाइल अपना खुद का फ़ाइल नाम निर्धारित कर सकती है?

उदाहरण के लिए, अगर मैं बैच फ़ाइल C: \ Temp \ myScript.bat चलाता हूं, तो क्या myScript.bat के भीतर एक कमांड है जो स्ट्रिंग "myScript.bat" को निर्धारित कर सकती है?

Comments

%0वह है जो आप ढूंढ रहे हैं। देखें [यह सवाल] [1] अधिक के लिए। [१]: stackoverflow.com/questions/357315/…

— जोनाथन रेइनहार्ट

हां, यही मैं ढूंढ रहा था। % ~ nx0 उत्तर है।

— djangofan

Answer 1

हाँ।

%0वर्तमान फ़ाइल का पथ प्राप्त करने के लिए विशेष चर का उपयोग करें ।

%~n0एक्सटेंशन के बिना सिर्फ फ़ाइल नाम प्राप्त करने के लिए लिखें ।

%~n0%~x0फ़ाइल नाम और एक्सटेंशन प्राप्त करने के लिए लिखें ।

%~nx0फ़ाइल नाम और एक्सटेंशन प्राप्त करने के लिए भी लिखना संभव है ।

Comments

यह सिर्फ गलत है। % 0 और% ~ n0 दोनों को केवल फ़ाइल नाम भाग मिलता है। @djangofan का उत्तर सही है।

— जस्टजेफ

% 0 उस तरह से रिटर्न करता है जिस तरह से फाइल को बुलाया गया था। यदि पूर्ण पथ का उपयोग किया गया था, तो% 0 में वह होगा। यदि आप cdपहले dir में जाते हैं और वहां से बैच निष्पादित करते हैं, तो% 0 में आमतौर पर पथ जानकारी नहीं होगी (लेकिन आप उस स्थिति में% cd% से प्राप्त कर सकते हैं)

— Gogowitsch

@gogowitsch: क्या आपको यकीन है? मुझे नहीं लगता कि यह सच है।

— SLAKs

Win2012 पर, %cd% प्रक्रिया की वर्तमान निर्देशिका को वापस करेगा जो बैच फ़ाइल कहलाती है। इसलिए, यदि आप एक संकेत में कर रहे हैं D:\dir1और प्रवेश Y:\foo\bar.bat, अगर bar.batहै @echo %cd%यह उत्पादन होगा तो D:\dir1।

— उपदेशक

Answer 2

आप फ़ाइल का नाम प्राप्त कर सकते हैं, लेकिन आप '% ~' और '0' के बीच जो जगह रखते हैं, उसके आधार पर आप पूर्ण पथ भी प्राप्त कर सकते हैं। से अपना लो

d -- drive
p -- path
n -- file name
x -- extension
f -- full path

जैसे, अंदर से c: \ tmp \ foo.bat, %~nx0आपको "foo.bat" %~dpnx0देता है , जबकि "c: \ tmp \ foo.bat" देता है। ध्यान दें कि टुकड़े हमेशा विहित क्रम में इकट्ठे होते हैं, इसलिए यदि आप प्यारे हो जाते हैं और कोशिश करते हैं %~xnpd0, तो भी आपको "c: \ tmp \ foo.bat" मिलता है।

Comments

आपके कोड ब्लॉक में, आप कहते हैं कि fफ़ाइल का नाम है, लेकिन आपके उदाहरणों में आप nफ़ाइल नाम के लिए उपयोग करते हैं । कुछ परीक्षण के बाद, ऐसा लगता है कि fपूर्ण पथ है, और nफ़ाइल नाम है।

— चपिन

@druciferre, मैंने आपकी टिप्पणी के अनुसार उत्तर संपादित किया

— रोबोटिक

"अगर तुम प्यारे हो जाओ और कोशिश करो %~xnpd0" ... मैं तुमसे प्यार करता हूँ।

— मार्क देवेन

Answer 3

SLaks उत्तर पर आधारित निम्नलिखित स्क्रिप्ट का उपयोग करते हुए, मैंने निर्धारित किया कि सही उत्तर है:

echo The name of this file is: %~n0%~x0
echo The name of this file is: %~nx0

और यहाँ मेरी टेस्ट स्क्रिप्ट है:

@echo off
echo %0
echo %~0
echo %n0
echo %x0
echo %~n0
echo %dp0
echo %~dp0
pause

मुझे जो दिलचस्प लगा वह यह है कि % nx0 काम नहीं करेगा, यह देखते हुए कि हम जानते हैं कि '~' वर्ण का प्रयोग आमतौर पर किसी चर के उद्धरण / छाँट के लिए किया जाता है।

Answer 4

ध्यान रखें कि 0एक बैच फ़ाइल, अंदर पैरामीटर नंबर की एक विशेष मामला है जहां 0साधन इस फाइल को कमांड लाइन पर दिए गए ।

इसलिए यदि फ़ाइल myfile.bat है, तो आप इसे कई तरीकों से कॉल कर सकते हैं, जिनमें से प्रत्येक आपको या उपयोग से एक अलग आउटपुट देगा :%0%~0

myfile

myfile.bat

mydir\myfile.bat

c:\mydir\myfile.bat

"c:\mydir\myfile.bat"

उपरोक्त सभी कानूनी कॉल हैं यदि आप इसे सही रिश्तेदार जगह से उस निर्देशिका में कहते हैं जिसमें यह मौजूद है। %~0पिछले उदाहरण से उद्धरण स्ट्रिप्स, जबकि%0 नहीं है।

क्योंकि ये सभी अलग-अलग परिणाम देते हैं, %0 और%~0 हैं आप जो वास्तव में उपयोग करना चाहते हैं वह होने की बहुत संभावना नहीं है।

यहाँ वर्णन करने के लिए एक बैच फ़ाइल है:

@echo Full path and filename: %~f0
@echo Drive: %~d0
@echo Path: %~p0
@echo Drive and path: %~dp0
@echo Filename without extension: %~n0
@echo Filename with    extension: %~nx0
@echo Extension: %~x0
@echo Filename as given on command line: %0
@echo Filename as given on command line minus quotes: %~0
@REM Build from parts
@SETLOCAL
@SET drv=%~d0
@SET pth=%~p0
@SET fpath=%~dp0
@SET fname=%~n0
@SET ext=%~x0
@echo Simply Constructed name: %fpath%%fname%%ext%
@echo Fully  Constructed name: %drv%%pth%%fname%%ext%
@ENDLOCAL
pause

Answer 5

जादुई चर कैसे काम करते हैं, यह महसूस करने के लिए नीचे दिए गए उदाहरण को चलाने का प्रयास करें।

@echo off

SETLOCAL EnableDelayedExpansion

echo Full path and filename: %~f0
echo Drive: %~d0
echo Path: %~p0
echo Drive and path: %~dp0
echo Filename without extension: %~n0
echo Filename with    extension: %~nx0
echo Extension: %~x0

echo date time : %~t0
echo file size: %~z0

ENDLOCAL

संबंधित नियम का पालन कर रहे हैं।

%~I         - expands %I removing any surrounding quotes ("")
%~fI        - expands %I to a fully qualified path name
%~dI        - expands %I to a drive letter only
%~pI        - expands %I to a path only
%~nI        - expands %I to a file name only
%~xI        - expands %I to a file extension only
%~sI        - expanded path contains short names only
%~aI        - expands %I to file attributes of file
%~tI        - expands %I to date/time of file
%~zI        - expands %I to size of file
%~$PATH:I   - searches the directories listed in the PATH
               environment variable and expands %I to the
               fully qualified name of the first one found.
               If the environment variable name is not
               defined or the file is not found by the
               search, then this modifier expands to the
               empty string

Answer 6

नीचे मेरा प्रारंभिक कोड है:

@echo off
Set z=%%
echo.
echo %z%0.......%0
echo %z%~0......%~0
echo %z%n0......%n0
echo %z%x0......%x0
echo %z%~n0.....%~n0
echo %z%dp0.....%dp0
echo %z%~dp0....%~dp0
echo.

मैंने देखा कि फ़ाइल नाम% ~ 0 और% 0 द्वारा दिया गया है जिस तरह से इसे कमांड-शेल में दर्ज किया गया था और न कि उस फ़ाइल का नाम वास्तव में कैसे रखा गया था। इसलिए यदि आप फ़ाइल नाम के लिए प्रयुक्त शाब्दिक मामला चाहते हैं तो आपको% ~ n0 का उपयोग करना चाहिए। हालाँकि, यह फ़ाइल एक्सटेंशन को छोड़ देगा। लेकिन अगर आपको पता है कि फ़ाइल का नाम आप निम्नलिखित कोड जोड़ सकते हैं।

set b=%~0
echo %~n0%b:~8,4%

मैंने सीखा है कि ": ~ 8,4%" का मतलब चर के 9 वें वर्ण से शुरू होता है और फिर अगले 4 वर्ण दिखाते हैं। चर स्ट्रिंग के अंत में सीमा 0 है। तो% पाथ% बहुत लंबा होगा!

fIlEnAmE.bat
012345678901

हालांकि, यह ऊपर के समाधान के रूप में ध्वनि (% ~ x0) के रूप में ध्वनि नहीं है।

मेरा साक्ष्य:

C:\bin>filename.bat

%0.......filename.bat
%~0......filename.bat
. . .

C:\bin>fIlEnAmE.bat

%0.......fIlEnAmE.bat
%~0......fIlEnAmE.bat
%n0......n0
%x0......x0
%~n0.....FileName
%dp0.....dp0
%~dp0....C:\bin\

%~n0%b:~8,4%...FileName.bat

Press any key to continue . . .

C:\bin>dir
 Volume in drive C has no label.
 Volume Serial Number is CE18-5BD0

 Directory of C:\bin
. . .
05/02/2018  11:22 PM               208 FileName.bat

---

यहाँ अंतिम कोड है

@echo off
Set z=%%
set b=%~0
echo.
echo %z%0.......%0
echo %z%~0......%~0
echo %z%n0......%n0
echo %z%x0......%x0
echo %z%~n0.....%~n0
echo %z%dp0.....%dp0
echo %z%~dp0....%~dp0
echo.
echo A complex solution:
echo ===================================
echo %z%~n0%z%b:~8,4%z%...%~n0%b:~8,4%
echo ===================================
echo.
echo The preferred solution:
echo ===================================
echo %z%~n0%z%~x0.......%~n0%~x0
echo ===================================
pause