मुझे टी-एसक्यूएल की गणना करने वाले लेवेंसहाइट दूरी में एल्गोरिथ्म में दिलचस्पी है।
मुझे टी-एसक्यूएल की गणना करने वाले लेवेंसहाइट दूरी में एल्गोरिथ्म में दिलचस्पी है।
जवाबों:
मैंने कई अनुकूलन के साथ TSQL में मानक Levenshtein एडिट डिस्टेंस फंक्शन को लागू किया जो कि मेरे द्वारा ज्ञात अन्य संस्करणों की गति में सुधार करता है। ऐसे मामलों में जहां दो तारों में उनके शुरू में (साझा उपसर्ग) में पात्र होते हैं, उनके अंत में समान (साझा प्रत्यय) के पात्र, और जब तार बड़े होते हैं और अधिकतम संपादित दूरी प्रदान की जाती है, तो गति में सुधार महत्वपूर्ण है। उदाहरण के लिए, जब इनपुट दो बहुत समान 4000 वर्ण तार होते हैं, और अधिकतम 2 की दूरी को निर्दिष्ट किया जाता है, यह परिमाण की तुलना में तेजी से लगभग तीन क्रम होता हैedit_distance_withinस्वीकृत जवाब में कार्य करते हैं, जवाब 55.0 सेकंड (0.0 मिली सेकेंड) बनाम 55 सेकंड में वापस करते हैं। यह दो इनपुट स्ट्रिंग्स के साथ-साथ कुछ स्थिर स्थान के बराबर स्थान का उपयोग करके भी मेमोरी कुशल है। यह एक स्तंभ का प्रतिनिधित्व करने वाले एक एकल nvarchar "सरणी" का उपयोग करता है, और उस में सभी संगणना करता है, साथ ही कुछ सहायक चर भी।
अनुकूलन:
यहाँ कोड है (1/20/2014 को अपडेट करने के लिए इसे थोड़ा और तेज करें):
-- =============================================
-- Computes and returns the Levenshtein edit distance between two strings, i.e. the
-- number of insertion, deletion, and sustitution edits required to transform one
-- string to the other, or NULL if @max is exceeded. Comparisons use the case-
-- sensitivity configured in SQL Server (case-insensitive by default).
--
-- Based on Sten Hjelmqvist's "Fast, memory efficient" algorithm, described
-- at http://www.codeproject.com/Articles/13525/Fast-memory-efficient-Levenshtein-algorithm,
-- with some additional optimizations.
-- =============================================
CREATE FUNCTION [dbo].[Levenshtein](
@s nvarchar(4000)
, @t nvarchar(4000)
, @max int
)
RETURNS int
WITH SCHEMABINDING
AS
BEGIN
DECLARE @distance int = 0 -- return variable
, @v0 nvarchar(4000)-- running scratchpad for storing computed distances
, @start int = 1 -- index (1 based) of first non-matching character between the two string
, @i int, @j int -- loop counters: i for s string and j for t string
, @diag int -- distance in cell diagonally above and left if we were using an m by n matrix
, @left int -- distance in cell to the left if we were using an m by n matrix
, @sChar nchar -- character at index i from s string
, @thisJ int -- temporary storage of @j to allow SELECT combining
, @jOffset int -- offset used to calculate starting value for j loop
, @jEnd int -- ending value for j loop (stopping point for processing a column)
-- get input string lengths including any trailing spaces (which SQL Server would otherwise ignore)
, @sLen int = datalength(@s) / datalength(left(left(@s, 1) + '.', 1)) -- length of smaller string
, @tLen int = datalength(@t) / datalength(left(left(@t, 1) + '.', 1)) -- length of larger string
, @lenDiff int -- difference in length between the two strings
-- if strings of different lengths, ensure shorter string is in s. This can result in a little
-- faster speed by spending more time spinning just the inner loop during the main processing.
IF (@sLen > @tLen) BEGIN
SELECT @v0 = @s, @i = @sLen -- temporarily use v0 for swap
SELECT @s = @t, @sLen = @tLen
SELECT @t = @v0, @tLen = @i
END
SELECT @max = ISNULL(@max, @tLen)
, @lenDiff = @tLen - @sLen
IF @lenDiff > @max RETURN NULL
-- suffix common to both strings can be ignored
WHILE(@sLen > 0 AND SUBSTRING(@s, @sLen, 1) = SUBSTRING(@t, @tLen, 1))
SELECT @sLen = @sLen - 1, @tLen = @tLen - 1
IF (@sLen = 0) RETURN @tLen
-- prefix common to both strings can be ignored
WHILE (@start < @sLen AND SUBSTRING(@s, @start, 1) = SUBSTRING(@t, @start, 1))
SELECT @start = @start + 1
IF (@start > 1) BEGIN
SELECT @sLen = @sLen - (@start - 1)
, @tLen = @tLen - (@start - 1)
-- if all of shorter string matches prefix and/or suffix of longer string, then
-- edit distance is just the delete of additional characters present in longer string
IF (@sLen <= 0) RETURN @tLen
SELECT @s = SUBSTRING(@s, @start, @sLen)
, @t = SUBSTRING(@t, @start, @tLen)
END
-- initialize v0 array of distances
SELECT @v0 = '', @j = 1
WHILE (@j <= @tLen) BEGIN
SELECT @v0 = @v0 + NCHAR(CASE WHEN @j > @max THEN @max ELSE @j END)
SELECT @j = @j + 1
END
SELECT @jOffset = @max - @lenDiff
, @i = 1
WHILE (@i <= @sLen) BEGIN
SELECT @distance = @i
, @diag = @i - 1
, @sChar = SUBSTRING(@s, @i, 1)
-- no need to look beyond window of upper left diagonal (@i) + @max cells
-- and the lower right diagonal (@i - @lenDiff) - @max cells
, @j = CASE WHEN @i <= @jOffset THEN 1 ELSE @i - @jOffset END
, @jEnd = CASE WHEN @i + @max >= @tLen THEN @tLen ELSE @i + @max END
WHILE (@j <= @jEnd) BEGIN
-- at this point, @distance holds the previous value (the cell above if we were using an m by n matrix)
SELECT @left = UNICODE(SUBSTRING(@v0, @j, 1))
, @thisJ = @j
SELECT @distance =
CASE WHEN (@sChar = SUBSTRING(@t, @j, 1)) THEN @diag --match, no change
ELSE 1 + CASE WHEN @diag < @left AND @diag < @distance THEN @diag --substitution
WHEN @left < @distance THEN @left -- insertion
ELSE @distance -- deletion
END END
SELECT @v0 = STUFF(@v0, @thisJ, 1, NCHAR(@distance))
, @diag = @left
, @j = case when (@distance > @max) AND (@thisJ = @i + @lenDiff) then @jEnd + 2 else @thisJ + 1 end
END
SELECT @i = CASE WHEN @j > @jEnd + 1 THEN @sLen + 1 ELSE @i + 1 END
END
RETURN CASE WHEN @distance <= @max THEN @distance ELSE NULL END
END
जैसा कि इस फ़ंक्शन की टिप्पणियों में उल्लेख किया गया है, वर्ण तुलना की केस सेंसिटिविटी उस कोलाज का अनुसरण करेगी जो प्रभाव में है। डिफ़ॉल्ट रूप से, SQL सर्वर का टकराव वह होता है जिसके परिणामस्वरूप असंवेदनशील तुलना होती है। इस फ़ंक्शन को हमेशा संवेदनशील होने के लिए संशोधित करने का एक तरीका यह होगा कि दो स्थानों पर एक विशिष्ट टकराव को जोड़ा जाए जहां तार की तुलना की जाती है। हालाँकि, मैंने इसका पूरी तरह से परीक्षण नहीं किया है, विशेष रूप से साइड इफेक्ट्स के लिए जब डेटाबेस एक गैर-डिफ़ॉल्ट कॉलेशन का उपयोग कर रहा है। ये हैं कि मामले की संवेदनशील तुलना करने के लिए दो लाइनों को कैसे बदला जाएगा:
-- prefix common to both strings can be ignored
WHILE (@start < @sLen AND SUBSTRING(@s, @start, 1) = SUBSTRING(@t, @start, 1) COLLATE SQL_Latin1_General_Cp1_CS_AS)
तथा
SELECT @distance =
CASE WHEN (@sChar = SUBSTRING(@t, @j, 1) COLLATE SQL_Latin1_General_Cp1_CS_AS) THEN @diag --match, no change
अर्नोल्ड फ्रिबल के sqlteam.com/forums पर दो प्रस्ताव थे
यह 2006 से छोटा है:
SET QUOTED_IDENTIFIER ON
GO
SET ANSI_NULLS ON
GO
CREATE FUNCTION edit_distance_within(@s nvarchar(4000), @t nvarchar(4000), @d int)
RETURNS int
AS
BEGIN
DECLARE @sl int, @tl int, @i int, @j int, @sc nchar, @c int, @c1 int,
@cv0 nvarchar(4000), @cv1 nvarchar(4000), @cmin int
SELECT @sl = LEN(@s), @tl = LEN(@t), @cv1 = '', @j = 1, @i = 1, @c = 0
WHILE @j <= @tl
SELECT @cv1 = @cv1 + NCHAR(@j), @j = @j + 1
WHILE @i <= @sl
BEGIN
SELECT @sc = SUBSTRING(@s, @i, 1), @c1 = @i, @c = @i, @cv0 = '', @j = 1, @cmin = 4000
WHILE @j <= @tl
BEGIN
SET @c = @c + 1
SET @c1 = @c1 - CASE WHEN @sc = SUBSTRING(@t, @j, 1) THEN 1 ELSE 0 END
IF @c > @c1 SET @c = @c1
SET @c1 = UNICODE(SUBSTRING(@cv1, @j, 1)) + 1
IF @c > @c1 SET @c = @c1
IF @c < @cmin SET @cmin = @c
SELECT @cv0 = @cv0 + NCHAR(@c), @j = @j + 1
END
IF @cmin > @d BREAK
SELECT @cv1 = @cv0, @i = @i + 1
END
RETURN CASE WHEN @cmin <= @d AND @c <= @d THEN @c ELSE -1 END
END
GO
IIRC, SQL सर्वर 2005 के साथ और बाद में आप किसी भी .NET भाषा में संग्रहीत कार्यविधियाँ लिख सकते हैं: SQL सर्वर 2005 में CLR एकीकरण का उपयोग करना । इसके साथ ही लेवेनस्टीन की दूरी की गणना के लिए एक प्रक्रिया लिखना कठिन नहीं होना चाहिए ।
एक साधारण नमस्ते, विश्व! मदद से निकाला गया:
using System;
using System.Data;
using Microsoft.SqlServer.Server;
using System.Data.SqlTypes;
public class HelloWorldProc
{
[Microsoft.SqlServer.Server.SqlProcedure]
public static void HelloWorld(out string text)
{
SqlContext.Pipe.Send("Hello world!" + Environment.NewLine);
text = "Hello world!";
}
}
फिर अपने SQL सर्वर में निम्न कार्य करें:
CREATE ASSEMBLY helloworld from 'c:\helloworld.dll' WITH PERMISSION_SET = SAFE
CREATE PROCEDURE hello
@i nchar(25) OUTPUT
AS
EXTERNAL NAME helloworld.HelloWorldProc.HelloWorld
और अब आप इसे चला सकते हैं:
DECLARE @J nchar(25)
EXEC hello @J out
PRINT @J
उम्मीद है की यह मदद करेगा।
तार की तुलना करने के लिए आप लेवेंसहाइट डिस्टेंस एल्गोरिथम का उपयोग कर सकते हैं
यहां आप http://www.kodyaz.com/articles/fuzzy-string-matching-using-levenshtein-distance-sql-server.aspx पर T-SQL का उदाहरण पा सकते हैं
CREATE FUNCTION edit_distance(@s1 nvarchar(3999), @s2 nvarchar(3999))
RETURNS int
AS
BEGIN
DECLARE @s1_len int, @s2_len int
DECLARE @i int, @j int, @s1_char nchar, @c int, @c_temp int
DECLARE @cv0 varbinary(8000), @cv1 varbinary(8000)
SELECT
@s1_len = LEN(@s1),
@s2_len = LEN(@s2),
@cv1 = 0x0000,
@j = 1, @i = 1, @c = 0
WHILE @j <= @s2_len
SELECT @cv1 = @cv1 + CAST(@j AS binary(2)), @j = @j + 1
WHILE @i <= @s1_len
BEGIN
SELECT
@s1_char = SUBSTRING(@s1, @i, 1),
@c = @i,
@cv0 = CAST(@i AS binary(2)),
@j = 1
WHILE @j <= @s2_len
BEGIN
SET @c = @c + 1
SET @c_temp = CAST(SUBSTRING(@cv1, @j+@j-1, 2) AS int) +
CASE WHEN @s1_char = SUBSTRING(@s2, @j, 1) THEN 0 ELSE 1 END
IF @c > @c_temp SET @c = @c_temp
SET @c_temp = CAST(SUBSTRING(@cv1, @j+@j+1, 2) AS int)+1
IF @c > @c_temp SET @c = @c_temp
SELECT @cv0 = @cv0 + CAST(@c AS binary(2)), @j = @j + 1
END
SELECT @cv1 = @cv0, @i = @i + 1
END
RETURN @c
END
(जोसेफ गामा द्वारा विकसित समारोह)
उपयोग:
select
dbo.edit_distance('Fuzzy String Match','fuzzy string match'),
dbo.edit_distance('fuzzy','fuzy'),
dbo.edit_distance('Fuzzy String Match','fuzy string match'),
dbo.edit_distance('levenshtein distance sql','levenshtein sql server'),
dbo.edit_distance('distance','server')
एल्गोरिथ्म बस एक स्टेप काउंट को एक स्टेप में एक दूसरे कैरेक्टर को रिप्लेस करके दूसरे में बदलने के लिए रिटर्न करता है
मैं भी लेवेंसहाइट एल्गोरिथ्म के लिए एक कोड उदाहरण की तलाश में था, और यहां पाकर खुश था। निश्चित रूप से मैं यह समझना चाहता था कि एल्गोरिथ्म कैसे काम कर रहा है और मैं उपरोक्त उदाहरणों में से एक के साथ थोड़ा खेल रहा था, जो कि मैं थोड़ा सा खेल रहा था जो कि वीवे द्वारा पोस्ट किया गया था । कोड की बेहतर समझ पाने के लिए मैंने मैट्रिक्स के साथ एक एक्सेल बनाया।
फ़ूजी के साथ तुलना में फ़ूजी के लिए दूरी
छवियाँ 1000 से अधिक शब्द कहती हैं।
इस EXCEL के साथ मैंने पाया कि अतिरिक्त प्रदर्शन अनुकूलन की क्षमता थी। ऊपरी दाएं लाल क्षेत्र में सभी मानों की गणना करने की आवश्यकता नहीं है। प्रत्येक लाल सेल का मान बाएं सेल के मान से अधिक होता है। 1. ऐसा इसलिए है, क्योंकि दूसरा स्ट्रिंग हमेशा उस क्षेत्र में पहले वाले की तुलना में अधिक लंबा होगा, जो प्रत्येक वर्ण के लिए 1 के मान से दूरी बढ़ाता है।
आप इस कथन को IF @j <= @i का उपयोग करके और इस कथन के लिए @i के मूल्य को बढ़ा सकते हैं ।
CREATE FUNCTION [dbo].[f_LevenshteinDistance](@s1 nvarchar(3999), @s2 nvarchar(3999))
RETURNS int
AS
BEGIN
DECLARE @s1_len int;
DECLARE @s2_len int;
DECLARE @i int;
DECLARE @j int;
DECLARE @s1_char nchar;
DECLARE @c int;
DECLARE @c_temp int;
DECLARE @cv0 varbinary(8000);
DECLARE @cv1 varbinary(8000);
SELECT
@s1_len = LEN(@s1),
@s2_len = LEN(@s2),
@cv1 = 0x0000 ,
@j = 1 ,
@i = 1 ,
@c = 0
WHILE @j <= @s2_len
SELECT @cv1 = @cv1 + CAST(@j AS binary(2)), @j = @j + 1;
WHILE @i <= @s1_len
BEGIN
SELECT
@s1_char = SUBSTRING(@s1, @i, 1),
@c = @i ,
@cv0 = CAST(@i AS binary(2)),
@j = 1;
SET @i = @i + 1;
WHILE @j <= @s2_len
BEGIN
SET @c = @c + 1;
IF @j <= @i
BEGIN
SET @c_temp = CAST(SUBSTRING(@cv1, @j + @j - 1, 2) AS int) + CASE WHEN @s1_char = SUBSTRING(@s2, @j, 1) THEN 0 ELSE 1 END;
IF @c > @c_temp SET @c = @c_temp
SET @c_temp = CAST(SUBSTRING(@cv1, @j + @j + 1, 2) AS int) + 1;
IF @c > @c_temp SET @c = @c_temp;
END;
SELECT @cv0 = @cv0 + CAST(@c AS binary(2)), @j = @j + 1;
END;
SET @cv1 = @cv0;
END;
RETURN @c;
END;
('jane', 'jeanne')3 की दूरी पर लौटेगा, जब दूरी 2. होनी चाहिए। सही करने के लिए इस अतिरिक्त कोड को जोड़ा जाना चाहिए जो स्वैप करता है @s1और @s2अगर @s1इसकी लंबाई कम है @s2।
TSQL में दो वस्तुओं की तुलना करने का सबसे अच्छा और सबसे तेज़ तरीका चुनिंदा कथन हैं जो अनुक्रमित स्तंभों पर तालिकाओं में शामिल होते हैं। इसलिए यह है कि अगर आप RDBMS इंजन के फायदों से लाभ उठाना चाहते हैं तो मैं संपादन दूरी को लागू करने का सुझाव देता हूं। TSQL लूप भी काम करेंगे, लेकिन बड़ी मात्रा में तुलना के लिए TSQL की तुलना में लेवेनस्टीन दूरी की गणना अन्य भाषाओं में तेज होगी।
मैंने केवल उस उद्देश्य के लिए डिज़ाइन की गई अस्थायी तालिकाओं के विरुद्ध जोड़ों की श्रृंखला का उपयोग करके कई प्रणालियों में संपादन दूरी को लागू किया है। इसके लिए कुछ भारी पूर्व-प्रसंस्करण चरणों की आवश्यकता होती है - अस्थायी तालिकाओं की तैयारी - लेकिन यह बड़ी संख्या में तुलनाओं के साथ बहुत अच्छी तरह से काम करता है।
कुछ शब्दों में: पूर्व-प्रसंस्करण में टेम्प टेबल बनाने, आबाद करने और अनुक्रमण करने के होते हैं। पहले वाले में रेफरेंस आईडी, एक-लेटर कॉलम और चारिंडेक्स कॉलम होता है। स्रोत तालिका में शब्द के रूप में कई पंक्तियों को बनाने के लिए यह तालिका सम्मिलित क्वेरीज़ की एक श्रृंखला को चलाती है, जो अक्षरों में हर शब्द को विभाजित करती है (SELUB SUBSTRING का उपयोग करके)। मुझे पता है कि बहुत सी पंक्तियाँ हैं लेकिन SQL सर्वर अरबों को संभाल सकता है पंक्तियों की)। फिर 2-लेटर कॉलम के साथ एक दूसरी टेबल बनाएं, 3-लेटर कॉलम के साथ एक और टेबल, आदि। अंतिम परिणाम टेबल की एक श्रृंखला है जिसमें प्रत्येक शब्द के संदर्भ आईडी और सबस्ट्रिंग होते हैं, साथ ही उनकी स्थिति का संदर्भ भी होता है। शब्द में।
एक बार यह पूरा हो जाने के बाद, पूरा खेल इन तालिकाओं की नकल करने और उन्हें अपने डुप्लिकेट के खिलाफ एक ग्रुप बाय चुनिंदा क्वेरी में शामिल करने के लिए होता है जो मैचों की संख्या को गिनता है। यह शब्दों की हर संभव जोड़ी के लिए उपायों की एक श्रृंखला बनाता है, जिन्हें तब प्रति जोड़ी शब्दों के एक सिंगल लेवेनस्टीन दूरी में फिर से एकत्र किया जाता है।
तकनीकी रूप से यह लेवेनस्टीन दूरी (या इसके वेरिएंट) के अन्य अन्य कार्यान्वयनों की तुलना में बहुत अलग है, इसलिए आपको गहराई से समझने की आवश्यकता है कि लेवेनस्टीन दूरी कैसे काम करती है और इसे क्यों बनाया गया था। साथ ही विकल्पों की जांच करें क्योंकि उस पद्धति के साथ आप अंतर्निहित मैट्रिक्स की एक श्रृंखला के साथ समाप्त होते हैं जो एक ही समय में संपादन दूरी के कई वेरिएंट की गणना करने में मदद कर सकता है, जिससे आपको दिलचस्प मशीन सीखने के संभावित सुधार मिलेंगे।
इस पृष्ठ में पिछले उत्तरों द्वारा पहले से ही उल्लेखित एक और बिंदु: उन जोड़ों को खत्म करने के लिए जितना संभव हो उतना पूर्व प्रक्रिया करने की कोशिश करें जिन्हें दूरी माप की आवश्यकता नहीं है। उदाहरण के लिए, दो शब्दों की एक जोड़ी जिसमें आम में एक भी अक्षर नहीं है, को बाहर रखा जाना चाहिए, क्योंकि संपादन दूरी तार की लंबाई से प्राप्त की जा सकती है। या एक ही शब्द की दो प्रतियों के बीच की दूरी को न मापें, क्योंकि यह स्वभाव से 0 है। या माप करने से पहले डुप्लिकेट को हटा दें, यदि आपके शब्दों की सूची एक लंबे पाठ से आती है तो संभावना है कि एक ही शब्द एक से अधिक बार दिखाई देंगे, इसलिए केवल एक बार दूरी को मापना प्रसंस्करण समय बचाएगा, आदि।