NerdTree - पेड़ में फ़ाइल का पता चलता है

Question

क्या कोई शॉर्टकट है जो NerdTree निर्देशिका पैनल में वर्तमान फ़ाइल को प्रकट करता है।

जैसे TextMate 'दराज में फ़ाइल का पता लगाएं' - Ctrl + कमांड + आर

Answer 1

में: h NERDTree:

:NERDTreeFind                                                  :NERDTreeFind
    Find the current file in the tree. If no tree exists for the current tab,
    or the file is not under the current root, then initialize a new tree where
    the root is the directory of the current file.

मुझे नहीं लगता कि यह डिफ़ॉल्ट रूप से किसी भी चीज के लिए बाध्य है, इसलिए आपको खुद को कीबाइंड करना होगा।

nmap ,n :NERDTreeFind<CR>

मेरे साथ .vimrc में क्या दिखाई देता है

nmap ,m :NERDTreeToggle<CR>

Comments

कीपिंग काम करता है, लेकिन विम के भीतर NERDTreeFind कैसे लागू करें?

— अज़ातार 21

@toszter बस:NERDTreeFind

— थॉमस

क्या ऐसा करने के लिए इसे सेट करने का कोई तरीका है जब भी NERDTree उस टैब के भीतर बनाया गया हो?

— श्री मिकेल

@ क्या आप केवल NERDTreeFind कमांड के साथ NERDTree बना सकते हैं - क्या यह पर्याप्त है?

— थॉमस

Answer 2

इसे देखें, यह सिंक ऑपरेशन को स्वचालित करता है, जब भी आप बफर बदलते हैं, तो nddtree स्वतः ही ताज़ा हो जाएगा (मैंने छोटे संशोधनों के साथ यहां से कॉपी की है )

" Check if NERDTree is open or active
function! IsNERDTreeOpen()        
  return exists("t:NERDTreeBufName") && (bufwinnr(t:NERDTreeBufName) != -1)
endfunction

" Call NERDTreeFind iff NERDTree is active, current window contains a modifiable
" file, and we're not in vimdiff
function! SyncTree()
  if &modifiable && IsNERDTreeOpen() && strlen(expand('%')) > 0 && !&diff
    NERDTreeFind
    wincmd p
  endif
endfunction

" Highlight currently open buffer in NERDTree
autocmd BufEnter * call SyncTree()

Comments

धन्यवाद, मैं इसे इतने लंबे समय से देख रहा था! :)

— ग्नगनो

यह कॉन्फिग ज्यादातर मामलों में अच्छी तरह से काम करता है लेकिन यह सब कुछ गड़बड़ कर देता है जब मैंने coc.nvim का उपयोग संदर्भ कार्यक्षमता में जाता है। निर्धारित समस्या के BufReadस्थान पर ईवेंट का उपयोग करना BufEnter।

— एडी कौरो

Answer 3

यह भी शायद सिर्फ एक टिप्पणी होनी चाहिए। वर्तमान संस्करण के साथ NerdTree को शुरू करने और सिंकट्री का उपयोग करने से NERDTree को दो बार आमंत्रित किया जाता है। यह संशोधन उस समस्या को ठीक करता है:

" Check if NERDTree is open or active
function! IsNERDTreeOpen()
  return exists("t:NERDTreeBufName") && (bufwinnr(t:NERDTreeBufName) != -1)
endfunction

" Call NERDTreeFind iff NERDTree is active, current window contains a modifiable
" file, and we're not in vimdiff
function! SyncTree()
  if &modifiable && IsNERDTreeOpen() && strlen(expand('%')) > 0 && !&diff
    NERDTreeFind
    wincmd p
  endif
endfunction

" Highlight currently open buffer in NERDTree
autocmd BufEnter * call SyncTree()

function! ToggleNerdTree()
  set eventignore=BufEnter
  NERDTreeToggle
  set eventignore=
endfunction
nmap <C-n> :call ToggleNerdTree()<CR>

Answer 4

चेन रुशन के पोस्ट के साथ जाने के लिए, ऑटोकैड बुफनेटर * कॉल सिंकट्री () एनईआरडीट्री को बंद नहीं होने देगा। मुझे ऐसा कोई हल नहीं मिला (नीचे के अलावा) जो NERDTree में NogDTree को टॉगल की अनुमति देते समय वर्तमान खुले बफर को उजागर करेगा।

नीचे मैंने NERDTree को चालू करने में सक्षम होने के लिए एक साथ स्क्रैप किया है और मेरी अगली बफर मैपिंग के लिए Ctrl +] का उपयोग करते हुए हाइलाइट की गई फाइलें हैं।

उम्मीद है कि अन्य लोग इसमें सुधार कर सकते हैं।

"Buffers
set hidden

function! IsNERDTreeOpen()        
  return exists("t:NERDTreeBufName") && (bufwinnr(t:NERDTreeBufName) != -1)
endfunction

function! NextBuffer()
     bnext
  if IsNERDTreeOpen() 
       NERDTreeFind
       wincmd p
  endif
endfunction

nnoremap <c-]> <Esc>:call NextBuffer()<CR>

function! PrevBuffer()
     bprev
  if IsNERDTreeOpen() 
       NERDTreeFind
       wincmd p
  endif
endfunction

nnoremap <c-[> <Esc>:call PrevBuffer()<CR>

function! ToggleNT()
    NERDTreeToggle
endfunction

map <c-u> <Esc>:call ToggleNT()<cr>

Answer 5

चेन रुशन का जवाब + टिप्पणी मेरे लिए पूरी तरह से अच्छी तरह से काम करती है सिवाय इसके कि जब पेड़ सक्रिय हो जाए। यह सेटिंग ट्री ओपन होने पर पेड़ में करंट फाइल को प्रकट करेगी।

" Check if NERDTree is open or active
function! IsNERDTreeOpen()
  return exists("t:NERDTreeBufName") && (bufwinnr(t:NERDTreeBufName) != -1)
endfunction

function! CheckIfCurrentBufferIsFile()
  return strlen(expand('%')) > 0
endfunction

" Call NERDTreeFind iff NERDTree is active, current window contains a modifiable
" file, and we're not in vimdiff
function! SyncTree()
  if &modifiable && IsNERDTreeOpen() && CheckIfCurrentBufferIsFile() && !&diff
    NERDTreeFind
    wincmd p
  endif
endfunction

" Highlight currently open buffer in NERDTree
autocmd BufRead * call SyncTree()

function! ToggleTree()
  if CheckIfCurrentBufferIsFile()
    if IsNERDTreeOpen()
      NERDTreeClose
    else
      NERDTreeFind
    endif
  else
    NERDTree
  endif
endfunction

" open NERDTree with ctrl + n
nmap <C-n> :call ToggleTree()<CR>