मैंने विशाल MS DOS बैच फ़ाइल लिखी है। इस बैच फ़ाइल का परीक्षण करने के लिए मुझे केवल कुछ लाइनों को निष्पादित करना होगा और शेष को छिपाना / टिप्पणी करना होगा।
मेरे पास कुछ मौजूदा टिप्पणी लाइनें हैं, ::इसलिए मैं ::अब इसका उपयोग नहीं कर सकता क्योंकि यह सभी टिप्पणियों को परिमार्जन करेगा।
इस समस्या का समाधान किस प्रकार से किया जा सकता है?
जवाबों:
आप एक gotoसे अधिक कोड को छोड़ कर उपयोग कर सकते हैं ।
goto comment
...skip this...
:comment
REMलाइनों को टिप्पणी लाइनों के रूप में स्वीकार नहीं कर सकता , यह आउटपुट को अस्पष्ट बनाता है
यदि आप GOTO का उपयोग करने के बजाय प्रत्येक पंक्ति की शुरुआत में REM जोड़ना चाहते हैं, तो आप इन चरणों का आसानी से पालन करने के लिए नोटपैड ++ का उपयोग कर सकते हैं:
पुनरावृत्ति के चरणों को दोहराएं
Ctrl-Q, में क्लिक करें Notepad++: Edit -> Comment/Uncomment।
break||(
code that cannot contain non paired closing bracket
)
जबकि gotoसमाधान एक अच्छा विकल्प है, यह कोष्ठक (फॉर और आईएफ कमांड सहित) के भीतर काम नहीं करेगा। लेकिन यह होगा। यद्यपि आपको कोष्ठक और अमान्य सिंटैक्स को बंद करने FORऔर IFआदेशों के बारे में सावधान रहना चाहिए क्योंकि उन्हें पार्स किया जाएगा।
अपडेट करें
डेंभम के जवाब में अपडेट ने मुझे कुछ विचार दिए। पहला - दो अलग-अलग मामले हैं जहां हमें मल्टी लाइन टिप्पणियों की आवश्यकता हो सकती है - एक ब्रैकेट के संदर्भ में जहां GOTO का उपयोग नहीं किया जा सकता है और इसके बाहर। ब्रैकेट्स के संदर्भ में हम एक और कोष्ठक का उपयोग कर सकते हैं यदि कोई ऐसी स्थिति है जो कोड को निष्पादित करने से रोकती है। तब भी कोड थ्रेड को पार्स किया जाएगा और कुछ सिंटैक्स त्रुटियों का पता लगाया जाएगा ( FORऔर IF, अनुचित रूप से बंद ब्रैकेट, गलत पैरामीटर विस्तार ..)। यदि यह संभव है तो GOTO का उपयोग करना बेहतर होगा।
यद्यपि यह एक लेबल के रूप में उपयोग किए जाने वाले मैक्रो / वैरिएबल को बनाना संभव नहीं है - लेकिन ब्रैकेट की टिप्पणियों के लिए मैक्रोज़ का उपयोग करना संभव है। दो ट्रिक का उपयोग किया जा सकता है गोटो टिप्पणियों को अधिक सममित और अधिक मनभावन (कम से कम मेरे लिए) बना सकते हैं। इसके लिए मैं दो तरकीबों का उपयोग करूंगा - 1) आप एक लेबल के सामने एक एकल चिह्न रख सकते हैं और गोटो अभी भी इसे ढूंढने में सक्षम होगा (मुझे नहीं पता कि यह क्यों है। मेरे लिए यह एक ड्राइव की खोज है)। 2) आप :
एक वैरिएबल नाम के अंत में एक सिंगल रख सकते हैं और एक रिप्लेसमेंट / सबट्रिंग फीचर को ट्रिगर नहीं किया जाएगा (यहां तक कि सक्षम किए गए अंडर में भी)। कोष्ठक टिप्पणियों के लिए मैक्रों के साथ संयुक्त विच दोनों मामलों को लगभग समान देख सकता है।
यहाँ उदाहरण हैं (क्रम में मैं उन्हें सबसे अधिक पसंद करता हूँ):
आयताकार कोष्ठक के साथ :
@echo off
::GOTO comment macro
set "[:=goto :]%%"
::brackets comment macros
set "[=rem/||(" & set "]=)"
::testing
echo not commented 1
%[:%
multi
line
comment outside of brackets
%:]%
echo not commented 2
%[:%
second multi
line
comment outside of brackets
%:]%
::GOTO macro cannot be used inside for
for %%a in (first second) do (
echo first not commented line of the %%a execution
%[%
multi line
comment
%]%
echo second not commented line of the %%a execution
)
घुंघराले कोष्ठक के साथ :
@echo off
::GOTO comment macro
set "{:=goto :}%%"
::brackets comment macros
set "{=rem/||(" & set "}=)"
::testing
echo not commented 1
%{:%
multi
line
comment outside of brackets
%:}%
echo not commented 2
%{:%
second multi
line
comment outside of brackets
%:}%
::GOTO macro cannot be used inside for loop
for %%a in (first second) do (
echo first not commented line of the %%a execution
%{%
multi line
comment
%}%
echo second not commented line of the %%a execution
)
कोष्ठक के साथ :
@echo off
::GOTO comment macro
set "(:=goto :)%%"
::brackets comment macros
set "(=rem/||(" & set ")=)"
::testing
echo not commented 1
%(:%
multi
line
comment outside of brackets
%:)%
echo not commented 2
%(:%
second multi
line
comment outside of brackets
%:)%
::GOTO macro cannot be used inside for loop
for %%a in (first second) do (
echo first not commented line of the %%a execution
%(%
multi line
comment
%)%
echo second not commented line of the %%a execution
)
शक्तियां और सी शैलियों के बीच मिश्रण ( <इसका उपयोग नहीं किया जा सकता क्योंकि पुनर्निर्देशन उच्चतर पुजारियों के साथ है। *इसका उपयोग नहीं किया जा सकता है %*):
@echo off
::GOTO comment macro
set "/#:=goto :#/%%"
::brackets comment macros
set "/#=rem/||(" & set "#/=)"
::testing
echo not commented 1
%/#:%
multi
line
comment outside of brackets
%:#/%
echo not commented 2
%/#:%
second multi
line
comment outside of brackets
%:#/%
::GOTO macro cannot be used inside for loop
for %%a in (first second) do (
echo first not commented line of the %%a execution
%/#%
multi line
comment
%#/%
echo second not commented line of the %%a execution
)
करने के लिए emphase कि एक टिप्पणी है (सोचा था कि यह इतना कम नहीं है):
@echo off
::GOTO comment macro
set "REM{:=goto :}REM%%"
::brackets comment macros
set "REM{=rem/||(" & set "}REM=)"
::testing
echo not commented 1
%REM{:%
multi
line
comment outside of brackets
%:}REM%
echo not commented 2
%REM{:%
second multi
line
comment outside of brackets
%:}REM%
::GOTO macro cannot be used inside for
for %%a in (first second) do (
echo first not commented line of the %%a execution
%REM{%
multi line
comment
%}REM%
echo second not commented line of the %%a execution
)
rem.||(कर सकते हैं या rem^ (इसके बजाय। आशय थोड़ा स्पष्ट है। देखिये मेरा अपडेटेड जवाब।
%rem:%+ %:rem%रूप को भी शामिल कर सकता हूं इसे और अधिक स्पष्ट बनाने के लिए हालांकि यह ढीली हो जाएगी। केवल सी-स्टाइल के करीब होने के लिए स्लैश ...
एक अन्य विकल्प एक IF ब्लॉक में अवांछित लाइनों को घेरना है जो कभी भी सच नहीं हो सकता है
if 1==0 (
...
)
बेशक, अगर ब्लॉक को निष्पादित नहीं किया जाएगा, लेकिन इसमें कुछ भी नहीं होगा। इसलिए आपके पास कोई अमान्य सिंटैक्स नहीं हो सकता है। इसके अलावा, टिप्पणी में )यह तब तक शामिल नहीं हो सकता जब तक कि वह बच न जाए या उद्धृत न हो। उन कारणों के लिए स्वीकृत GOTO समाधान अधिक विश्वसनीय है। (GOTO समाधान भी तेज हो सकता है)
अद्यतन 2017-09-19
यहाँ pdub के GOTO समाधान के लिए एक कॉस्मेटिक वृद्धि है । मैं एक साधारण पर्यावरण चर "मैक्रो" को परिभाषित करता हूं जो GOTO टिप्पणी को वाक्यविन्यास को थोड़ा बेहतर स्व-दस्तावेजीकरण बनाता है। हालांकि यह आमतौर पर सिफारिश की जाती है कि: लेबल एक बैच स्क्रिप्ट के भीतर अद्वितीय हैं, यह वास्तव में एक ही बैच स्क्रिप्ट के भीतर इस तरह से कई टिप्पणियों को एम्बेड करने के लिए ठीक है।
@echo off
setlocal
set "beginComment=goto :endComment"
%beginComment%
Multi-line comment 1
goes here
:endComment
echo This code executes
%beginComment%
Multi-line comment 2
goes here
:endComment
echo Done
या आप npocmaka के समाधान के इन प्रकारों में से एक का उपयोग कर सकते हैं । BREAK के बजाय REM का उपयोग इरादे को थोड़ा साफ करता है।
rem.||(
remarks
go here
)
rem^ ||(
The space after the caret
is critical
)
केवल यह उल्लेख करना चाहते हैं कि pdub का GOTO समाधान पूरी तरह से सही नहीं है: कई बार टिप्पणी लेबल दिखाई देता है। मैं उदाहरण के रूप में इस प्रश्न से कोड को संशोधित करता हूं ।
@ECHO OFF
SET FLAG=1
IF [%FLAG%]==[1] (
ECHO IN THE FIRST IF...
GOTO comment
ECHO "COMMENT PART 1"
:comment
ECHO HERE AT TD_NEXT IN THE FIRST BLOCK
)
IF [%FLAG%]==[1] (
ECHO IN THE SECOND IF...
GOTO comment
ECHO "COMMENT PART"
:comment
ECHO HERE AT TD_NEXT IN THE SECOND BLOCK
)
आउटपुट होगा
IN THE FIRST IF...
HERE AT TD_NEXT IN THE SECOND BLOCK
कमांड ECHO यहाँ FIRST ब्लॉक में TD_NEXT पर छोड़ दी गई है।
@jeb
और इसे इस्तेमाल करने के बाद, स्टाडर दुर्गम होने लगता है
नहीं, यह प्रयास करें:
@echo off 2>Nul 3>Nul 4>Nul
ben ali
mubarak 2>&1
gadeffi
..next ?
echo hello Tunisia
pause
लेकिन यह काम क्यों करता है?
क्षमा करें, मैं frensh में सवाल का जवाब:
(la redirection par 3> est spécial car elle persiste, va l'utiliser pour capturer le flux des erreurs 2> est on va le ट्रांसफार्मर en un flux persistant à l'ade 3> ceci va nous permettre d'avoir une gestion des erreur pour tout notre environement de script ..par la Suite si on veux recuperer le flux 'stderr' il faut faire une autre redirection du handle 2> au handle 1 - qui n'est autre que la कंसोल ..)
इसे इस्तेमाल करे:
@echo off 2>Nul 3>Nul 4>Nul
ben ali
mubarak
gadeffi
..next ?
echo hello Tunisia
pause